sys-cluster/resource-agents: version bump, move to EAPI 6

Package-Manager: Portage-2.3.5, Repoman-2.3.2

diff --git a/sys-cluster/resource-agents/Manifest b/sys-cluster/resource-agents/Manifest
index fcf0170293c4eb772567200998e25753665c9725..b7b1df465b31a281d6ca7a02d6615217d413fa61 100644 (file)
--- a/sys-cluster/resource-agents/Manifest
+++ b/sys-cluster/resource-agents/Manifest
@@ -1 +1,2 @@
 DIST resource-agents-3.9.6.tar.gz 617790 SHA256 39722cdee68ff96d06788f05f325bd21ec2fc59c59d847e5e4b23c6df23bf678 SHA512 b4ca8b8cc3e09508847af3f1cf50cef946f374eae4ee7903700ba49ef7a3357b1ceaa26dca0616feaa79fb290713f18939dda42ee92a5a7bca2fab807fc77901 WHIRLPOOL d5210c70096d45dc91f49f1333711a3d2350d682d9e5720eeda1470b680fcba2b7cbe8c0dd1fbcd26408e88c40ad0ec60951b06a6e2174131f0c588d2a10720c
+DIST resource-agents-4.0.1.tar.gz 659123 SHA256 863f83c724bad3a8bcff12b9c8712406c43e010041868826cad7b78fd8cfb9fb SHA512 9c92bca7775e3c47c6463587fd7eea89f019997cfab0361ef37ee97192604d3b3d0dcd1cb70f774e01689b803dc856af170bd10e86a9d4824597293c264735d5 WHIRLPOOL 8fe3ce305b0b6b37fce83464bcf2ac45c3c060d9b4021fdb8cf5bb7972ab547fea8ec19603210d473c917d7314268296c682b0b9366c7a735cee1b0f7e767496

diff --git a/sys-cluster/resource-agents/resource-agents-3.9.6.ebuild b/sys-cluster/resource-agents/resource-agents-3.9.6.ebuild
index 0ed39e237c01209d8865afcc04b43e1d9e6f1d20..70c075ce654501d94acacecfccd2fc3bf9a53ba8 100644 (file)
--- a/sys-cluster/resource-agents/resource-agents-3.9.6.ebuild
+++ b/sys-cluster/resource-agents/resource-agents-3.9.6.ebuild
@@ -1,10 +1,10 @@
 # Copyright 1999-2017 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI="5"
+EAPI=6
 
 MY_P="${P/resource-}"
-inherit autotools base eutils multilib
+inherit autotools eutils multilib
 
 DESCRIPTION="Resources pack for Heartbeat / Pacemaker"
 HOMEPAGE="http://www.linux-ha.org/wiki/Resource_Agents"
@@ -30,7 +30,7 @@ PATCHES=(
 )
 
 src_prepare() {
-       base_src_prepare
+       default
        eautoreconf
 }
 
@@ -47,7 +47,7 @@ src_configure() {
 }
 
 src_install() {
-       base_src_install
+       default
        rm -rf "${D}"/etc/init.d/ || die
        rm -rf "${D}"/var/run || die
        use rgmanager || rm -rf "${D}"/usr/share/cluster/ "${D}"/var/

diff --git a/sys-cluster/resource-agents/resource-agents-4.0.1.ebuild b/sys-cluster/resource-agents/resource-agents-4.0.1.ebuild
new file mode 100644 (file)
index 0000000..dcbb842
--- /dev/null
+++ b/sys-cluster/resource-agents/resource-agents-4.0.1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+MY_P="${P/resource-}"
+inherit autotools eutils multilib
+
+DESCRIPTION="Resources pack for Heartbeat / Pacemaker"
+HOMEPAGE="http://www.linux-ha.org/wiki/Resource_Agents"
+SRC_URI="https://github.com/ClusterLabs/resource-agents/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~x86"
+IUSE="doc libnet rgmanager"
+
+RDEPEND="sys-apps/iproute2
+       sys-cluster/cluster-glue
+       !<sys-cluster/heartbeat-3.0
+       libnet? ( net-libs/libnet:1.1 )"
+DEPEND="${RDEPEND}
+       doc? (
+               dev-libs/libxslt
+               app-text/docbook-xsl-stylesheets
+       )"
+
+PATCHES=(
+       "${FILESDIR}/3.9.4-configure.patch"
+)
+
+src_prepare() {
+       default
+       eautoreconf
+}
+
+src_configure() {
+       econf \
+               --disable-dependency-tracking \
+               --disable-fatal-warnings \
+               --localstatedir=/var \
+               --docdir=/usr/share/doc/${PF} \
+               --libdir=/usr/$(get_libdir) \
+               --with-ocf-root=/usr/$(get_libdir)/ocf \
+               $(use_enable doc) \
+               $(use_enable libnet)
+}
+
+src_install() {
+       default
+       rm -rf "${D}"/etc/init.d/ || die
+       rm -rf "${D}"/var/run || die
+       use rgmanager || rm -rf "${D}"/usr/share/cluster/ "${D}"/var/
+}
+
+pkg_postinst() {
+       elog "To use Resource Agents installed in /usr/$(get_libdir)/ocf/resource.d"
+       elog "you have to emerge required runtime dependencies manually."
+       elog ""
+       elog "Description and dependencies of all Agents can be found on"
+       elog "http://www.linux-ha.org/wiki/Resource_Agents"
+       elog "or in the documentation of this package."
+}