dev-util/eric: add 19.11, EAPI=7, drop python2 support

Package-Manager: Portage-2.3.79, Repoman-2.3.18
Signed-off-by: Davide Pesavento <pesa@gentoo.org>

diff --git a/dev-util/eric/Manifest b/dev-util/eric/Manifest
index fa92b8ea12c9db56740b62095a4f0d6830331d35..27009a0fbd21298b9d4d1fc2ddeacc7a2d59b2a2 100644 (file)
--- a/dev-util/eric/Manifest
+++ b/dev-util/eric/Manifest
@@ -1 +1,2 @@
 DIST eric6-18.03.tar.gz 16517664 BLAKE2B f7f5292df8bc694fc4715ec1a250d948123a2eb99a590e6824d985318446babff86aeb745f5b5dbd0707e771638eaa943673e5b546676bea97e266888b844989 SHA512 e488010791b44cc7da782620baec9b97259aaefeb90d491023ec1d4582fb68acbc06d9eedba7beef9ddc706302e06e36b9ebb4e46d6f035b6c74e9f4eb9ac400
+DIST eric6-19.11.tar.gz 16241807 BLAKE2B bd8284164c6c191e91fc08bc42f594107ebab50f71a980ef331d42fbd8d9c488d5674b2f53665718a6e723a228e838d082095fc3c3b2d40c3fb350c5be9a98ee SHA512 a8305c5185687d62231926bd4c484f3786ac1c20d125a1f8fb1b6bc0d42c57ba92bf00aaffd8699f8d7594c6432896bef8db13da85513ba4f217a60223f2f533

diff --git a/dev-util/eric/eric-19.11.ebuild b/dev-util/eric/eric-19.11.ebuild
new file mode 100644 (file)
index 0000000..637b427
--- /dev/null
+++ b/dev-util/eric/eric-19.11.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7} )
+PYTHON_REQ_USE="sqlite,xml"
+inherit python-single-r1 xdg
+
+MY_P=${PN}6-${PV}
+
+DESCRIPTION="A full featured Python IDE using PyQt and QScintilla"
+HOMEPAGE="https://eric-ide.python-projects.org/"
+SRC_URI="mirror://sourceforge/eric-ide/${PN}6/stable/${PV}/${MY_P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="6"
+KEYWORDS="~amd64 ~x86"
+IUSE="spell"
+
+DEPEND="
+       ${PYTHON_DEPS}
+       >=dev-python/PyQt5-5.12[gui,help,network,printsupport,sql,svg,widgets,${PYTHON_USEDEP}]
+       dev-python/PyQtWebEngine[${PYTHON_USEDEP}]
+       dev-python/qscintilla-python[${PYTHON_USEDEP}]
+       dev-python/sip[${PYTHON_USEDEP}]
+"
+RDEPEND="${DEPEND}
+       >=dev-python/chardet-3.0.4[${PYTHON_USEDEP}]
+       >=dev-python/pygments-2.3.1[${PYTHON_USEDEP}]
+       spell? ( dev-python/pyenchant[${PYTHON_USEDEP}] )
+"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+S=${WORKDIR}/${MY_P}
+
+DOCS=( eric/docs/{changelog,README.rst,README-eric6-doc.rst,README-passive-debugging.rst,THANKS} )
+
+src_prepare() {
+       default
+
+       # Delete internal copies of dev-python/chardet and dev-python/pygments
+       rm -fr eric/eric6/ThirdParty/{CharDet,Pygments} || die
+}
+
+src_install() {
+       yes n | "${PYTHON}" install.py \
+               -b "${EPREFIX}/usr/bin" \
+               -d "$(python_get_sitedir)" \
+               -i "${D}" \
+               -c \
+               -z \
+               || die
+
+       python_optimize
+       einstalldocs
+}