net-mail/mpop: version bump to 1.4.7

Signed-off-by: Tim Harder <radhermit@gentoo.org>

diff --git a/net-mail/mpop/Manifest b/net-mail/mpop/Manifest
index 401363f503befec963079bf54b3772b5ce28777e..0b2784b391870b655df2433f7c0d8adfbf62c345 100644 (file)
--- a/net-mail/mpop/Manifest
+++ b/net-mail/mpop/Manifest
@@ -1 +1,2 @@
 DIST mpop-1.4.4.tar.xz 319372 BLAKE2B acf5bdb62479126ae212bb008878872d16efba1eb9a077bf4697ba22ff512977fcd5affad090bc952fb01cf07a607a4dce91b873128c43f087c34dca6d6bae81 SHA512 1ed89108d35d7bbd6bcbd6de956f51cfcfaefd808f6aa7135b168d789f8cbe7070be9db676d1222dce5b6fe8b6692616d6b7adec9c23df11ac3de112897924da
+DIST mpop-1.4.7.tar.xz 322488 BLAKE2B ea73e84b5ed3b5aad7ef91ceb510187c3f2d42976329a6a53511329a84713edc056ca6db35b1de2c9bff8b417e2710e598c472e78acbdc499dd73b24c46dfb47 SHA512 ce0ac899fd2af1d50ef221c88282c12263c5862b9ff1f6341a8551c3fe6b69272772599a2040a0f553a776245514c55b8102ca8cf291b411e5127a3f39897832

diff --git a/net-mail/mpop/mpop-1.4.7.ebuild b/net-mail/mpop/mpop-1.4.7.ebuild
new file mode 100644 (file)
index 0000000..ee0c884
--- /dev/null
+++ b/net-mail/mpop/mpop-1.4.7.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="A small, fast, and portable POP3 client"
+HOMEPAGE="https://marlam.de/mpop/"
+SRC_URI="https://marlam.de/mpop/releases/${P}.tar.xz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="gnutls idn libressl gnome-keyring nls sasl ssl vim-syntax"
+
+RDEPEND="
+       idn? ( net-dns/libidn2 )
+       gnome-keyring? ( app-crypt/libsecret )
+       nls? ( virtual/libintl )
+       sasl? ( virtual/gsasl )
+       ssl? (
+               gnutls? ( net-libs/gnutls:0=[idn?] )
+               !gnutls? (
+                       !libressl? ( dev-libs/openssl:0= )
+                       libressl? ( dev-libs/libressl:0= )
+               )
+       )"
+DEPEND="${RDEPEND}
+       nls? ( sys-devel/gettext )
+       virtual/pkgconfig"
+
+REQUIRED_USE="gnutls? ( ssl )"
+
+DOCS="AUTHORS ChangeLog NEWS NOTES README THANKS"
+
+src_configure() {
+       econf \
+               $(use_enable nls) \
+               $(use_with ssl tls $(usex gnutls "gnutls" "openssl")) \
+               $(use_with sasl libgsasl) \
+               $(use_with idn libidn) \
+               $(use_with gnome-keyring libsecret)
+}
+
+src_install() {
+       default
+
+       if use vim-syntax ; then
+               insinto /usr/share/vim/vimfiles/syntax
+               doins scripts/vim/mpop.vim
+       fi
+}