sci-libs/ViSP: bump to 3.2.0

Package-Manager: Portage-2.3.73, Repoman-2.3.17
Signed-off-by: Alexis Ballier <aballier@gentoo.org>

diff --git a/sci-libs/ViSP/Manifest b/sci-libs/ViSP/Manifest
index 8d8294fa543ff11da385daef9f79bed50bf11f88..728c48689cbb26a196eb5bbd6ba806b760861006 100644 (file)
--- a/sci-libs/ViSP/Manifest
+++ b/sci-libs/ViSP/Manifest
@@ -1,2 +1,3 @@
 DIST visp-3.0.1.tar.gz 26029005 BLAKE2B d8881b0dd56b38f5db88e33f13e7dfa29b0a64fa1aebc5160384db2c7124d3a0ab2f0a5b3ba0255cbe209b578a3cdeb4420dc138a063248f945e9a73e041f21d SHA512 558e9acbd7ac5ef2193dca026062b75e0a30a7efbcae7d1e7d392b0855e643ee96ab9f60c19465f6bfa861374e30d9e91faf2f860e0442fa48ea5ea384b4e3fa
 DIST visp-3.1.0.tar.gz 38743434 BLAKE2B 294eaaf95c7ff7a8ade8bdf2146018856b081a9c461aca68eedb6fb096d253e537f41ad9a81687cba7a9e42a34b5a3fe2d1a705917a1c96f47e1e3e708f20cc3 SHA512 b7d56d3286e3610ff0db4f4c3a51f953825578532a9c518f7654142a644f466343660901632487fb513b0f6a6503d3716d56e733830b4d52daf5839bc1cfbdb5
+DIST visp-3.2.0.tar.gz 52737424 BLAKE2B 78b733183a62541f5d5af22a376ac52ba2377753fa53be62858611b27d961fad286923c11f624c4fe0f561d8dbc5367e2ac01e6bc11a2a19068167ef52198307 SHA512 b4ad21e5063327d91d4ebda268cf4a4dc2ceffbe39d6af0dd6bfeb94d1150884d37fc4ea4295f640135fc2ba758afd29b9090755561ef05249fe2cbc5680dcce

diff --git a/sci-libs/ViSP/ViSP-3.2.0.ebuild b/sci-libs/ViSP/ViSP-3.2.0.ebuild
new file mode 100644 (file)
index 0000000..e6404f3
--- /dev/null
+++ b/sci-libs/ViSP/ViSP-3.2.0.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+inherit cmake-utils
+
+DESCRIPTION="Visual Servoing Platform: visual tracking and visual servoing library"
+HOMEPAGE="http://www.irisa.fr/lagadic/visp/visp.html"
+SRC_URI="http://gforge.inria.fr/frs/download.php/latestfile/475/visp-${PV}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0/3.2"
+KEYWORDS="~amd64 ~arm"
+IUSE="
+       +coin demos +dmtx doc examples gsl ieee1394 jpeg lapack motif ogre
+       opencv png test tutorials usb v4l X xml +zbar zlib
+       cpu_flags_x86_sse2 cpu_flags_x86_sse3 cpu_flags_x86_ssse3
+"
+
+RDEPEND="
+       coin? ( media-libs/coin virtual/opengl )
+       dmtx? ( media-libs/libdmtx )
+       gsl? ( sci-libs/gsl )
+       ieee1394? ( media-libs/libdc1394 )
+       jpeg? ( virtual/jpeg:0 )
+       lapack? ( virtual/lapack )
+       motif? ( media-libs/SoXt )
+       ogre? ( dev-games/ogre[ois(+)] dev-libs/boost:=[threads] )
+       opencv? ( media-libs/opencv:= )
+       png? ( media-libs/libpng:0= )
+       usb? ( virtual/libusb:1 )
+       v4l? ( media-libs/libv4l )
+       X? ( x11-libs/libX11 )
+       xml? ( dev-libs/libxml2 )
+       zbar? ( media-gfx/zbar )
+       zlib? ( sys-libs/zlib )
+"
+DEPEND="${RDEPEND}
+       virtual/pkgconfig
+       doc? ( app-doc/doxygen virtual/latex-base media-gfx/graphviz )
+       test? ( sci-misc/ViSP-images )
+       v4l? ( virtual/os-headers )"
+RDEPEND="${RDEPEND}
+       demos? ( sci-misc/ViSP-images )"
+REQUIRED_USE="motif? ( coin )"
+
+S="${WORKDIR}/visp-${PV}"
+PATCHES=( "${FILESDIR}/${PN}-3.0.1-opencv.patch" )
+
+src_configure() {
+       local mycmakeargs=(
+               "-DBUILD_EXAMPLES=$(usex examples ON OFF)"
+               "-DBUILD_TESTS=$(usex test ON OFF)"
+               "-DBUILD_DEMOS=$(usex demos ON OFF)"
+               "-DBUILD_TUTORIALS=$(usex tutorials ON OFF)"
+               "-DUSE_COIN3D=$(usex coin ON OFF)"
+               "-DUSE_DC1394=$(usex ieee1394 ON OFF)"
+               "-DUSE_DMTX=$(usex dmtx ON OFF)"
+               "-DUSE_GSL=$(usex gsl ON OFF)"
+               "-DUSE_LAPACK=$(usex lapack ON OFF)"
+               "-DUSE_JPEG=$(usex jpeg ON OFF)"
+               "-DUSE_PNG=$(usex png ON OFF)"
+               "-DUSE_LIBUSB_1=$(usex usb ON OFF)"
+               "-DUSE_OGRE=$(usex ogre ON OFF)"
+               "-DUSE_OIS=$(usex ogre ON OFF)"
+               "-DUSE_OPENCV=$(usex opencv ON OFF)"
+               "-DUSE_SOQT=OFF"
+               "-DUSE_SOXT=$(usex motif ON OFF)"
+               "-DUSE_V4L2=$(usex v4l ON OFF)"
+               "-DUSE_X11=$(usex X ON OFF)"
+               "-DUSE_XML2=$(usex xml ON OFF)"
+               "-DUSE_ZBAR=$(usex zbar ON OFF)"
+               "-DUSE_ZLIB=$(usex zlib ON OFF)"
+               "-DCOIN3D_INCLUDE_DIR=${EPREFIX:-${SYSROOT}}/usr/include/coin"
+               "-DSOQT_INCLUDE_DIR=${EPREFIX:-${SYSROOT}}/usr/include/coin"
+               "-DENABLE_SSE2=$(usex cpu_flags_x86_sse2 ON OFF)"
+               "-DENABLE_SSE3=$(usex cpu_flags_x86_sse3 ON OFF)"
+               "-DENABLE_SSSE3=$(usex cpu_flags_x86_ssse3 ON OFF)"
+       )
+       cmake-utils_src_configure
+}
+
+src_compile() {
+       cmake-utils_src_compile
+       cd "${BUILD_DIR}"
+       use doc && emake visp_doc
+}
+
+src_install() {
+       cmake-utils_src_install
+       if use tutorials ; then
+               dodoc -r tutorial
+               docompress -x /usr/share/doc/${PF}/tutorial
+       fi
+       cd "${BUILD_DIR}"
+       use doc && dohtml -r doc/html/*
+}