app-antivirus/clamav-unofficial-sigs: new version 6.0.1.

Package-Manager: Portage-2.3.69, Repoman-2.3.16
Signed-off-by: Hasan ÇALIŞIR <hasan.calisir@psauxit.com>
Signed-off-by: Michael Orlitzky <mjo@gentoo.org>

diff --git a/app-antivirus/clamav-unofficial-sigs/Manifest b/app-antivirus/clamav-unofficial-sigs/Manifest
index af52a5be8e262f15f5565d355fd6087dca720046..a557118db7555347b38da66bc7fe60c14a04c93d 100644 (file)
--- a/app-antivirus/clamav-unofficial-sigs/Manifest
+++ b/app-antivirus/clamav-unofficial-sigs/Manifest
@@ -1 +1,2 @@
 DIST clamav-unofficial-sigs-5.6.2.tar.gz 50931 BLAKE2B 6fea42f8f76ae5344c2b96c9203d2b09e755573d03f2b9d3d9ee2a488150fbb6f598e052b730daf12c551920a71fd8daad1dc10002fca12fa4a74554cf7d445e SHA512 79978db065a22d778490d0a2673f5a0bb7ab73e42de64563e7d26ac23459f7e5b2e73b0548e1ea6483e3c5f43eed65cdbc6814037cc0c46a339366a0150e5427
+DIST clamav-unofficial-sigs-6.0.1.tar.gz 52262 BLAKE2B 9523da749e88c5e93f0986d7d4a234c3b1eff7c207ceb266e63cd76d7cffdf4a85aedf90aa746f7e1c82be97018f40896bbaa2dfd8f749f3c167d3bff74293d7 SHA512 d4f619628c9b2804a6d5ad533adaad72e323bb0604334c045cf92fc550ffb114493653d097b68337b33f51dc1215dc073b4ec9dc42abea8707cb03aefa40b289

diff --git a/app-antivirus/clamav-unofficial-sigs/clamav-unofficial-sigs-6.0.1.ebuild b/app-antivirus/clamav-unofficial-sigs/clamav-unofficial-sigs-6.0.1.ebuild
new file mode 100644 (file)
index 0000000..e2a1d38
--- /dev/null
+++ b/app-antivirus/clamav-unofficial-sigs/clamav-unofficial-sigs-6.0.1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit user
+
+DESCRIPTION="Download and install third-party clamav signatures"
+HOMEPAGE="https://github.com/extremeshok/${PN}"
+SRC_URI="${HOMEPAGE}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+# The script relies on either net-misc/socat, or Perl's
+# IO::Socket::UNIX. We already depend on Perl, and Gentoo's Perl ships
+# with IO::Socket::UNIX, so we can leave out net-misc/socat here.
+RDEPEND="${DEPEND}
+       app-crypt/gnupg
+       dev-lang/perl
+       net-dns/bind-tools
+       || ( net-misc/wget net-misc/curl )"
+
+src_install() {
+       dosbin "${PN}.sh"
+
+       # The script's working directory (set in the conf file). By default,
+       # it runs as clamav/clamav. We set the owner/group later, in
+       # pkg_preinst, after the user/group is sure to exist (because we
+       # create them otherwise).
+       keepdir "/var/lib/${PN}"
+
+       insinto /etc/logrotate.d
+       doins "${FILESDIR}/${PN}.logrotate"
+
+       insinto "/etc/${PN}"
+       doins config/{master,user}.conf
+       newins config/os.gentoo.conf os.conf
+
+       doman "${FILESDIR}/${PN}.8"
+       dodoc README.md
+}
+
+pkg_preinst() {
+       # Should agree with app-antivirus/clamav. We don't actually need
+       # clamav to function, so it isn't one of our dependencies, and
+       # that's why we might need to create its user ourselves.
+       enewgroup clamav
+       enewuser clamav -1 -1 /dev/null clamav
+       fowners clamav:clamav "/var/lib/${PN}"
+}
+
+pkg_postinst() {
+       elog ''
+       elog "You will need to select databases in /etc/${PN}/master.conf."
+       elog "For details, please see the ${PN}(8) manual page."
+       elog ''
+       elog 'An up-to-date description of the available Sanesecurity'
+       elog 'databases is available at,'
+       elog ''
+       elog '  http://sanesecurity.com/usage/signatures/'
+       elog ''
+}