app-emulation/containers-storage: Bump to version 1.15.0

Package-Manager: Portage-2.3.79, Repoman-2.3.18
Signed-off-by: Zac Medico <zmedico@gentoo.org>

diff --git a/app-emulation/containers-storage/Manifest b/app-emulation/containers-storage/Manifest
index d7414a331404d48f381abf5269e97e6a7f375176..55b75dbde3f84414330fe7453d6e22f37dfd2504 100644 (file)
--- a/app-emulation/containers-storage/Manifest
+++ b/app-emulation/containers-storage/Manifest
@@ -1 +1,2 @@
 DIST containers-storage-1.14.0.tar.gz 5969311 BLAKE2B 7a7a7cb02b0dde590a633f14c0f17ed9b020c352857914b142efe3b47202c94869828b442fe703ad796c6c16a4f7321bc0832ddcc2a588bcc10c25af4bddc75e SHA512 95f8804808e2603cbca0ada584c2057832d6d7a0e83cc59defea27e8a825c4db1bb1e604311d81421341e2cb324d2f1833e6498f05e71d22d86414e5206ac748
+DIST containers-storage-1.15.0.tar.gz 5971848 BLAKE2B 79e39d0587319df2e73d1f2b0d34dd5d72b32151edd94a87af9e0ce109ee4a276bba80db8c04e496618c16ff427b6396414cfa1b99b2eaeacc66fbceb7456965 SHA512 5d758a863b0c845d912ee97afb4e8304e3899071d489c41b3116c8acaf2aa55648e6c0a14d0edb0d2694a8eb74b61ea05373b6bb5d3d577aeda9b8693092fced

diff --git a/app-emulation/containers-storage/containers-storage-1.15.0.ebuild b/app-emulation/containers-storage/containers-storage-1.15.0.ebuild
new file mode 100644 (file)
index 0000000..d094e8e
--- /dev/null
+++ b/app-emulation/containers-storage/containers-storage-1.15.0.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit go-module
+
+KEYWORDS="~amd64"
+DESCRIPTION="containers/storage library"
+HOMEPAGE="https://github.com/containers/storage"
+LICENSE="Apache-2.0 BSD BSD-2 CC-BY-SA-4.0 ISC MIT"
+SLOT="0"
+IUSE="btrfs +device-mapper test"
+EGO_PN="${HOMEPAGE#*//}"
+EGIT_COMMIT="v${PV}"
+SRC_URI="https://${EGO_PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+RDEPEND="
+       btrfs? ( sys-fs/btrfs-progs )
+       device-mapper? ( sys-fs/lvm2:= )"
+DEPEND="${RDEPEND}
+       dev-go/go-md2man
+       test? (
+               sys-fs/btrfs-progs
+               sys-fs/lvm2
+               sys-apps/util-linux
+       )"
+RESTRICT="test"
+
+S=${WORKDIR}/${P#containers-}
+
+src_prepare() {
+       default
+
+       sed -e 's:GO111MODULE=off:GO111MODULE=on:' -i Makefile || die
+
+       [[ -f hack/btrfs_tag.sh ]] || die
+       use btrfs || { echo -e "#!/bin/sh\necho exclude_graphdriver_btrfs" > \
+               "hack/btrfs_tag.sh" || die; }
+
+       [[ -f hack/libdm_tag.sh ]] || die
+       use device-mapper || { echo -e "#!/bin/sh\necho btrfs_noversion exclude_graphdriver_devicemapper" > \
+               "hack/libdm_tag.sh" || die; }
+}
+
+src_compile() {
+       export -n GOCACHE XDG_CACHE_HOME #678856
+       emake containers-storage docs
+}
+
+src_install() {
+       dobin "${PN}"
+       while read -r -d ''; do
+               mv "${REPLY}" "${REPLY%.1}" || die
+       done < <(find "${S}/docs" -name '*.[[:digit:]].1' -print0)
+       find "${S}/docs" -name '*.[[:digit:]]' -exec doman '{}' + || die
+}
+
+src_test() {
+       GOPATH="${S}" unshare -m emake local-test-unit || die
+}