sys-block/fio: Version bump & bug #572446.

- Version bump.
- Fix bug #572446: USE=static builds, the deps need to be build with
  USE=static-libs, or else the build will fail (backported change to
  last stable as well, as also affected).

X-Gentoo-Bug: 572446
Package-Manager: portage-2.2.24
Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>

diff --git a/sys-block/fio/Manifest b/sys-block/fio/Manifest
index 89185efae6a36c25f3b5c8eef457fdf2b8c55d21..5fca220072fcdbcaa56f5ec8c0da8024c39c626b 100644 (file)
--- a/sys-block/fio/Manifest
+++ b/sys-block/fio/Manifest
@@ -4,5 +4,7 @@ DIST fio-2.0.14.tar.bz2 253574 SHA256 4bf01f1d2baf6d4fa905e5489e446e85e01979c427
 DIST fio-2.0.15.tar.bz2 258773 SHA256 3cc1b5e6c6955f9acad016b4d2ef619061ad9937874c7663e2a29777ed845ac4 SHA512 00289a0404cb44dd670614856932fbdf61cb1508e0eb672e5778c2ba3eba661b82892f7c969e4a82cf4fc487a744eb7411bfebf3b9612863de0197a28787f556 WHIRLPOOL 08b37573b63f812ea62c4ba323f05f510a9656e74f780117bd711bcc78e7fc7b5bef009212e7ec98f0ed153cc3786ece4d75d565845c0bc5eaba59afa1b037d8
 DIST fio-2.1.9.tar.bz2 429122 SHA256 4ae877939a1a1460ad4d93f7891a15bad8ca7295f441204b12c723758a0d4493 SHA512 91913941c0d83705c156eef550eb87b388368804ee722c8c99ea638481ee657960e333c58b54e720034e92c2c34e9a8bb901336399a209a87f5eaa1ad1dfde53 WHIRLPOOL 6f44cbfe601f436b1ed0173e1dfbcf3b342f1a191c947392f0167a2dba9c4806fa422ffaedf9475f83b49fab8832aa1076ba91d27a9f2bdbcae126fa4d708824
 DIST fio-2.2.10.tar.bz2 497503 SHA256 04b4490c69f82bafeccbab51d33732cfd74e7a54e74eae0d9a2450faf4f1d857 SHA512 6ff71ca78b2ffa40cd9390b3e4f0b6f07db4d50c85f89c4a9e03c7f327153c0fed3eb8b7c44f3a8f8d0b1b35b48ccb5b1aa96a95fdca08581c22b99f2961c7d3 WHIRLPOOL 7bb881ecea82f3ad568d7513af0486494dc657ede69cc4de0f71e7bdf873ccf8f7a58744ab8f1fce8a1c507c3ce0f7e95eb3a7098a01fe041f04cd29a6a4afb7
+DIST fio-2.2.13.tar.bz2 503950 SHA256 66a0084c37bd8804d9f7d260d843a9a3bf51561954024d3b32062b9332281924 SHA512 b2adc4fb1b8c71bb909cfc2cfd9e0d25affcacd47908bc6d126625b448c0e964afa7c65fb88cf21662d4b9d07bfbaebbb2fd66b4c4662382ef68aaf8f053bd6d WHIRLPOOL 112af8620a73e907723760fd01caa4c582f7adba5eef5bf51bb6b695c1a15ff812957937cb67dff00b93c3e941df67d751ecf1aca1627722a6084c5494e7f70a
 DIST fio-2.2.4.tar.bz2 467312 SHA256 9e1c77216457d9e21e418a55fa28bc1f98c283723fe9dcccff6138e3fb25285b SHA512 91fa0d8f9dd8d950dd26ef5c778414acddd9d6deeb84caeecdfef08df7e00c7972566a76bd242b0d5aea33a7c588aa05cf2fdcd79ef5a475277a2139d1f111a1 WHIRLPOOL 4588601d5f44c1836f97cc223bf08cce3f29f5ea3421880c00a16dcd9e3cffd741bbdd2029518712f8808548469d7f44f1b0348189643419bfd2104eab980536
 DIST fio-2.2.9.tar.bz2 492404 SHA256 c881d9cf15500bd4436970d0467c356c5c021417131587931ba78845e965bf56 SHA512 e0cd26bb8a760ef5e40ddb73246671c1988f0c0886bd24fa510fcab93fe64d8853f120355f55fa109168c7fae0b081f63278f2233644f5ed20da4e4c3cb3f3fc WHIRLPOOL 4f5ada7f1140c7229fc3173fa0582a4ae7401121768d8dec828dcd42c1c22ec828e9c000c482b155ead4fd75ee15c4d7678fc7c6d18c8fbb9c749e83f87a4881
+DIST fio-2.5.tar.bz2 509978 SHA256 30f85cd6596125bd2f76b379f15a4edee1149bb0347a9c10a2dda15d7591a543 SHA512 44fc4bc342b611f9ed89685d73592389dd9e63970a9bbcc1b332aa8434a3e4a52b0c16d27b6a6dd96fcf3a9831a68af5249251895a6dbd9f7190ad0b8935eb40 WHIRLPOOL dced416aae899987ff80c6f37999a064d8a45c8ea809d7a3f3a2eea5dd3b6ae5633125326373a5da3b37429dc940f0c97fa9694e976a61819709db3b6ab7ac3e

diff --git a/sys-block/fio/fio-2.2.10.ebuild b/sys-block/fio/fio-2.2.10.ebuild
index 82955436697f1e6eb155c5493bf11ca031c5674f..1d6b7d4b20eac2ac684b2e11219728fc410ef543 100644 (file)
--- a/sys-block/fio/fio-2.2.10.ebuild
+++ b/sys-block/fio/fio-2.2.10.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2015 Gentoo Foundation
+# Copyright 1999-2016 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 # $Id$
 
@@ -18,15 +18,17 @@ SLOT="0"
 KEYWORDS="~amd64 ~arm ~ia64 ~ppc ~ppc64 ~x86"
 IUSE="aio glusterfs gnuplot gtk numa rbd rdma static zlib"
 
-DEPEND="aio? ( dev-libs/libaio )
-       glusterfs? ( sys-cluster/glusterfs )
+# GTK+:2 does not offer static libaries
+# numactl always includes static libraries
+DEPEND="aio? ( static? ( dev-libs/libaio[static-libs(+)] ) !static? ( dev-libs/libaio ) )
+       glusterfs? ( static? ( sys-cluster/glusterfs[static-libs(+)] ) !static? ( sys-cluster/glusterfs ) )
        gtk? (
-               dev-libs/glib:2
+               static? ( dev-libs/glib:2[static-libs(+)] ) !static? ( dev-libs/glib:2 )
                x11-libs/gtk+:2
        )
        numa? ( sys-process/numactl )
-       rbd? ( sys-cluster/ceph )
-       zlib? ( sys-libs/zlib )"
+       rbd? ( static? ( sys-cluster/ceph[static-libs(+)] ) !static? ( sys-cluster/ceph ) )
+       zlib? ( static? ( sys-libs/zlib[static-libs(+)] ) !static? ( sys-libs/zlib ) )"
 RDEPEND="${DEPEND}
        gnuplot? (
                sci-visualization/gnuplot

diff --git a/sys-block/fio/fio-2.2.13.ebuild b/sys-block/fio/fio-2.2.13.ebuild
new file mode 100644 (file)
index 0000000..1d6b7d4
--- /dev/null
+++ b/sys-block/fio/fio-2.2.13.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+PYTHON_COMPAT=( python2_7 )
+inherit eutils python-r1 toolchain-funcs
+
+MY_PV="${PV/_rc/-rc}"
+MY_P="${PN}-${MY_PV}"
+
+DESCRIPTION="Jens Axboe's Flexible IO tester"
+HOMEPAGE="http://brick.kernel.dk/snaps/"
+SRC_URI="http://brick.kernel.dk/snaps/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ia64 ~ppc ~ppc64 ~x86"
+IUSE="aio glusterfs gnuplot gtk numa rbd rdma static zlib"
+
+# GTK+:2 does not offer static libaries
+# numactl always includes static libraries
+DEPEND="aio? ( static? ( dev-libs/libaio[static-libs(+)] ) !static? ( dev-libs/libaio ) )
+       glusterfs? ( static? ( sys-cluster/glusterfs[static-libs(+)] ) !static? ( sys-cluster/glusterfs ) )
+       gtk? (
+               static? ( dev-libs/glib:2[static-libs(+)] ) !static? ( dev-libs/glib:2 )
+               x11-libs/gtk+:2
+       )
+       numa? ( sys-process/numactl )
+       rbd? ( static? ( sys-cluster/ceph[static-libs(+)] ) !static? ( sys-cluster/ceph ) )
+       zlib? ( static? ( sys-libs/zlib[static-libs(+)] ) !static? ( sys-libs/zlib ) )"
+RDEPEND="${DEPEND}
+       gnuplot? (
+               sci-visualization/gnuplot
+               ${PYTHON_DEPS}
+       )"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+       sed -i '/^DEBUGFLAGS/s: -D_FORTIFY_SOURCE=2::g' Makefile || die
+       epatch_user
+
+       # Many checks don't have configure flags.
+       sed -i \
+               -e "s:\<pkg-config\>:$(tc-getPKG_CONFIG):" \
+               -e '/if compile_prog "" "-lz" "zlib" *; *then/  '"s::if $(usex zlib true false) ; then:" \
+               -e '/if compile_prog "" "-laio" "libaio" ; then/'"s::if $(usex aio true false) ; then:" \
+               configure || die
+}
+
+src_configure() {
+       chmod g-w "${T}"
+       # not a real configure script
+       set -- \
+       ./configure \
+               --disable-optimizations \
+               --extra-cflags="${CFLAGS} ${CPPFLAGS}" \
+               --cc="$(tc-getCC)" \
+               $(usex glusterfs '' '--disable-gfapi') \
+               $(usex gtk '--enable-gfio' '') \
+               $(usex numa '' '--disable-numa') \
+               $(usex rbd '' '--disable-rbd') \
+               $(usex static '--build-static' '')
+       echo "$@"
+       "$@" || die 'configure failed'
+}
+
+src_compile() {
+       emake V=1 OPTFLAGS=
+}
+
+src_install() {
+       emake install DESTDIR="${D}" prefix="${EPREFIX}/usr" mandir="${EPREFIX}/usr/share/man"
+
+       if use gnuplot ; then
+               python_replicate_script "${ED}/usr/bin/fio2gnuplot"
+       else
+               rm "${ED}"/usr/bin/{fio2gnuplot,fio_generate_plots} || die
+               rm "${ED}"/usr/share/man/man1/{fio2gnuplot,fio_generate_plots}.1 || die
+               rm "${ED}"/usr/share/fio/*.gpm || die
+               rmdir "${ED}"/usr/share/fio/ 2>/dev/null
+       fi
+
+       # This tool has security/parallel issues -- it hardcodes /tmp/template.fio.
+       rm "${ED}"/usr/bin/genfio || die
+
+       dodoc README REPORTING-BUGS HOWTO
+       docinto examples
+       dodoc examples/*
+}

diff --git a/sys-block/fio/fio-2.2.9.ebuild b/sys-block/fio/fio-2.2.9.ebuild
index 8f3560078ce655967b9ae3942a7589e519b58c33..7010f30399c9b0b85b7831861d4178c80d52dc41 100644 (file)
--- a/sys-block/fio/fio-2.2.9.ebuild
+++ b/sys-block/fio/fio-2.2.9.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2015 Gentoo Foundation
+# Copyright 1999-2016 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 # $Id$
 
@@ -18,15 +18,17 @@ SLOT="0"
 KEYWORDS="amd64 arm ia64 ppc ppc64 x86"
 IUSE="aio glusterfs gnuplot gtk numa rbd rdma static zlib"
 
-DEPEND="aio? ( dev-libs/libaio )
-       glusterfs? ( sys-cluster/glusterfs )
+# GTK+:2 does not offer static libaries
+# numactl always includes static libraries
+DEPEND="aio? ( static? ( dev-libs/libaio[static-libs(+)] ) !static? ( dev-libs/libaio ) )
+       glusterfs? ( static? ( sys-cluster/glusterfs[static-libs(+)] ) !static? ( sys-cluster/glusterfs ) )
        gtk? (
-               dev-libs/glib:2
+               static? ( dev-libs/glib:2[static-libs(+)] ) !static? ( dev-libs/glib:2 )
                x11-libs/gtk+:2
        )
        numa? ( sys-process/numactl )
-       rbd? ( sys-cluster/ceph )
-       zlib? ( sys-libs/zlib )"
+       rbd? ( static? ( sys-cluster/ceph[static-libs(+)] ) !static? ( sys-cluster/ceph ) )
+       zlib? ( static? ( sys-libs/zlib[static-libs(+)] ) !static? ( sys-libs/zlib ) )"
 RDEPEND="${DEPEND}
        gnuplot? (
                sci-visualization/gnuplot

diff --git a/sys-block/fio/fio-2.5.ebuild b/sys-block/fio/fio-2.5.ebuild
new file mode 100644 (file)
index 0000000..1d6b7d4
--- /dev/null
+++ b/sys-block/fio/fio-2.5.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+PYTHON_COMPAT=( python2_7 )
+inherit eutils python-r1 toolchain-funcs
+
+MY_PV="${PV/_rc/-rc}"
+MY_P="${PN}-${MY_PV}"
+
+DESCRIPTION="Jens Axboe's Flexible IO tester"
+HOMEPAGE="http://brick.kernel.dk/snaps/"
+SRC_URI="http://brick.kernel.dk/snaps/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ia64 ~ppc ~ppc64 ~x86"
+IUSE="aio glusterfs gnuplot gtk numa rbd rdma static zlib"
+
+# GTK+:2 does not offer static libaries
+# numactl always includes static libraries
+DEPEND="aio? ( static? ( dev-libs/libaio[static-libs(+)] ) !static? ( dev-libs/libaio ) )
+       glusterfs? ( static? ( sys-cluster/glusterfs[static-libs(+)] ) !static? ( sys-cluster/glusterfs ) )
+       gtk? (
+               static? ( dev-libs/glib:2[static-libs(+)] ) !static? ( dev-libs/glib:2 )
+               x11-libs/gtk+:2
+       )
+       numa? ( sys-process/numactl )
+       rbd? ( static? ( sys-cluster/ceph[static-libs(+)] ) !static? ( sys-cluster/ceph ) )
+       zlib? ( static? ( sys-libs/zlib[static-libs(+)] ) !static? ( sys-libs/zlib ) )"
+RDEPEND="${DEPEND}
+       gnuplot? (
+               sci-visualization/gnuplot
+               ${PYTHON_DEPS}
+       )"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+       sed -i '/^DEBUGFLAGS/s: -D_FORTIFY_SOURCE=2::g' Makefile || die
+       epatch_user
+
+       # Many checks don't have configure flags.
+       sed -i \
+               -e "s:\<pkg-config\>:$(tc-getPKG_CONFIG):" \
+               -e '/if compile_prog "" "-lz" "zlib" *; *then/  '"s::if $(usex zlib true false) ; then:" \
+               -e '/if compile_prog "" "-laio" "libaio" ; then/'"s::if $(usex aio true false) ; then:" \
+               configure || die
+}
+
+src_configure() {
+       chmod g-w "${T}"
+       # not a real configure script
+       set -- \
+       ./configure \
+               --disable-optimizations \
+               --extra-cflags="${CFLAGS} ${CPPFLAGS}" \
+               --cc="$(tc-getCC)" \
+               $(usex glusterfs '' '--disable-gfapi') \
+               $(usex gtk '--enable-gfio' '') \
+               $(usex numa '' '--disable-numa') \
+               $(usex rbd '' '--disable-rbd') \
+               $(usex static '--build-static' '')
+       echo "$@"
+       "$@" || die 'configure failed'
+}
+
+src_compile() {
+       emake V=1 OPTFLAGS=
+}
+
+src_install() {
+       emake install DESTDIR="${D}" prefix="${EPREFIX}/usr" mandir="${EPREFIX}/usr/share/man"
+
+       if use gnuplot ; then
+               python_replicate_script "${ED}/usr/bin/fio2gnuplot"
+       else
+               rm "${ED}"/usr/bin/{fio2gnuplot,fio_generate_plots} || die
+               rm "${ED}"/usr/share/man/man1/{fio2gnuplot,fio_generate_plots}.1 || die
+               rm "${ED}"/usr/share/fio/*.gpm || die
+               rmdir "${ED}"/usr/share/fio/ 2>/dev/null
+       fi
+
+       # This tool has security/parallel issues -- it hardcodes /tmp/template.fio.
+       rm "${ED}"/usr/bin/genfio || die
+
+       dodoc README REPORTING-BUGS HOWTO
+       docinto examples
+       dodoc examples/*
+}