x11-drivers/xf86-video-intel: Depend on virtual/libudev:=

Bug: https://bugs.gentoo.org/545906

diff --git a/x11-drivers/xf86-video-intel/xf86-video-intel-2.99.917_p20180214-r1.ebuild b/x11-drivers/xf86-video-intel/xf86-video-intel-2.99.917_p20180214-r1.ebuild
new file mode 100644 (file)
index 0000000..b3cc334
--- /dev/null
+++ b/x11-drivers/xf86-video-intel/xf86-video-intel-2.99.917_p20180214-r1.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+XORG_DRI=dri
+XORG_EAUTORECONF=yes
+inherit linux-info xorg-2 flag-o-matic
+
+if [[ ${PV} == 9999* ]]; then
+       SRC_URI=""
+else
+       KEYWORDS="amd64 x86"
+       COMMIT_ID="75795523003798d789d417e82aaa81c7ea1ed616"
+       SRC_URI="https://cgit.freedesktop.org/xorg/driver/xf86-video-intel/snapshot/${COMMIT_ID}.tar.xz -> ${P}.tar.xz"
+       S=${WORKDIR}/${COMMIT_ID}
+fi
+
+DESCRIPTION="X.Org driver for Intel cards"
+
+IUSE="debug dri3 +sna tools +udev uxa xvmc"
+
+REQUIRED_USE="
+       || ( sna uxa )
+"
+RDEPEND="
+       x11-libs/libXext
+       x11-libs/libXfixes
+       x11-libs/libXScrnSaver
+       >=x11-libs/pixman-0.27.1
+       >=x11-libs/libdrm-2.4.52[video_cards_intel]
+       dri3? (
+               >=x11-base/xorg-server-1.18
+               !<=media-libs/mesa-12.0.4
+       )
+       sna? (
+               >=x11-base/xorg-server-1.10
+       )
+       tools? (
+               x11-libs/libX11
+               x11-libs/libxcb
+               x11-libs/libXcursor
+               x11-libs/libXdamage
+               x11-libs/libXinerama
+               x11-libs/libXrandr
+               x11-libs/libXrender
+               x11-libs/libxshmfence
+               x11-libs/libXtst
+       )
+       udev? (
+               virtual/libudev:=
+       )
+       xvmc? (
+               x11-libs/libXvMC
+               >=x11-libs/libxcb-1.5
+               x11-libs/xcb-util
+       )
+"
+DEPEND="${RDEPEND}
+       x11-base/xorg-proto"
+
+src_configure() {
+       replace-flags -Os -O2
+       XORG_CONFIGURE_OPTIONS=(
+               --disable-dri1
+               $(use_enable debug)
+               $(use_enable dri)
+               $(use_enable dri dri3)
+               $(usex dri3 "--with-default-dri=3")
+               $(use_enable sna)
+               $(use_enable tools)
+               $(use_enable udev)
+               $(use_enable uxa)
+               $(use_enable xvmc)
+       )
+       xorg-2_src_configure
+}
+
+pkg_postinst() {
+       if linux_config_exists && \
+               kernel_is -lt 4 3 && ! linux_chkconfig_present DRM_I915_KMS; then
+               echo
+               ewarn "This driver requires KMS support in your kernel"
+               ewarn "  Device Drivers --->"
+               ewarn "    Graphics support --->"
+               ewarn "      Direct Rendering Manager (XFree86 4.1.0 and higher DRI support)  --->"
+               ewarn "      <*>   Intel 830M, 845G, 852GM, 855GM, 865G (i915 driver)  --->"
+               ewarn "       i915 driver"
+               ewarn "      [*]       Enable modesetting on intel by default"
+               echo
+       fi
+}

diff --git a/x11-drivers/xf86-video-intel/xf86-video-intel-9999.ebuild b/x11-drivers/xf86-video-intel/xf86-video-intel-9999.ebuild
index 260b7765466341514151d0c8c6d2c0b7ed50706b..57a5241bcdd5f25d70e3d9c2de22c99710856a17 100644 (file)
--- a/x11-drivers/xf86-video-intel/xf86-video-intel-9999.ebuild
+++ b/x11-drivers/xf86-video-intel/xf86-video-intel-9999.ebuild
@@ -48,7 +48,7 @@ RDEPEND="
                x11-libs/libXtst
        )
        udev? (
-               virtual/udev
+               virtual/libudev:=
        )
        xvmc? (
                x11-libs/libXvMC