dev-libs/libnl: EAPI bump.

Package-Manager: Portage-2.3.43, Repoman-2.3.10

diff --git a/dev-libs/libnl/libnl-1.1.4-r1.ebuild b/dev-libs/libnl/libnl-1.1.4-r1.ebuild
new file mode 100644 (file)
index 0000000..2b9928f
--- /dev/null
+++ b/dev-libs/libnl/libnl-1.1.4-r1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit multilib toolchain-funcs
+
+DESCRIPTION="Libraries providing APIs to netlink protocol based Linux kernel interfaces"
+HOMEPAGE="http://www.infradead.org/~tgr/libnl/"
+SRC_URI="http://www.infradead.org/~tgr/libnl/files/${P}.tar.gz"
+LICENSE="LGPL-2.1"
+SLOT="1.1"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc static-libs"
+
+DEPEND="doc? ( app-doc/doxygen )"
+DOCS=( ChangeLog )
+PATCHES=(
+       "${FILESDIR}"/${PN}-1.1-vlan-header.patch
+       "${FILESDIR}"/${PN}-1.1-flags.patch
+       "${FILESDIR}"/${PN}-1.1.3-offsetof.patch
+)
+
+src_prepare() {
+       default
+
+       sed -i \
+               -e '/@echo/d' \
+               Makefile.rules {lib,src,tests}/Makefile || die
+       sed -i \
+               -e 's|-g ||g' \
+               Makefile.opts.in || die
+
+       if ! use static-libs; then
+               sed -i lib/Makefile -e '/OUT_AR/d' || die
+       fi
+
+       rm -f lib/libnl.a
+}
+
+src_compile() {
+       emake AR=$(tc-getAR)
+
+       if use doc ; then
+               cd "${S}/doc"
+               emake gendoc || die
+       fi
+}
+
+src_install() {
+       default
+
+       if use doc ; then
+               cd "${S}/doc"
+               docinto html
+               dodoc -r html/*
+       fi
+}