sci-libs/htslib: Version bump to 1.9

Bug: https://bugs.gentoo.org/647714
Signed-off-by: David Seifert <soap@gentoo.org>
Package-Manager: Portage-2.3.50, Repoman-2.3.11

diff --git a/sci-libs/htslib/Manifest b/sci-libs/htslib/Manifest
index 6841d0a69fb9d042ab58fc3b42441a474f027e84..e818f35f147365d02377685be04885c5e26d4e08 100644 (file)
--- a/sci-libs/htslib/Manifest
+++ b/sci-libs/htslib/Manifest
@@ -1 +1,2 @@
 DIST htslib-1.5.tar.bz2 1051132 BLAKE2B 90c6aeeaa2a2692228aa1f530d775a6e81f9275d321e8b2d6005b86b9a25e5967acca19dd898311a5bc4f3c17d4e8ea36d18da4602e18fadee47666350122077 SHA512 fd58552ddbd178f9797123fdaf47914ccd0e2aefd055fc6557ac8f479c600775616107cfa871c3acd93079f45974a19f443941a79f2acfd2a8c2983ef35b8917
+DIST htslib-1.9.tar.bz2 1178859 BLAKE2B a0229313d3572717101f4f23d39fa124f3bb38d8b2e65055f4f801dbb5f1549df95115e8beadd8fa024171b3ff8a874d20087bf71819c36700666f168dbe41ab SHA512 ddb0e2d970e4c2c27e203b064898f95cb7c187cd497c02fc7b4312dcea25669d0b6063d537687521e7a065f6daefa1ae897add2df4981037a187b499d08fdef7

diff --git a/sci-libs/htslib/htslib-1.9.ebuild b/sci-libs/htslib/htslib-1.9.ebuild
new file mode 100644 (file)
index 0000000..69df48a
--- /dev/null
+++ b/sci-libs/htslib/htslib-1.9.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="C library for high-throughput sequencing data formats"
+HOMEPAGE="http://www.htslib.org/"
+SRC_URI="mirror://sourceforge/samtools/${PV}/${P}.tar.bz2"
+
+SLOT="0/2"
+LICENSE="MIT"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="+bzip2 curl +lzma static-libs"
+
+RDEPEND="
+       bzip2? ( app-arch/bzip2:= )
+       curl? ( net-misc/curl )
+       lzma? ( app-arch/xz-utils:= )"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+       default
+
+       # upstream injects LDFLAGS into the .pc file,
+       # which is a big nono for QA
+       sed 's/private_LIBS=$LDFLAGS/private_LIBS=""/g' -i configure || die
+}
+
+src_configure() {
+       econf \
+               --disable-gcs \
+               --disable-plugins \
+               --disable-s3 \
+               $(use_enable bzip2 bz2) \
+               $(use_enable curl libcurl) \
+               $(use_enable lzma)
+}
+
+src_install() {
+       default
+
+       if ! use static-libs; then
+               find "${D}" -name '*.a' -delete || die
+       fi
+}