net-irc/quassel-irssi: revbump old vers, fix CFLAGS, CC

Package-Manager: Portage-2.3.3, Repoman-2.3.1

diff --git a/net-irc/quassel-irssi/quassel-irssi-0_p20160412-r1.ebuild b/net-irc/quassel-irssi/quassel-irssi-0_p20160412-r1.ebuild
new file mode 100644 (file)
index 0000000..c564e45
--- /dev/null
+++ b/net-irc/quassel-irssi/quassel-irssi-0_p20160412-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit toolchain-funcs
+
+# https://github.com/phhusson/quassel-irssi/pull/10 if accepted will
+# allow QuasselC to be installed as a separate package.
+QC_VER="0_p20150406"
+
+DESCRIPTION="Irssi module to connect to Quassel cores."
+HOMEPAGE="https://github.com/phhusson/quassel-irssi/"
+SRC_URI="https://dev.gentoo.org/~wraeth/distfiles/${P}.tar.gz
+       https://dev.gentoo.org/~wraeth/distfiles/quasselc-${QC_VER}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="net-irc/irssi"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+       mv "${WORKDIR}"/quasselc-"${QC_VER}"/* "${S}"/core/lib/ || die
+       default
+
+       sed -e 's:^CFLAGS=:CFLAGS+=$(IRSSI_CFLAGS) :' \
+               -e 's:gcc -shared:$(CC) -shared:' \
+               -e "s:pkg-config:$(tc-getPKG_CONFIG):" \
+               -i "${S}/core/Makefile" || die
+
+       tc-export CC
+}
+
+src_compile() {
+       emake IRSSI_LIB="${ROOT}/usr/$(get_libdir)/irssi" -C core
+}
+
+src_install() {
+       emake DESTDIR="${D}" LIBDIR="${ROOT}usr/$(get_libdir)" -C core install
+       default
+}
+
+pkg_postinst() {
+       elog "Note that this requires additional configuration of your irssi client. See"
+       elog "    ${ROOT}usr/share/doc/${P}/README.md.bz2'"
+       elog "for instructions."
+}