net-misc/miniupnpd: Bump to 2.0.20180203

diff --git a/net-misc/miniupnpd/Manifest b/net-misc/miniupnpd/Manifest
index 61f1ab2d750970fd65aa7e0230aae14d4a93d079..7bc51592b921fbcbd754a3544f8da3f0c7f7b594 100644 (file)
--- a/net-misc/miniupnpd/Manifest
+++ b/net-misc/miniupnpd/Manifest
@@ -1 +1,2 @@
 DIST miniupnpd-2.0.20171212.tar.gz 222617 BLAKE2B 6ac33048b18d9f8aeb5103f57c9982fec956a61155f8592118c38dea70801597d9e867690ef2f1cdfaf848a25d7ddb4891b3ebf37cd391b33518d6b02e6f9b4a SHA512 3ab81c840953736c662bcb6f074421052a846c7827768acd7a961a23906b9e3d3389f5b593fb6f8011c8e717dae6cd3907b6d34e7904d560378671a7fc1dd3b2
+DIST miniupnpd-2.0.20180203.tar.gz 223084 BLAKE2B 14d7b1f8136be5e211ee2e5374b8ee77dfeb3e64e1308f918d9334a8600234e38581caa293b613cd3736d4a8cfc196a54839cffa8091a36961f4e0e79c727455 SHA512 ef02e33cd93225992c193a13be2320de02255610532de77cf704573384c777d82a4cb89c295982bb660ce056e38ef341223ab362bab74b2cb6954ed4e62b0219

diff --git a/net-misc/miniupnpd/miniupnpd-2.0.20180203.ebuild b/net-misc/miniupnpd/miniupnpd-2.0.20180203.ebuild
new file mode 100644 (file)
index 0000000..9f786c4
--- /dev/null
+++ b/net-misc/miniupnpd/miniupnpd-2.0.20180203.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit toolchain-funcs
+
+DESCRIPTION="MiniUPnP IGD Daemon"
+HOMEPAGE="http://miniupnp.free.fr/"
+SRC_URI="http://miniupnp.free.fr/files/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="+leasefile igd2 ipv6 pcp-peer portinuse strict"
+
+RDEPEND=">=net-firewall/iptables-1.4.6:0=[ipv6?]
+       net-libs/libnfnetlink:=
+       net-libs/libmnl:=
+       dev-libs/gmp:0=
+       sys-apps/util-linux
+       dev-libs/openssl:0="
+DEPEND="${RDEPEND}
+       sys-apps/lsb-release"
+
+src_prepare() {
+       default
+       mv Makefile.linux Makefile || die
+}
+
+src_configure() {
+       local -a opts
+       opts=(
+               --vendorcfg
+               $(usex igd2 '--igd2' '')
+               $(usex ipv6 '--ipv6' '')
+               $(usex leasefile '--leasefile' '')
+               $(usex portinuse '--portinuse' '')
+               $(usex pcp-peer '--pcp-peer' '')
+               $(usex strict '--strict' '')
+       )
+
+       emake CONFIG_OPTIONS="${opts[*]}" config.h
+}
+
+src_compile() {
+       # By default, it builds a bunch of unittests that are missing wrapper
+       # scripts in the tarball
+       emake CC="$(tc-getCC)" STRIP=true miniupnpd
+}
+
+src_install() {
+       emake PREFIX="${ED}" STRIP=true install
+
+       newinitd "${FILESDIR}"/${PN}-init.d-r1 ${PN}
+       newconfd "${FILESDIR}"/${PN}-conf.d-r1 ${PN}
+}
+
+pkg_postinst() {
+       elog "Please correct the external interface in the top of the two"
+       elog "scripts in /etc/miniupnpd and edit the config file in there too"
+}