media-gfx/librecad: insinto -> docinto (bug #637950).

Package-Manager: Portage-2.3.20, Repoman-2.3.6

diff --git a/media-gfx/librecad/librecad-2.1.3-r3.ebuild b/media-gfx/librecad/librecad-2.1.3-r3.ebuild
new file mode 100644 (file)
index 0000000..20902c5
--- /dev/null
+++ b/media-gfx/librecad/librecad-2.1.3-r3.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+inherit eutils qmake-utils
+
+DESCRIPTION="Generic 2D CAD program"
+HOMEPAGE="http://www.librecad.org/"
+SRC_URI="https://github.com/LibreCAD/LibreCAD/archive/${PV/_/}.zip -> ${P}.zip"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+
+IUSE="3d debug doc tools"
+
+DEPEND="
+       dev-cpp/muParser
+       dev-libs/boost:=
+       dev-qt/qtcore:5
+       dev-qt/qtgui:5
+       dev-qt/qthelp:5
+       dev-qt/qtprintsupport:5
+       dev-qt/qtsvg:5
+       dev-qt/qtwidgets:5
+       dev-qt/qtxml:5
+       media-libs/freetype:2"
+
+RDEPEND="${DEPEND}"
+S="${WORKDIR}/LibreCAD-${PV}"
+
+src_prepare() {
+#      epatch "${FILESDIR}/iota-fix-2.1.1.patch"
+
+       # currently RS_VECTOR3D causes an internal compiler error on GCC-4.8
+       if ! use 3d; then
+               sed -i -e '/RS_VECTOR2D/ s/^#//' librecad/src/src.pro || die
+       fi
+}
+
+src_configure() {
+       eqmake5 -r
+}
+
+src_install() {
+       dobin unix/librecad
+       use tools && dobin unix/ttf2lff
+       insinto /usr/share/${PN}
+       doins -r unix/resources/*
+       use doc && docinto html && dodoc -r librecad/support/doc/*
+       insinto /usr/share/appdata
+       doins unix/appdata/librecad.appdata.xml
+       doicon librecad/res/main/${PN}.png
+       make_desktop_entry ${PN} LibreCAD ${PN} Graphics
+}

diff --git a/media-gfx/librecad/librecad-9999.ebuild b/media-gfx/librecad/librecad-9999.ebuild
index de157dedc9ef3d060845f5daa0b95ba901d953a9..efb61a9472a1e0b7adc78fb9f9c0e5a7cb855e18 100644 (file)
--- a/media-gfx/librecad/librecad-9999.ebuild
+++ b/media-gfx/librecad/librecad-9999.ebuild
@@ -47,7 +47,7 @@ src_install() {
        doins -r unix/appdata
        insinto /usr/share/${PN}
        doins -r unix/resources/*
-       use doc && insinto html && dodoc -r librecad/support/doc/*
+       use doc && docinto html && dodoc -r librecad/support/doc/*
        insinto /usr/share/appdata
        doins unix/appdata/librecad.appdata.xml
        doicon librecad/res/main/${PN}.png