-----BEGIN PGP SIGNED MESSAGE-----
-Hash: SHA512
+Hash: SHA256
AUX dist/01_gentoo_set_xdg_menu_prefix-1.patch 592 RMD160 80ac0ae419f0f721a044053cdaeaf2f1f982f74e SHA1 80e9a70b108cab0b05efc50d6fa66665b711f149 SHA256 dea20e8a0e8f0ecc1aec1b38cec994312514aa1e88ba25fede01e1953623f341
AUX dist/01_gentoo_set_xdg_menu_prefix.patch 606 RMD160 37290ce06adf1cf43b0006c02804d7fe762ed609 SHA1 8e86e06a70438c12085a595fd66e2354141fb056 SHA256 9c64b093340d7d25ce6c28d298cd62f3f4da141b762c663df9cd9b5b7722f7d3
EBUILD kdelibs-4.6.4.ebuild 9999 RMD160 7125dfccaef7e8ff4d99ff31d74700842bf5bc37 SHA1 a5fac3a8cf61d48d4d8dc8278e8868a25225acdc SHA256 fb18a2441a51850704db3789004b81b858da1ab8e509852bb7a6736b83cc0994
EBUILD kdelibs-4.6.5-r1.ebuild 10230 RMD160 743b3d28569dd790dabc0f58d500690d195506a1 SHA1 bf8e6f7ed2434585f9c39c8a11cb59fe292772a7 SHA256 3b30ea9b25a47b6b0c3846bfb2b6ece34eb26d34b00727ae37ba48bee2fb232d
EBUILD kdelibs-4.6.5.ebuild 10179 RMD160 ab2505eb9c0512fcb8e165063c6628ffc762688f SHA1 0c50d9abb1cff71d8011c7192fb0a0dae1c6a74c SHA256 55c2d3baa02334de601ce2b5c89b10f8d0ae866ab6b435bbeffad8b677f95552
+EBUILD kdelibs-4.7.0-r1.ebuild 9796 RMD160 ab10520201c17a8b74f1bd8dd3a6430c97f3e38d SHA1 6cada2d15ab33643b9429deb362fbd08219e792f SHA256 a78e41dd87b4392c3c5bb4226cad775d4dbb92cda97f92fcce05c64963ce9c05
EBUILD kdelibs-4.7.0.ebuild 9723 RMD160 c8385a1229de11dfa282d25608948dccb32b9642 SHA1 c0a16ac99e2d63dac5143b4e415006ed8d1d9b49 SHA256 c73674336af8bca99b690512a151c979dcea580c994c72bf12088d4d1166a2e7
-MISC ChangeLog 130095 RMD160 52921e2e9af0f5e11aaf6ec524fad7aeff80fbb8 SHA1 f243f2fa540f8625a41a881b98587d0e30ab51f0 SHA256 cd5cb39f56fea455400c0a53921e29cdebd2085efa12aa89e24c05b15bcb62c7
-MISC metadata.xml 400 RMD160 2464c52adb57c7f5949a31aea4b1e5e2e10a5081 SHA1 487530dfca818a8ff2b2583b808303778c19b6da SHA256 a5ce1ca62fd98100220bea78ba6b85c7b086b07a2b93ec153020ba06ec9f4e80
+MISC ChangeLog 130241 RMD160 7a9854c4841be7f61346b877bc8de02ea3b1f4e2 SHA1 eddd96995fd11bc92dee4cc3d475116307e0fe84 SHA256 1de562202424780425bb7855970e65aa7b24bd78c1738b25d5be71783304d2cf
+MISC metadata.xml 443 RMD160 765aa5080e9ecee24e26f5b8a5168e674db2ffd2 SHA1 82f77d1dc84732dbedcdebbac460896bd6b5484b SHA256 79624eb4920e9849ea5ce593a5adc8c7e45cd9670f9f63a64cf00a637de2d701
-----BEGIN PGP SIGNATURE-----
-Version: GnuPG v2.0.17 (GNU/Linux)
+Version: GnuPG v2.0.18 (GNU/Linux)
-iQIcBAEBCgAGBQJOOFNlAAoJENwGBM22xffeub8QAJM2lujqcNqSVe92ykkdOGMc
-iCJDpem1nZQWztPiDkDqv9+I/lDJLRHeO0m6KP4eXDQADQJG8abDgYX3ugxRUwKa
-V1pX3Ng9X4YwJXdHXpM3nJyRVFXrmkvzq9hy1S+w24bUJ+LctiEGKom0R5UZNe4P
-972nL3ASgcq1Krx0+8kEsuI5K801LSzaOXa1r1rwq9IXkXAyvXdztp5X3n1gOJv/
-L1eZVd4ahdevwGgo55NCxgrQTDQeMGeF9P0Ia18h+d4MQLKSpevpaahfne9jh+Zu
-FTJTQ38jMbSw9t1wYOxzFbxztj4V6m9TXcOF0c3Wm4KMctMHho3PKsXJoQ53zDT/
-o4yYWr5LYDd9Qqpoa7cEkhc/c4HzR4fO53QjvAkfxd2xFxHLAsaNHeAxUOUi39La
-12yT8YBOtO/HDL6s8nL3gzywKWX2w7XqEjHL7d8b0GLzv81FAjzBLpAkZGdXqKqy
-8ie7YuAgaQLh1Y/08Lfn4pxGxDp1wPDw8YTV4ss190TmyumUO0FD0PVBSS4So/H5
-eZRoKg8iaHqNaJjMZaa8vVm1za4sUyLk2WxCbJDOf/jCbfwaV5dVHb9v19NAFIvM
-XUD1J30a921VexL5NGSnKGKFAMKi73zahZi1kgmXJvJ2vATf7VoQJLfBwEgnmYkQ
-l+VQ8igOt2dUrnYURsXr
-=k4bk
+iQIcBAEBCAAGBQJOPsMxAAoJEOf+E+/4L5LmZGgP/jho4a5rnP16/GAvbwuANqsk
+n8P3G6tQlyUU8BrW0KHnkhqMdaGWI7b6z1e6lpqxNMGnXngIiIa0YQK54Cl++n1U
+6Lv0hjTvfC/sk9990HSW1WsDHEWGCs7/lBBOZ4Kv+3TwhPCgSy1oHl6Zp0OynnSZ
+AB2yhQYXxrdgXuH/33qvNiEK1dZnsT2mUg5DK6WBCroH1oaomb10R3c9DKBttayA
+/vzjrI+Yanpjm+KLaSZJ90HYVC66wbKwvcU+enRuwJqb85Ku05kWydBMtlJ5R8IB
+U3c1yNNF6KDY+DqKK6ntaX8nDJRfZSPU4TgqItSV+70auhOPgMNg/H09a7iM4ohG
+TbkabKjPaWzqi2jS7hpLcLPY6K84eo0Ywb2iJUb6uNA7EBB52KeE5O0ojnh6PtCO
+6/ZSwKZ6AQMKHlzjn1WEyZL3RNYd5GueeT5U33bihFl7YQTykY90hxUSSjBFJ6pe
+lXxKIUseccuw/DFJ/PPCXqdHiXpbVfgMyOHdQb7ya/lSG4HJjm0Iy9mJfrwrtPnk
+Sv8DzHYOBl6xdlt6EVm2Hhtgz/fmWtoAKtxbB7goPSVCxF+XMZsDxOlKQQbheS82
+dCDzMaQHssNq6kQtaFNggsakBav+67xvMQpD+i4QqMzvYWcwA6OvHWNf1l6f+Okj
+YRlD3Pc3S1PzssYIT0fj
+=zVYB
-----END PGP SIGNATURE-----
--- /dev/null
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kdelibs/kdelibs-4.7.0-r1.ebuild,v 1.1 2011/08/07 16:54:15 alexxy Exp $
+
+EAPI=4
+
+CPPUNIT_REQUIRED="optional"
+DECLARATIVE_REQUIRED="always"
+OPENGL_REQUIRED="optional"
+KDE_SCM="git"
+inherit kde4-base fdo-mime toolchain-funcs
+
+DESCRIPTION="KDE libraries needed by all KDE programs."
+HOMEPAGE="http://www.kde.org/"
+
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+LICENSE="LGPL-2.1"
+IUSE="3dnow acl alsa altivec bindist +bzip2 debug doc fam +handbook jpeg2k kerberos
+lzma mmx nls openexr +policykit semantic-desktop spell sse sse2 ssl +udev
++udisks +upower upnp zeroconf"
+
+REQUIRED_USE="
+ udisks? ( udev )
+ upower? ( udev )
+"
+
+# needs the kate regression testsuite from svn
+RESTRICT="test"
+
+COMMONDEPEND="
+ app-crypt/qca:2
+ >=app-misc/strigi-0.6.3
+ >=dev-libs/libattica-0.1.90
+ >=dev-libs/libdbusmenu-qt-0.3.2
+ dev-libs/libpcre[unicode]
+ dev-libs/libxml2
+ dev-libs/libxslt
+ media-libs/fontconfig
+ media-libs/freetype:2
+ media-libs/giflib
+ >=media-libs/libpng-1.4
+ >=media-libs/phonon-4.4.3
+ sys-libs/zlib
+ virtual/jpeg
+ >=x11-misc/shared-mime-info-0.60
+ acl? ( virtual/acl )
+ alsa? ( media-libs/alsa-lib )
+ !aqua? (
+ x11-libs/libICE
+ x11-libs/libSM
+ x11-libs/libX11
+ x11-libs/libXau
+ x11-libs/libXcursor
+ x11-libs/libXdmcp
+ x11-libs/libXext
+ x11-libs/libXfixes
+ x11-libs/libXft
+ x11-libs/libXpm
+ x11-libs/libXrender
+ x11-libs/libXScrnSaver
+ x11-libs/libXtst
+ !kernel_SunOS? ( sys-libs/libutempter )
+ )
+ bzip2? ( app-arch/bzip2 )
+ fam? ( virtual/fam )
+ jpeg2k? ( media-libs/jasper )
+ kerberos? ( virtual/krb5 )
+ lzma? ( app-arch/xz-utils )
+ openexr? (
+ media-libs/openexr
+ media-libs/ilmbase
+ )
+ policykit? ( >=sys-auth/polkit-qt-0.99 )
+ semantic-desktop? (
+ >=dev-libs/shared-desktop-ontologies-0.6.50
+ >=dev-libs/soprano-2.6.51[dbus,raptor,redland]
+ )
+ spell? ( app-text/enchant )
+ ssl? ( dev-libs/openssl )
+ udev? ( sys-fs/udev )
+ upnp? ( media-libs/herqq )
+ zeroconf? (
+ || (
+ net-dns/avahi[mdnsresponder-compat]
+ !bindist? ( net-misc/mDNSResponder )
+ )
+ )
+"
+DEPEND="${COMMONDEPEND}
+ app-text/docbook-xml-dtd:4.2
+ app-text/docbook-xsl-stylesheets
+ doc? ( app-doc/doxygen )
+ nls? ( virtual/libintl )
+"
+RDEPEND="${COMMONDEPEND}
+ !dev-libs/conversion
+ !dev-libs/kunitconversion
+ !x11-libs/qt-phonon
+ !<=kde-misc/kdnssd-avahi-0.1.2:0
+ !<=kde-misc/knetworkmanager-4.4.0_p20100820
+ >=app-crypt/gnupg-2.0.11
+ app-misc/ca-certificates
+ $(add_kdebase_dep kde-env)
+ !aqua? (
+ x11-apps/iceauth
+ x11-apps/rgb
+ >=x11-misc/xdg-utils-1.0.2-r3
+ udisks? ( sys-fs/udisks )
+ upower? ( sys-power/upower )
+ )
+"
+PDEPEND="
+ || ( ( $(add_kdebase_dep kfmclient) ) x11-misc/xdg-utils )
+ handbook? ( $(add_kdebase_dep khelpcenter) )
+ policykit? (
+ >=kde-misc/polkit-kde-kcmodules-0.98_pre20101127
+ >=sys-auth/polkit-kde-agent-0.99
+ )
+ semantic-desktop? ( $(add_kdebase_dep nepomuk) )
+"
+
+# Blockers added due to packages from old versions, removed in the meanwhile
+# as well as for file collisions
+add_blocker libknotificationitem
+add_blocker libkworkspace '<4.3.66'
+add_blocker kcontrol '<4.5.80'
+# @since 4.4 - kpilot is gone (blocker added to help upgrades)
+add_blocker kpilot
+# Block some old versions of KDE-3.5 packages that don't work well with KDE-4
+add_blocker kdebase 0 3.5.9-r4:3.5
+add_blocker kdebase-startkde 0 3.5.10:3.5
+add_blocker kdelibs 0 '<3.5.10:3.5'
+# libnepomukquery moved to kdelibs from plasma-workspace between 4.3.74 -> 4.3.75
+add_blocker plasma-workspace '<4.3.75'
+
+PATCHES=(
+ "${FILESDIR}/dist/01_gentoo_set_xdg_menu_prefix-1.patch"
+ "${FILESDIR}/dist/02_gentoo_append_xdg_config_dirs-1.patch"
+ "${FILESDIR}/${PN}-4.5.90-mimetypes.patch"
+ "${FILESDIR}/${PN}-4.4.90-xslt.patch"
+ "${FILESDIR}/${PN}-4.6.2-nonepomuk.patch"
+ "${FILESDIR}/${PN}-4.6.3-no_suid_kdeinit.patch"
+ "${FILESDIR}/${PN}-4.6.3-bytecode.patch"
+)
+
+pkg_pretend() {
+ if [[ ${MERGE_TYPE} != binary ]]; then
+ [[ $(gcc-major-version) -lt 4 ]] || \
+ ( [[ $(gcc-major-version) -eq 4 && $(gcc-minor-version) -le 3 ]] ) \
+ && die "Sorry, but gcc-4.3 and earlier won't work for KDE SC 4.6 (see bug #354837)."
+ fi
+}
+
+src_prepare() {
+ kde4-base_src_prepare
+ use arm && epatch "${FILESDIR}/${PN}-4.6.2-armlinking.patch"
+
+ # Rename applications.menu (needs 01_gentoo_set_xdg_menu_prefix-1.patch to work)
+ sed -e 's|FILES[[:space:]]applications.menu|FILES applications.menu RENAME kde-4-applications.menu|g' \
+ -i kded/CMakeLists.txt || die "Sed on CMakeLists.txt for applications.menu failed."
+
+ if use aqua; then
+ sed -i -e \
+ "s:BUNDLE_INSTALL_DIR \"/Applications:BUNDLE_INSTALL_DIR \"${EPREFIX}/${APP_BUNDLE_DIR}:g" \
+ cmake/modules/FindKDE4Internal.cmake || die "failed to sed FindKDE4Internal.cmake"
+
+ #if [[ ${CHOST} == *-darwin8 ]]; then
+ sed -i -e \
+ "s:set(_add_executable_param MACOSX_BUNDLE):remove(_add_executable_param MACOSX_BUNDLE):g" \
+ cmake/modules/KDE4Macros.cmake || die "failed to sed KDE4Macros.cmake"
+ #fi
+
+ # solid/solid/backends/iokit doesn't properly link, so disable it.
+ sed -e "s|\(APPLE\)|(FALSE)|g" -i solid/solid/CMakeLists.txt \
+ || die "disabling solid/solid/backends/iokit failed"
+ sed -e "s|m_backend = .*Backends::IOKit.*;|m_backend = 0;|g" -i solid/solid/managerbase.cpp \
+ || die "disabling solid/solid/backends/iokit failed"
+
+ # There's no fdatasync on OSX and the check fails to detect that.
+ sed -e "/HAVE_FDATASYNC/ d" -i config.h.cmake \
+ || die "disabling fdatasync failed"
+
+ # Fix nameser include to nameser8_compat
+ sed -e "s|nameser8_compat.h|nameser_compat.h|g" -i kio/misc/kpac/discovery.cpp \
+ || die "fixing nameser include failed"
+ append-flags -DHAVE_ARPA_NAMESER8_COMPAT_H=1
+
+ # Try to fix kkeyserver_mac
+ epatch "${FILESDIR}"/${PN}-4.3.80-kdeui_util_kkeyserver_mac.patch
+ fi
+
+ if [[ ${CHOST} == *-solaris* ]] ; then
+ epatch "${FILESDIR}/kdelibs-4.3.2-solaris-ksyscoca.patch"
+ # getgrouplist not in solaris libc
+ epatch "${FILESDIR}/kdelibs-4.3.2-solaris-getgrouplist.patch"
+ # solaris has no d_type element in dir_ent
+ epatch "${FILESDIR}/kdelibs-4.3.2-solaris-fileunix.patch"
+ fi
+}
+
+src_configure() {
+ if use zeroconf; then
+ if has_version net-dns/avahi; then
+ mycmakeargs=(-DWITH_Avahi=ON -DWITH_DNSSD=OFF)
+ elif has_version net-misc/mDNSResponder; then
+ mycmakeargs=(-DWITH_Avahi=OFF -DWITH_DNSSD=ON)
+ else
+ die "USE=\"zeroconf\" enabled but neither net-dns/avahi nor net-misc/mDNSResponder were found."
+ fi
+ else
+ mycmakeargs=(-DWITH_Avahi=OFF -DWITH_DNSSD=OFF)
+ fi
+ mycmakeargs+=(
+ -DWITH_HSPELL=OFF
+ -DWITH_ASPELL=OFF
+ -DKDE_DEFAULT_HOME=.kde4
+ -DKAUTH_BACKEND=POLKITQT-1
+ $(cmake-utils_use_build handbook doc)
+ $(cmake-utils_use_has 3dnow X86_3DNOW)
+ $(cmake-utils_use_has altivec PPC_ALTIVEC)
+ $(cmake-utils_use_has mmx X86_MMX)
+ $(cmake-utils_use_has sse X86_SSE)
+ $(cmake-utils_use_has sse2 X86_SSE2)
+ $(cmake-utils_use_with acl)
+ $(cmake-utils_use_with alsa)
+ $(cmake-utils_use_with bzip2 BZip2)
+ $(cmake-utils_use_with fam)
+ $(cmake-utils_use_with jpeg2k Jasper)
+ $(cmake-utils_use_with kerberos GSSAPI)
+ $(cmake-utils_use_with lzma LibLZMA)
+ $(cmake-utils_use_with nls Libintl)
+ $(cmake-utils_use_with openexr OpenEXR)
+ $(cmake-utils_use_with opengl OpenGL)
+ $(cmake-utils_use_with policykit PolkitQt-1)
+ $(cmake-utils_use_with semantic-desktop Soprano)
+ $(cmake-utils_use_with semantic-desktop SharedDesktopOntologies)
+ $(cmake-utils_use_with spell ENCHANT)
+ $(cmake-utils_use_with ssl OpenSSL)
+ $(cmake-utils_use_with udev UDev)
+ $(cmake-utils_use_with upnp HUpnp)
+ )
+ kde4-base_src_configure
+}
+
+src_compile() {
+ kde4-base_src_compile
+
+ # The building of apidox is not managed anymore by the build system
+ if use doc; then
+ einfo "Building API documentation"
+ cd "${S}"/doc/api/
+ ./doxygen.sh "${S}" || die "APIDOX generation failed"
+ fi
+}
+
+src_install() {
+ kde4-base_src_install
+
+ # use system certificates
+ rm -f "${ED}"/usr/share/apps/kssl/ca-bundle.crt || die
+ dosym /etc/ssl/certs/ca-certificates.crt /usr/share/apps/kssl/ca-bundle.crt
+
+ if use doc; then
+ einfo "Installing API documentation. This could take a bit of time."
+ cd "${S}"/doc/api/
+ docinto /HTML/en/kdelibs-apidox
+ dohtml -r ${P}-apidocs/*
+ fi
+
+ if use aqua; then
+ einfo "fixing ${PN} plugins"
+
+ local _PV=${PV:0:3}.0
+ local _dir=${EPREFIX}/usr/$(get_libdir)/kde4/plugins/script
+
+ install_name_tool -id \
+ "${_dir}/libkrossqtsplugin.${_PV}.dylib" \
+ "${D}/${_dir}/libkrossqtsplugin.${_PV}.dylib" \
+ || die "failed fixing libkrossqtsplugin.${_PV}.dylib"
+
+ einfo "fixing ${PN} cmake detection files"
+ #sed -i -e \
+ # "s:if (HAVE_XKB):if (HAVE_XKB AND NOT APPLE):g" \
+ echo -e "set(XKB_FOUND FALSE)\nset(HAVE_XKB FALSE)" > \
+ "${ED}"/usr/share/apps/cmake/modules/FindXKB.cmake \
+ || die "failed fixing FindXKB.cmake"
+ fi
+
+ einfo Installing environment file.
+ # Since 44qt4 is sourced earlier QT_PLUGIN_PATH is defined.
+ echo "COLON_SEPARATED=QT_PLUGIN_PATH" > "${T}/77kde"
+ echo "QT_PLUGIN_PATH=${EPREFIX}/usr/$(get_libdir)/kde4/plugins" >> "${T}/77kde"
+ doenvd "${T}/77kde"
+}
+
+pkg_postinst() {
+ fdo-mime_mime_database_update
+
+ if use zeroconf; then
+ echo
+ elog "To make zeroconf support available in KDE make sure that the 'mdnsd' daemon"
+ elog "is running."
+ echo
+ einfo "If you also want to use zeroconf for hostname resolution, emerge sys-auth/nss-mdns"
+ einfo "and enable multicast dns lookups by editing the 'hosts:' line in /etc/nsswitch.conf"
+ einfo "to include 'mdns', e.g.:"
+ einfo " hosts: files mdns dns"
+ echo
+ fi
+
+ elog "Your homedir is set to \${HOME}/.kde4"
+ echo
+
+ kde4-base_pkg_postinst
+}
+
+pkg_prerm() {
+ # Remove ksycoca4 global database
+ rm -f "${EROOT}${PREFIX}"/share/kde4/services/ksycoca4
+}
+
+pkg_postrm() {
+ fdo-mime_mime_database_update
+
+ kde4-base_pkg_postrm
+}
projects / gentoo.git / commitdiff