net-analyzer/ettercap: version bump to 0.8.3

Signed-off-by: Agostino Sarubbo <ago@gentoo.org>
Package-Manager: Portage-2.3.66, Repoman-2.3.11

diff --git a/net-analyzer/ettercap/Manifest b/net-analyzer/ettercap/Manifest
index 2eda4ae804a746b0824b88311dd09aedb61866cb..dccca758f8652d1e8354f95fd8ad56ca4f8e5a93 100644 (file)
--- a/net-analyzer/ettercap/Manifest
+++ b/net-analyzer/ettercap/Manifest
@@ -1 +1,2 @@
 DIST ettercap-0.8.2.tar.gz 8082561 BLAKE2B 851df0a8700de45ce0e3427f7fdbdcd13feb2f75c0d1136563449db634b1f02276bade0d82a1a51bf8de726d6faddf05ff537e397c2e56cfc3e3181d25566fe9 SHA512 18137b1cc518c9db3c9650157a5cbf09dbb665b79876a24875d6c5125e8923ebde543464adb61cf1d1244101242f4d66b80d94ef3b36aa265cefca7646aa6415
+DIST ettercap-0.8.3.tar.gz 8381943 BLAKE2B f49098d61f60877d3f979d7861f36dad6ec3fbfca7ed89d8f9826867145ea36daec65a1076c893f81391218688448515ef020a9cdf9a16ffddc830bacec8eb1c SHA512 1929c986d3a17ebc693ffe8531e01c66379c0ee6ea71305ea49b6a9eece84b6da1923135311db458bdb6035feb593e525786e6cf4c465ced5a7683384d4a4ae7

diff --git a/net-analyzer/ettercap/ettercap-0.8.3.ebuild b/net-analyzer/ettercap/ettercap-0.8.3.ebuild
new file mode 100644 (file)
index 0000000..12a0ca3
--- /dev/null
+++ b/net-analyzer/ettercap/ettercap-0.8.3.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils
+
+DESCRIPTION="A suite for man in the middle attacks"
+HOMEPAGE="https://github.com/Ettercap/ettercap"
+
+LICENSE="GPL-2+"
+SLOT="0"
+
+if [[ ${PV} == "9999" ]] ; then
+       inherit git-r3
+       EGIT_REPO_URI="https://github.com/Ettercap/${PN}.git"
+else
+       SRC_URI="https://github.com/Ettercap/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+       KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+fi
+
+IUSE="doc geoip gtk ipv6 libressl ncurses +plugins test"
+
+RDEPEND="dev-libs/libbsd
+       dev-libs/libpcre
+       !libressl? ( dev-libs/openssl:0= )
+       libressl? ( dev-libs/libressl:0= )
+       net-libs/libnet:1.1
+       >=net-libs/libpcap-0.8.1
+       sys-libs/zlib
+       geoip? ( dev-libs/geoip )
+       gtk? (
+               >=dev-libs/atk-1.2.4
+               >=dev-libs/glib-2.2.2:2
+               media-libs/freetype
+               x11-libs/cairo
+               x11-libs/gdk-pixbuf:2
+               >=x11-libs/gtk+-2.2.2:2
+               >=x11-libs/pango-1.2.3
+       )
+       ncurses? ( >=sys-libs/ncurses-5.3:= )
+       plugins? ( >=net-misc/curl-7.26.0 )"
+DEPEND="${RDEPEND}
+       doc? ( app-text/ghostscript-gpl
+               sys-apps/groff )
+       test? ( dev-libs/check )
+       sys-devel/flex
+       virtual/yacc"
+
+src_prepare() {
+       sed -i "s:Release:Release Gentoo:" CMakeLists.txt || die
+       cmake-utils_src_prepare
+}
+
+src_configure() {
+       local mycmakeargs=(
+               -DENABLE_CURSES="$(usex ncurses)"
+               -DENABLE_GTK="$(usex gtk)"
+               -DENABLE_PLUGINS="$(usex plugins)"
+               -DENABLE_IPV6="$(usex ipv6)"
+               -DENABLE_TESTS="$(usex test)"
+               -DENABLE_PDF_DOCS="$(usex doc)"
+               -DENABLE_GEOIP="$(usex geoip)"
+               -DBUNDLED_LIBS=OFF
+               -DSYSTEM_LIBS=ON
+               -DINSTALL_SYSCONFDIR="${EROOT}"etc
+       )
+               #right now we only support gtk2, but ettercap also supports gtk3
+               #do we care? do we want to support both?
+       cmake-utils_src_configure
+}