dev-ruby/charlock_holmes: add 0.7.6

Package-Manager: Portage-2.3.24, Repoman-2.3.6

diff --git a/dev-ruby/charlock_holmes/Manifest b/dev-ruby/charlock_holmes/Manifest
index ed310850910331fb402cd0cbb0d10c8d6e207239..b237f6ad8240e86b7cd9deeb2283057c911ab9b4 100644 (file)
--- a/dev-ruby/charlock_holmes/Manifest
+++ b/dev-ruby/charlock_holmes/Manifest
@@ -1 +1,2 @@
 DIST charlock_holmes-0.7.5.tar.gz 1192676 BLAKE2B d1e5bb3089d32ef7efa46fe54d37c71caa75b5d3a059c45d1d0275014822690031a8df894295e72be11be5ca685e90f35832dd6a06a4c482afe938da2a25ea28 SHA512 a5ee9d47d8c8386e7be9ad10e93e7bd7663713df285b33e5d8afd865570e463a9f785e568675363f9b949a8207bbcc144a7378dfb206645824e9f0abc33ec668
+DIST charlock_holmes-0.7.6.tar.gz 1192708 BLAKE2B 9024238f225e7c5040c0550beb573615939037e0113672d7d048a9abd536d8e1d224eb1c8f6a155906074394838888960e955d0318c47fa2e1330e46275f4e99 SHA512 410a210e4fc7e9905f38e3f68375ffdf0cf73cca8a8b230d7c4165ac23503e2460692168b1eb5d69ff183e70d89e5dcfbf6688dd22b736f4adf3c9f3af18575b

diff --git a/dev-ruby/charlock_holmes/charlock_holmes-0.7.6.ebuild b/dev-ruby/charlock_holmes/charlock_holmes-0.7.6.ebuild
new file mode 100644 (file)
index 0000000..b9bbacc
--- /dev/null
+++ b/dev-ruby/charlock_holmes/charlock_holmes-0.7.6.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+USE_RUBY="ruby22 ruby23 ruby24 ruby25"
+
+RUBY_FAKEGEM_RECIPE_DOC="rdoc"
+RUBY_FAKEGEM_EXTRADOC="README.md"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Character encoding detecting library for Ruby using ICU"
+HOMEPAGE="https://github.com/brianmario/charlock_holmes"
+SRC_URI="https://github.com/brianmario/charlock_holmes/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+
+ruby_add_bdepend "test? (
+       dev-ruby/minitest )"
+
+CDEPEND="dev-libs/icu:=
+               sys-libs/zlib"
+DEPEND+=" ${CDEPEND}"
+RDEPEND+=" ${CDEPEND}"
+
+all_ruby_prepare() {
+       sed -i -e '/bundler/d' test/helper.rb || die
+
+       # Avoid dependency on rake-compiler
+       sed -i -e '/rake-compiler/,$ s:^:#:' Rakefile || die
+}
+
+each_ruby_configure() {
+       ${RUBY} -Cext/${PN} extconf.rb || die
+}
+
+each_ruby_compile() {
+       emake V=1 -Cext/${PN}
+       cp ext/${PN}/${PN}$(get_modname) lib/${PN}/ || die
+}
+
+each_ruby_test() {
+       ${RUBY} -Ilib test/*.rb || die
+}