media-plugins/gst-plugins-opus: Properly split again

... instead of building as part of gst-plugins-base[opus].
This makes gst-plugins-opus a split of -base instead of -bad as it
was moved from -base to -bad with some leftovers in -bad.
The ext/opus/ leftover part in gst-plugins-bad is not necessary
for anything and we can safely not package that at all.
This should give a nicer upgrade path for stable opus plugin users.

Gentoo-bug: 589440

diff --git a/media-libs/gst-plugins-base/gst-plugins-base-1.8.3-r1.ebuild b/media-libs/gst-plugins-base/gst-plugins-base-1.8.3-r1.ebuild
new file mode 100644 (file)
index 0000000..0b26be7
--- /dev/null
+++ b/media-libs/gst-plugins-base/gst-plugins-base-1.8.3-r1.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+GST_ORG_MODULE="gst-plugins-base"
+
+inherit gstreamer
+
+DESCRIPTION="Basepack of plugins for gstreamer"
+HOMEPAGE="https://gstreamer.freedesktop.org/"
+
+LICENSE="GPL-2+ LGPL-2+"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+
+IUSE="alsa +introspection ivorbis +ogg +orc +pango theora +vorbis X"
+REQUIRED_USE="
+       ivorbis? ( ogg )
+       theora? ( ogg )
+       vorbis? ( ogg )
+"
+
+RDEPEND="
+       app-text/iso-codes
+       >=dev-libs/glib-2.40.0:2[${MULTILIB_USEDEP}]
+       >=media-libs/gstreamer-${PV}:1.0[introspection?,${MULTILIB_USEDEP}]
+       >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}]
+       alsa? ( >=media-libs/alsa-lib-1.0.27.2[${MULTILIB_USEDEP}] )
+       introspection? ( >=dev-libs/gobject-introspection-1.31.1:= )
+       ivorbis? ( >=media-libs/tremor-0_pre20130223[${MULTILIB_USEDEP}] )
+       ogg? ( >=media-libs/libogg-1.3.0[${MULTILIB_USEDEP}] )
+       orc? ( >=dev-lang/orc-0.4.23[${MULTILIB_USEDEP}] )
+       pango? ( >=x11-libs/pango-1.36.3[${MULTILIB_USEDEP}] )
+       theora? ( >=media-libs/libtheora-1.1.1[encode,${MULTILIB_USEDEP}] )
+       vorbis? ( >=media-libs/libvorbis-1.3.3-r1[${MULTILIB_USEDEP}] )
+       X? (
+               >=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+               >=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
+               >=x11-libs/libXv-1.0.10[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+       >=dev-util/gtk-doc-am-1.12
+       X? (
+               >=x11-proto/videoproto-2.3.1-r1[${MULTILIB_USEDEP}]
+               >=x11-proto/xextproto-7.2.1-r1[${MULTILIB_USEDEP}]
+               >=x11-proto/xproto-7.0.24[${MULTILIB_USEDEP}] )
+"
+
+multilib_src_configure() {
+       gstreamer_multilib_src_configure \
+               $(use_enable alsa) \
+               $(multilib_native_use_enable introspection) \
+               $(use_enable ivorbis) \
+               $(use_enable ogg) \
+               $(use_enable orc) \
+               $(use_enable pango) \
+               $(use_enable theora) \
+               $(use_enable vorbis) \
+               $(use_enable X x) \
+               $(use_enable X xshm) \
+               $(use_enable X xvideo) \
+               --disable-debug \
+               --disable-examples \
+               --disable-static
+       # cdparanoia and libvisual are split out, per leio's request
+
+       # bug #366931, flag-o-matic for the whole thing is overkill
+       if [[ ${CHOST} == *86-*-darwin* ]] ; then
+               sed -i \
+                       -e '/FLAGS = /s|-O[23]|-O1|g' \
+                       gst/audioconvert/Makefile \
+                       gst/volume/Makefile || die
+       fi
+
+       if multilib_is_native_abi; then
+               local x
+               for x in libs plugins; do
+                       ln -s "${S}"/docs/${x}/html docs/${x}/html || die
+               done
+       fi
+}
+
+multilib_src_install_all() {
+       DOCS="AUTHORS NEWS README RELEASE"
+       einstalldocs
+       prune_libtool_files --modules
+}

diff --git a/media-plugins/gst-plugins-opus/Manifest b/media-plugins/gst-plugins-opus/Manifest
index 8dc3a91528ed2b250c4b3b6290f65b70348db450..8f30b4443c0b12d661fe60104c2145c9eae46d91 100644 (file)
--- a/media-plugins/gst-plugins-opus/Manifest
+++ b/media-plugins/gst-plugins-opus/Manifest
@@ -3,3 +3,4 @@ DIST gst-plugins-bad-1.4.5.tar.xz 3824936 SHA256 152fad7250683d72f9deb36c5685428
 DIST gst-plugins-bad-1.6.3.tar.xz 4216940 SHA256 971b29101d6a9c5e3fe94d99d977a227f58f0b2d29b6ca2c7f292052542b3a61 SHA512 0a3a1d3617f167e69c20db3fccf7af0c4983b8012136093dcc3d08c059d0d8687cf921309c91f94afb250e0c3b9f9ff397a98ff548ca83dc12ae762119ffc915 WHIRLPOOL eb1f1376ee9b36da09f93b14d587169a007578f7cfdce3981ae905638c28f32b85a2f2667fc347f0b9ff4aaa51512f9726377c9ab3c73040886eab9a09833612
 DIST gst-plugins-bad-1.8.2.tar.xz 4455536 SHA256 d7995317530c8773ec088f94d9320909d41da61996b801ebacce9a56af493f97 SHA512 0b8a7df6b60f24655b463dedae71de6c92dbbbc3bdf42f4b722caaee17cd701ae3c078a2ca81a9d6568123aeade20a8a3759f72a7a9806f4533375d61ab028b6 WHIRLPOOL a7af68b86bfff8c19683dd5afaaed6ea627b6d2fa54103ccc1310909ff500d36ee2c72a5bd66f2074f2bcf9f8292733dd09101ece26c47b54a18598364e39415
 DIST gst-plugins-bad-1.8.3.tar.xz 4500300 SHA256 7899fcb18e6a1af2888b19c90213af018a57d741c6e72ec56b133bc73ec8509b SHA512 3676903fea7a5b078187c3b295208bc24b567ba4e965035db603cf8106e34ca619668253ff4320b192c4e3d1698572e6591bf7fb7253bd2399e7986711bb85c4 WHIRLPOOL 7dbe853dd83b15c33a78da1cbe43d121dd92e90b9b0016ba8f77fbc8f4b6c4167fd508ed9ae0370c03a2b548a765539ed7a45e5dd0418bb6f66d789e133ee7c5
+DIST gst-plugins-base-1.8.3.tar.xz 2939464 SHA256 114871d4d63606b4af424a8433cd923e4ff66896b244bb7ac97b9da47f71e79e SHA512 9fe88b73fe85be8614340f65515900998bdee010ebc39d6d4286b7ba39a82b75e58da76dc15e23fae7f228f4efa51c68935e2515ccc367d13dd68e173cf1ae0c WHIRLPOOL 83a41208b37582c8fc3bddbb66916052486f6c3b175f7568bd48dff494c81f219d1273ebdd192c22fad21942b8dbf8a212e9a5b4f5df348efb2058a77bc9a4f1

diff --git a/media-plugins/gst-plugins-opus/gst-plugins-opus-1.8.3-r1.ebuild b/media-plugins/gst-plugins-opus/gst-plugins-opus-1.8.3-r1.ebuild
new file mode 100644 (file)
index 0000000..f4f2e1a
--- /dev/null
+++ b/media-plugins/gst-plugins-opus/gst-plugins-opus-1.8.3-r1.ebuild
@@ -0,0 +1,27 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+GST_ORG_MODULE=gst-plugins-base
+
+inherit gstreamer
+
+DESCRIPTION="Opus audio parser plugin for GStreamer"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd"
+IUSE=""
+
+COMMON_DEPEND=">=media-libs/opus-1.1:=[${MULTILIB_USEDEP}]"
+
+RDEPEND="${COMMON_DEPEND}
+       >=media-libs/gst-plugins-base-${PV}-r1:${SLOT}[${MULTILIB_USEDEP},ogg]
+"
+DEPEND="${COMMON_DEPEND}"
+
+src_prepare() {
+       default
+       gstreamer_system_link \
+               gst-libs/gst/tag:gstreamer-tag \
+               gst-libs/gst/pbutils:gstreamer-pbutils \
+               gst-libs/gst/audio:gstreamer-audio
+}