x11-libs/gl2ps: version bump to 1.4.0

Package-Manager: Portage-2.3.24, Repoman-2.3.6

diff --git a/x11-libs/gl2ps/Manifest b/x11-libs/gl2ps/Manifest
index 26d7d5bafa475210bfe572d0992a9b3e88c3370e..40cb87fca8c09ea02fe2e55fc0a91f475b0b9cec 100644 (file)
--- a/x11-libs/gl2ps/Manifest
+++ b/x11-libs/gl2ps/Manifest
@@ -1 +1,2 @@
 DIST gl2ps-1.3.9.tgz 294907 BLAKE2B b8473f9f3fc6cefa2374f6fdd94fb98d73ea79b9c0087ccc573f6b66eafe11098fc4312d8ff121abe2a8d6c9a3474f69dcb321ef978f8777b6dc077e5504621f SHA512 e6770c27d4832a300b4e16a9f98deb8557e7875460e7aa7e655fdb796f5dfffd5eccdc8b15f5a3ae151713fc46f97dacad48ee7550c41373b6fc8cfd21a437cb
+DIST gl2ps-1.4.0.tgz 300339 BLAKE2B bda8742dea6c1b4eb3e3a3492e6f38229feb6480131ce69e3512e9c558f7817a34bc76985311c3879cfcec5f715f36f0b8300300dd26025cdb7e72478802aa7d SHA512 420b21a5b4397c9a9a2323a8686b8635c2683354c94762d2d0172c661fc36c4298042498dd8ef2323adf32f45aa4e0a3dba146058ccde597e5a46c2027cbf7ce

diff --git a/x11-libs/gl2ps/gl2ps-1.4.0.ebuild b/x11-libs/gl2ps/gl2ps-1.4.0.ebuild
new file mode 100644 (file)
index 0000000..2fcb418
--- /dev/null
+++ b/x11-libs/gl2ps/gl2ps-1.4.0.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit cmake-utils
+
+DESCRIPTION="OpenGL to PostScript printing library"
+HOMEPAGE="http://www.geuz.org/gl2ps/"
+SRC_URI="http://geuz.org/${PN}/src/${P}.tgz"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
+IUSE="doc png zlib"
+
+RDEPEND="
+       media-libs/freeglut
+       x11-libs/libXmu
+       png? ( media-libs/libpng:0= )
+       zlib? ( sys-libs/zlib )"
+DEPEND="${RDEPEND}
+       doc? (
+               dev-tex/tth
+               dev-texlive/texlive-latex
+               dev-texlive/texlive-latexrecommended )"
+
+S=${WORKDIR}/${P}-source
+
+PATCHES=( "${FILESDIR}"/${PN}-1.3.8-cmake.patch )
+
+src_prepare() {
+       cmake-utils_src_prepare
+       sed '/^install.*TODO\.txt/d' -i "${S}"/CMakeLists.txt || die
+}
+
+src_configure() {
+       local mycmakeargs=(
+               -DCMAKE_INSTALL_DOCDIR="share/doc/${PF}"
+               -DENABLE_DOC="$(usex doc)"
+               -DENABLE_PNG="$(usex png)"
+               -DENABLE_ZLIB="$(usex zlib)"
+       )
+       cmake-utils_src_configure
+}
+
+src_install() {
+       cmake-utils_src_install
+       if [[ ${CHOST} == *-darwin* ]] ; then
+               install_name_tool \
+                       -id "${EPREFIX}"/usr/$(get_libdir)/libgl2ps.dylib \
+                       "${D%/}${EPREFIX}"/usr/$(get_libdir)/libgl2ps.dylib || die
+       fi
+}