net-p2p/gtk-gnutella: add 1.1.12

Package-Manager: Portage-2.3.8, Repoman-2.3.3

diff --git a/net-p2p/gtk-gnutella/Manifest b/net-p2p/gtk-gnutella/Manifest
index 99081bd7aefa428cc98964d58b5607cda485cc5c..6dfabf3125f2159b8217fadd3743990f00bc26d5 100644 (file)
--- a/net-p2p/gtk-gnutella/Manifest
+++ b/net-p2p/gtk-gnutella/Manifest
@@ -1 +1,2 @@
 DIST gtk-gnutella-1.1.11.tar.bz2 19966423 SHA256 e46ffa3905831828f867709aa346cd88576075bd1299ef396962ad860e2589d5 SHA512 87d2d66b555180c0db7c360106377133b9e1f8ad8d28fc0f9a38498f3b4502a817650f9683cf92919b7d3a1b3602f7136143d2f1c920e10727576c703e233d07 WHIRLPOOL d70a4dd39ac25856fd3fbe4b4d4f2447f1ed8448e672fb64ab1e66bcc59a2e36b30112db0123aed1b52a6fa00c274d17ac47bb2ac9a775182516558e9d38dd08
+DIST gtk-gnutella-1.1.12.tar.bz2 20075956 SHA256 ca65f9c56a5e17e6cb84246d5e2db453f1c73863ef937b8a1772ff4572d562ff SHA512 3b95f66389ed45f45ff8cc1c5f4eda0d03d5a4060a083f23fd5318ec004c3e96a37a6909688828cd8de97067d18280cc533146ce6de2129c83f9aeb8a3c5a589 WHIRLPOOL a7efc554ee6aad289444aa59e73ed4b0b7701c7a87a98b2f9cd45ef1439fe53cfa8d4f9722854ea90600d37e225e3be80533971f056d9ef831fec0b151629218

diff --git a/net-p2p/gtk-gnutella/gtk-gnutella-1.1.12.ebuild b/net-p2p/gtk-gnutella/gtk-gnutella-1.1.12.ebuild
new file mode 100644 (file)
index 0000000..6cbf0a7
--- /dev/null
+++ b/net-p2p/gtk-gnutella/gtk-gnutella-1.1.12.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils
+
+IUSE="nls dbus ssl +gtk"
+
+DESCRIPTION="A GTK+ Gnutella client"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+HOMEPAGE="http://gtk-gnutella.sourceforge.net/"
+
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~ppc ~x86 ~x86-fbsd"
+
+RDEPEND="
+       sys-libs/binutils-libs:=
+       dev-libs/glib:2
+       sys-libs/zlib
+       gtk? ( >=x11-libs/gtk+-2.2.1:2 )
+       dbus? ( >=sys-apps/dbus-0.35.2 )
+       ssl? ( >=net-libs/gnutls-2.2.5 )
+       nls? ( >=sys-devel/gettext-0.11.5 )"
+DEPEND="${RDEPEND}
+       virtual/pkgconfig"
+
+src_prepare() {
+       strip-linguas -i po
+
+       echo "# Gentoo-selected LINGUAS" > po/LINGUAS
+       for ling in ${LINGUAS}; do
+               echo $ling >> po/LINGUAS
+       done
+
+       default
+}
+
+src_configure() {
+       # There is no option to turn off optimization through the build.sh
+       # script.
+       sed -i -e "s/Configure -Oder/Configure -Oder -Doptimize=none/" build.sh || die
+
+       # The build script does not support the equivalent --enable
+       # options so we must construct the configuration by hand.
+
+       local myconf
+
+       if ! use nls; then
+               myconf="${myconf} --disable-nls"
+       fi
+
+       if ! use dbus; then
+               myconf="${myconf} --disable-dbus"
+       fi
+
+       if ! use ssl; then
+               myconf="${myconf} --disable-gnutls"
+       fi
+
+       if use gtk; then
+               myconf="${myconf} --gtk2"
+       else
+               myconf="${myconf} --topless"
+       fi
+
+       ./build.sh \
+               --configure-only \
+               --prefix="/usr" \
+               --cc=$(tc-getCC) \
+               ${myconf}
+}
+
+src_compile() {
+       # Build system is not parallel-safe, bug 500760
+       emake -j1
+}
+
+src_install() {
+       dodir /usr/bin
+       emake INSTALL_PREFIX="${D}" install || die "Install failed"
+       dodoc AUTHORS ChangeLog README TODO
+
+       # Touch the symbols file into the future to avoid warnings from
+       # gtk-gnutella later on, since we will most likely strip the binary.
+       touch --date="next minute" "${D}/usr/lib/gtk-gnutella/gtk-gnutella.nm" || die
+}