app-misc/solaar: Ensure python_prepare_all() is called

Package-Manager: Portage-2.3.79, Repoman-2.3.16
Signed-off-by: Chris Mayo <aklhfex@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/14078
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

diff --git a/app-misc/solaar/solaar-1.0.1-r1.ebuild b/app-misc/solaar/solaar-1.0.1-r1.ebuild
new file mode 100644 (file)
index 0000000..94e1cd0
--- /dev/null
+++ b/app-misc/solaar/solaar-1.0.1-r1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=no
+PYTHON_COMPAT=( python2_7 python3_{5,6,7} )
+
+inherit linux-info udev xdg distutils-r1
+
+DESCRIPTION="A Linux device manager for Logitech's Unifying Receiver peripherals"
+HOMEPAGE="https://pwr-solaar.github.io/Solaar/"
+SRC_URI="https://github.com/pwr-Solaar/Solaar/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="doc"
+
+RDEPEND="
+       acct-group/plugdev
+       dev-python/pygobject:3[${PYTHON_USEDEP}]
+       >=dev-python/pyudev-0.13[${PYTHON_USEDEP}]
+       x11-libs/gtk+:3[introspection]"
+
+S="${WORKDIR}"/Solaar-${PV}
+
+CONFIG_CHECK="~HID_LOGITECH_DJ ~HIDRAW"
+
+python_prepare_all() {
+       # don't autostart (bug #494608)
+       sed -i '/yield autostart_path/d' setup.py || die
+
+       # grant plugdev group rw access
+       sed -i 's/#MODE=/MODE=/' rules.d/42-logitech-unify-permissions.rules || die
+
+       distutils-r1_python_prepare_all
+}
+
+python_install_all() {
+       distutils-r1_python_install_all
+
+       udev_dorules rules.d/*.rules
+
+       dodoc docs/devices.md
+       if use doc; then
+               dodoc -r docs/*
+       fi
+}