xfce-base/xfdesktop: Bump to 4.12.4 (stable branch)

diff --git a/xfce-base/xfdesktop/Manifest b/xfce-base/xfdesktop/Manifest
index b3e7b664f69422ebec9919bfd5939a4787c4b5d7..9efba5b7526eb557e5aa4a836ccb1201b3435b21 100644 (file)
--- a/xfce-base/xfdesktop/Manifest
+++ b/xfce-base/xfdesktop/Manifest
@@ -1,2 +1,3 @@
 DIST xfdesktop-4.12.3.tar.bz2 1420704 SHA256 a8a8d93744d842ca6ac1f9bd2c8789ee178937bca7e170e5239cbdbef30520ac SHA512 e8c89640722d3dfb2c5aae09779f81e5e2a6e157cc4756a46139547bd1a5b1977fa828f68e8ea61d6c9483c35a9303169fc33cbeacde06f7e95e19c65ce54878 WHIRLPOOL ce6fbfa82b9ac753b640035c458c2d81cea76500c6905933c343b061c5f66192926dcc47baa0f72f2a55579212cc0a297538f5f1d913b026f0d5b88f4211e9d8
+DIST xfdesktop-4.12.4.tar.bz2 1421623 SHA256 098a35510562907e1431d5adbfa8307484a235c1dec6a43e2d58d2ac4241f1cb SHA512 29f170b96836298dc83e3c49650ab7e88a93c1a2fa1599d1d98f3b6c80c9c059748b76a821077eea39b5b4619998bb300ff17f06e88483a59bd5ae2b76d0605e WHIRLPOOL 6f818332c7de3c39632a29991432664807dcc78829e85a5f665727b3cee97a79ee5aaad2775959c7fa795e664d5c2d57a55d8c973e696e576bd982f44158ca88
 DIST xfdesktop-4.13.1.tar.bz2 1485914 SHA256 7e81fd3b8c939d7eee4e293ac1b670c1f3f59cf4de81e47382ecf857bc8879a4 SHA512 efe5ffe450f498ee0188a1ca5efd0ef340d73b5650060f18db4fe94ae9130dd27e41c6b30af2f90839e6c8272f3e270d16b86df64d595fe82169c26d624f806a WHIRLPOOL 99dcb6331b93b14e99aec09207c00b9adba810d6eaa622c0c175b1e4601a9c7076a2f2dd2e1564c9cf318edcdc6ea8e4ce0c11656235fd41d0cd12c7077cba75

diff --git a/xfce-base/xfdesktop/xfdesktop-4.12.4.ebuild b/xfce-base/xfdesktop/xfdesktop-4.12.4.ebuild
new file mode 100644 (file)
index 0000000..f7864fa
--- /dev/null
+++ b/xfce-base/xfdesktop/xfdesktop-4.12.4.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit gnome2-utils
+
+DESCRIPTION="Desktop manager for the Xfce desktop environment"
+HOMEPAGE="https://www.xfce.org/projects/"
+SRC_URI="mirror://xfce/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="debug libnotify +thunar"
+
+# src/xfdesktop-file-utils.c:#if GLIB_CHECK_VERSION (2, 38, 0)
+RDEPEND=">=x11-libs/cairo-1.6:=
+       >=dev-libs/dbus-glib-0.100:=
+       >=dev-libs/glib-2.20:=
+       >=x11-libs/gtk+-2.24:2=
+       >=x11-libs/libwnck-2.30:1=
+       x11-libs/libX11:=
+       >=xfce-base/exo-0.8:=
+       >=xfce-base/garcon-0.3:=
+       >=xfce-base/libxfce4ui-4.11:=
+       >=xfce-base/libxfce4util-4.11:=
+       >=xfce-base/xfconf-4.10:=
+       libnotify? ( >=x11-libs/libnotify-0.7:= )
+       thunar? (
+               >=dev-libs/glib-2.38:=
+               >=xfce-base/thunar-1.6:=[dbus]
+               )"
+DEPEND="${RDEPEND}
+       dev-util/intltool
+       sys-devel/gettext
+       virtual/pkgconfig"
+
+src_configure() {
+       local myconf=(
+               $(use_enable thunar file-icons)
+               $(use_enable thunar thunarx)
+               $(use_enable libnotify notifications)
+       )
+
+       econf "${myconf[@]}"
+}
+
+pkg_postinst() {
+       gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+       gnome2_icon_cache_update
+}