media-sound/whipper: bump version to 0.9.0

Closes: https://bugs.gentoo.org/702002
Package-Manager: Portage-2.3.79, Repoman-2.3.16
Signed-off-by: Quentin Retornaz <gentoo@retornaz.com>
Closes: https://github.com/gentoo/gentoo/pull/13925
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

diff --git a/media-sound/whipper/Manifest b/media-sound/whipper/Manifest
index abf3fbecc5cf0d4dde60a225b43dc64eee465933..45df92ca84192f1d0db32a319b758a7850ec44c4 100644 (file)
--- a/media-sound/whipper/Manifest
+++ b/media-sound/whipper/Manifest
@@ -1 +1,2 @@
 DIST whipper-0.7.3.tar.gz 168393 BLAKE2B b34151ede7c867dbbca34fcec3d8ef81cb50d66abc760fa54bec880f8f1186faf3e0f5298c2890501b9bd2f586b80d2cdc45a0755b6fe12fc1a2215e9ea9ecbb SHA512 ac96393471a6b4c40f5870f6e3183b65d43229314e2a1eacbf065c51ac61cbc772f2de3bde9f20ee1f7ffec427cd03c31f27df60eb6c621a699927646080c0ab
+DIST whipper-0.9.0.tar.gz 200836 BLAKE2B 197567d476bcfa448bee7d6ba2d1b980355f792e6591840d1291800c3ae205496dc58579394870adf171f11f31d7042b48d070cf03d203e45e7c369500c500ef SHA512 49e66ad2c6e8450199a53a28bb71725704daac86ce2cbf68080d4dee1c2357cf8367ddb4735a07f2ffe612d84f016661e5b6f94efa9d5a7d6b8cf56ee32b0ae7

diff --git a/media-sound/whipper/whipper-0.9.0.ebuild b/media-sound/whipper/whipper-0.9.0.ebuild
new file mode 100644 (file)
index 0000000..f29364e
--- /dev/null
+++ b/media-sound/whipper/whipper-0.9.0.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7} )
+
+inherit distutils-r1
+
+DESCRIPTION="A Python CD-DA ripper preferring accuracy over speed (forked from morituri)"
+HOMEPAGE="https://github.com/whipper-team/whipper"
+SRC_URI="https://github.com/whipper-team/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT+=" !test? ( test )"
+
+BDEPEND="test? ( dev-python/twisted[${PYTHON_USEDEP}] )"
+COMMON_DEPEND="media-libs/libsndfile"
+DEPEND="${COMMON_DEPEND}"
+RDEPEND="
+       ${COMMON_DEPEND}
+       app-cdr/cdrdao
+       >=dev-libs/libcdio-paranoia-0.94_p2
+       >=dev-python/pycdio-2.1.0[${PYTHON_USEDEP}]
+       dev-python/pygobject:=[${PYTHON_USEDEP}]
+       dev-python/python-musicbrainz-ngs[${PYTHON_USEDEP}]
+       dev-python/requests[${PYTHON_USEDEP}]
+       dev-python/ruamel-yaml[${PYTHON_USEDEP}]
+       dev-python/setuptools[${PYTHON_USEDEP}]
+       media-libs/mutagen[${PYTHON_USEDEP}]
+       media-sound/sox[flac]
+"
+
+PATCHES=(
+       "${FILESDIR}/${PN}-0.7.0-cdparanoia-name-fix.patch"
+       "${FILESDIR}/${PN}-0.7.0-src-Makefile-respect-CFLAGS.patch"
+)
+
+python_prepare_all() {
+       # accurip test totally depends on network access
+       rm "${PN}"/test/test_common_accurip.py || die
+
+       distutils-r1_python_prepare_all
+}
+
+src_compile() {
+       distutils-r1_src_compile
+       emake -C src CC="$(tc-getCC)"
+}
+
+python_test() {
+       "${EPYTHON}" -m unittest discover -v || die "Tests fail with ${EPYTHON}"
+}
+
+src_install() {
+       distutils-r1_src_install
+       emake PREFIX="${EPREFIX}/usr" DESTDIR="${D}" -C src install
+}