dev-qt/qtwidgets: Add KDE (krita) upstream recommended backport

See also: https://mail.kde.org/pipermail/distributions/2019-April/000317.html

Package-Manager: Portage-2.3.76, Repoman-2.3.17
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

diff --git a/dev-qt/qtwidgets/qtwidgets-5.12.5-r1.ebuild b/dev-qt/qtwidgets/qtwidgets-5.12.5-r1.ebuild
new file mode 100644 (file)
index 0000000..57de535
--- /dev/null
+++ b/dev-qt/qtwidgets/qtwidgets-5.12.5-r1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+QT5_MODULE="qtbase"
+inherit qt5-build
+
+DESCRIPTION="Set of components for creating classic desktop-style UIs for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+       KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd"
+fi
+
+# keep IUSE defaults in sync with qtgui
+IUSE="gles2 gtk +png +xcb"
+
+DEPEND="
+       ~dev-qt/qtcore-${PV}
+       ~dev-qt/qtgui-${PV}[gles2=,png=,xcb?]
+       gtk? (
+               ~dev-qt/qtgui-${PV}[dbus]
+               x11-libs/gtk+:3
+               x11-libs/libX11
+               x11-libs/pango
+       )
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+       src/tools/uic
+       src/widgets
+       src/plugins/platformthemes
+)
+
+QT5_GENTOO_CONFIG=(
+       gtk:gtk3:
+       ::widgets
+       !:no-widgets:
+)
+
+QT5_GENTOO_PRIVATE_CONFIG=(
+       :widgets
+)
+
+PATCHES+=(
+       # Still pending: https://codereview.qt-project.org/c/qt/qtbase/+/255384
+       "${FILESDIR}/${PN}-5.12.4-synth-enterleaveEvent-for-accepted-QTabletEvent.patch"
+)
+
+src_configure() {
+       local myconf=(
+               -opengl $(usex gles2 es2 desktop)
+               $(qt_use gtk)
+               -gui
+               $(qt_use png libpng system)
+               -widgets
+               $(qt_use xcb xcb system)
+               $(usex xcb '-xcb-xlib -xcb-xinput -xkb -xkbcommon' '')
+       )
+       qt5-build_src_configure
+}