media-sound/audacious: 3.10.1 version bump, EAPI-7 bump

Switch gnome2-utils to xdg

Package-Manager: Portage-2.3.60, Repoman-2.3.12
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

diff --git a/media-sound/audacious/Manifest b/media-sound/audacious/Manifest
index f033188b17575009fbd5a0aa687950fb0507e516..f4dd0e94a85635a64966d572d483d9ea51789b74 100644 (file)
--- a/media-sound/audacious/Manifest
+++ b/media-sound/audacious/Manifest
@@ -1,3 +1,4 @@
+DIST audacious-3.10.1.tar.bz2 564481 BLAKE2B d1f76f34f0f6fbbe5ba92a95015fa0f3ef6399cc05f69f58474523761b00a4de7b8471660d9cb640487110cc3998df59f21108ff0b4ea72014ad75cd32ad864b SHA512 e88891caaa3897f9b4abf39136e20834aedf1287d0d5eefea392fda89050db8db00c6f363976a68fe250ddbae4e27590f7615916a76370a44ca9235f1fa60b43
 DIST audacious-3.10.tar.bz2 563531 BLAKE2B cde59bd5aff8e0530f76f3bdde20b48f829592a0a67cc03e8b7c08a8892259e99e9de2b1608698ff28819b7a6d0341d5237491f7591c4380566512076a0889b9 SHA512 513d5f9608c1ebeae9cf9bb95128244e990e66c74bf49aff6570ec557d537809f3ebf93c400f5df2708ff61cf04ecc95da183b111f5a757735cef5a68dd9907f
 DIST audacious-3.9-gtk3.tar.bz2 600249 BLAKE2B 08559eafc85236e8e881d0cbe6f08e29c82baf0fc46b9209f1d3eee290460260bfa99e6e8f26940f8c6854f3782da24061226ebdb416b6249d10914093e16276 SHA512 6ff98d027c13b30ea9600a9aba914ec993c69826199b8dc303cb60cebdf2af06a7e3dd4af1d34a86343be5485848a57c8a29e48d2a45a33945585550de4e5f9c
 DIST gentoo_ice-xmms-0.2.tar.bz2 51839 BLAKE2B d3bf8dbfee675dd588bc0258f1015c76877b6b0a3835813d8e9621d149b924aaa33544d07f7ad44a01c058d41d7480b3908b0773c124af33b6e020c376b13d54 SHA512 e863a8f86073007c47ce8c20739aae4bff22e22a7ddc11556b12ae6ebb68654cec7310fdc9d05f2c47f81cf2591fe601b2eb12a2fd911c0a6118c9f3cc524f05

diff --git a/media-sound/audacious/audacious-3.10.1.ebuild b/media-sound/audacious/audacious-3.10.1.ebuild
new file mode 100644 (file)
index 0000000..12769bf
--- /dev/null
+++ b/media-sound/audacious/audacious-3.10.1.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_P="${P/_/-}"
+
+if [[ ${PV} == *9999 ]]; then
+       inherit autotools git-r3
+       EGIT_REPO_URI="https://github.com/audacious-media-player/audacious.git"
+else
+       SRC_URI="https://distfiles.audacious-media-player.org/${MY_P}.tar.bz2"
+       KEYWORDS="~amd64 ~x86"
+fi
+inherit xdg
+
+DESCRIPTION="Lightweight and versatile audio player"
+HOMEPAGE="https://audacious-media-player.org/"
+SRC_URI+=" mirror://gentoo/gentoo_ice-xmms-0.2.tar.bz2"
+
+LICENSE="BSD-2"
+SLOT="0"
+IUSE="nls qt5"
+
+BDEPEND="
+       virtual/pkgconfig
+       nls? ( dev-util/intltool )
+"
+DEPEND="
+       >=dev-libs/dbus-glib-0.60
+       >=dev-libs/glib-2.28
+       >=x11-libs/cairo-1.2.6
+       >=x11-libs/pango-1.8.0
+       virtual/freedesktop-icon-theme
+       !qt5? ( x11-libs/gtk+:2 )
+       qt5? (
+               dev-qt/qtcore:5
+               dev-qt/qtgui:5
+               dev-qt/qtwidgets:5
+       )
+"
+RDEPEND="${DEPEND}"
+PDEPEND="~media-plugins/audacious-plugins-${PV}"
+
+S="${WORKDIR}/${MY_P}"
+
+src_unpack() {
+       default
+       [[ ${PV} == *9999 ]] && git-r3_src_unpack
+}
+
+src_prepare() {
+       default
+       if ! use nls; then
+               sed -e "/SUBDIRS/s/ po//" -i Makefile || die # bug #512698
+       fi
+       [[ ${PV} == *9999 ]] && eautoreconf
+}
+
+src_configure() {
+       # D-Bus is a mandatory dependency, remote control,
+       # session management and some plugins depend on this.
+       # Building without D-Bus is *unsupported* and a USE-flag
+       # will not be added due to the bug reports that will result.
+       # Bugs #197894, #199069, #207330, #208606
+       econf \
+               --disable-valgrind \
+               --enable-dbus \
+               $(use_enable nls) \
+               $(use_enable !qt5 gtk) \
+               $(use_enable qt5 qt)
+}
+
+src_install() {
+       default
+
+       # Gentoo_ice skin installation; bug #109772
+       insinto /usr/share/audacious/Skins/gentoo_ice
+       doins -r "${WORKDIR}"/gentoo_ice/.
+       docinto gentoo_ice
+       dodoc "${WORKDIR}"/README
+}

diff --git a/media-sound/audacious/audacious-9999.ebuild b/media-sound/audacious/audacious-9999.ebuild
index 282261cbea55ee5c29c889c9f027b14408d8fc95..12769bfaa1029366075e3dc922b60425374f982d 100644 (file)
--- a/media-sound/audacious/audacious-9999.ebuild
+++ b/media-sound/audacious/audacious-9999.ebuild
@@ -1,7 +1,7 @@
-# Copyright 1999-2018 Gentoo Authors
+# Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
+EAPI=7
 
 MY_P="${P/_/-}"
 
@@ -12,7 +12,7 @@ else
        SRC_URI="https://distfiles.audacious-media-player.org/${MY_P}.tar.bz2"
        KEYWORDS="~amd64 ~x86"
 fi
-inherit gnome2-utils xdg-utils
+inherit xdg
 
 DESCRIPTION="Lightweight and versatile audio player"
 HOMEPAGE="https://audacious-media-player.org/"
@@ -22,7 +22,11 @@ LICENSE="BSD-2"
 SLOT="0"
 IUSE="nls qt5"
 
-RDEPEND="
+BDEPEND="
+       virtual/pkgconfig
+       nls? ( dev-util/intltool )
+"
+DEPEND="
        >=dev-libs/dbus-glib-0.60
        >=dev-libs/glib-2.28
        >=x11-libs/cairo-1.2.6
@@ -35,10 +39,7 @@ RDEPEND="
                dev-qt/qtwidgets:5
        )
 "
-DEPEND="${RDEPEND}
-       virtual/pkgconfig
-       nls? ( dev-util/intltool )
-"
+RDEPEND="${DEPEND}"
 PDEPEND="~media-plugins/audacious-plugins-${PV}"
 
 S="${WORKDIR}/${MY_P}"
@@ -79,13 +80,3 @@ src_install() {
        docinto gentoo_ice
        dodoc "${WORKDIR}"/README
 }
-
-pkg_postinst() {
-       xdg_desktop_database_update
-       gnome2_icon_cache_update
-}
-
-pkg_postrm() {
-       xdg_desktop_database_update
-       gnome2_icon_cache_update
-}