dev-python/graph-tool: Bump version to 2.27

Closes: https://bugs.gentoo.org/675162
Closes: https://bugs.gentoo.org/686754
Package-Manager: Portage-2.3.67, Repoman-2.3.13
Signed-off-by: David Seifert <soap@gentoo.org>

diff --git a/dev-python/graph-tool/Manifest b/dev-python/graph-tool/Manifest
index 05ee3384046d0d7bc802d49b43925b9c6611884f..1f5390d7f43327391ee8745901efb9bf54121557 100644 (file)
--- a/dev-python/graph-tool/Manifest
+++ b/dev-python/graph-tool/Manifest
@@ -1,3 +1,4 @@
 DIST graph-tool-2.19.tar.bz2 15147961 BLAKE2B 93f4220d6f86ed5e18619a4300272185673d54418b6b73eb9cf2264d698b9f66589f22fe9906082c5b6360e037115c6df7c52871e33c1dcb8ec64c3596b76bda SHA512 dc0bd93ccf21bb6616035dbfe33b0d9406eb894791e615795d486dc8f9d9991a6b93cf835cf4e59197005c14faedf105f3384cccd42db544104840cf857b2a84
 DIST graph-tool-2.23.tar.bz2 14998733 BLAKE2B 5eef201f9751ba0ee64d3f3d0694631b23b8ee7799d0e0a1a52125b3b355ee30bb59400665404cd040df29ab2534dc0fdf940d2f3abdb1ddfff0894fb150ed3b SHA512 bd7e493806152d004ed8fcd5cd93f8a27200b0acacde07026ad6f83e8b9a0cdbdedfee79f5ff4c41de179ea3293a1d100571501e8791dad2ff608ecb424a9e36
 DIST graph-tool-2.26.tar.bz2 15000764 BLAKE2B eb4db3d6753b4af8e38cbd9a71e5e5a6368e30556b83f8b9b9a67d8ede2fea9789bb959eb405eb1896c69c487915f18849146bc5fbd95bea1b7910c7c871d577 SHA512 97f51f777f45383780f765277d1af6ae4879ec39243e9b5c11a5c8f58e952e34c301d51e4ce86a0de1bb7b86bf7150d85ef182693e99f319a19a36d2cc25742a
+DIST graph-tool-2.27.tar.bz2 14989318 BLAKE2B 1fc307f33fc3e4642e91c20cc4988915cae61306ac445be070f19c263e2d2a74a241d651dd9c4b6b78d5f28fc8cde00789cf90db53cbae6db0583cf216824301 SHA512 39ea5e76a91f03bc2475d80df6001c87fc47517d279e27fdab413aec8982146993d3c4a370f85cb28a53e5c974b0e90b0fb22538f3d66ef9cb635abf6188d434

diff --git a/dev-python/graph-tool/graph-tool-2.27.ebuild b/dev-python/graph-tool/graph-tool-2.27.ebuild
new file mode 100644 (file)
index 0000000..722d863
--- /dev/null
+++ b/dev-python/graph-tool/graph-tool-2.27.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{5,6,7} )
+
+inherit check-reqs python-r1 toolchain-funcs
+
+if [[ ${PV} == *9999 ]]; then
+       EGIT_REPO_URI="https://git.skewed.de/count0/graph-tool.git"
+       inherit autotools git-r3
+else
+       SRC_URI="https://downloads.skewed.de/${PN}/${P}.tar.bz2"
+       KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="An efficient python module for manipulation and statistical analysis of graphs"
+HOMEPAGE="https://graph-tool.skewed.de/"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="+cairo openmp"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+       ${PYTHON_DEPS}
+       >=dev-libs/boost-1.70:=[context,python,${PYTHON_USEDEP}]
+       dev-libs/expat:=
+       dev-python/numpy[${PYTHON_USEDEP}]
+       sci-libs/scipy[${PYTHON_USEDEP}]
+       sci-mathematics/cgal:=
+       cairo? (
+               dev-cpp/cairomm
+               dev-python/pycairo[${PYTHON_USEDEP}]
+       )
+       dev-python/matplotlib[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+       dev-cpp/sparsehash"
+BDEPEND="virtual/pkgconfig"
+
+# bug 453544
+CHECKREQS_DISK_BUILD="6G"
+
+pkg_pretend() {
+       [[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+       check-reqs_pkg_pretend
+}
+
+pkg_setup() {
+       [[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+src_prepare() {
+       default
+       [[ ${PV} == *9999 ]] && eautoreconf
+       python_copy_sources
+}
+
+src_configure() {
+       configure() {
+               econf \
+                       --disable-static \
+                       $(use_enable openmp) \
+                       $(use_enable cairo) \
+                       --with-boost-python="boost_${EPYTHON/./}"
+       }
+       python_foreach_impl run_in_build_dir configure
+}
+
+src_compile() {
+       # most machines don't have enough ram for parallel builds
+       python_foreach_impl run_in_build_dir emake -j1
+}
+
+src_install() {
+       python_foreach_impl run_in_build_dir default
+       find "${D}" -name '*.la' -delete || die
+}

diff --git a/profiles/package.mask b/profiles/package.mask
index 5ae80603ce04ca27bbdd1ef2517f39af8d42bdbe..a4bb98e0b24a589f1dc85ca72772006113a16679 100644 (file)
--- a/profiles/package.mask
+++ b/profiles/package.mask
@@ -372,6 +372,7 @@ sys-boot/systemrescuecd-x86-grub
 >=dev-util/boost-build-1.70.0
 >=net-mail/libpst-0.6.66-r2
 >=net-proxy/trojan-1.12.2
+>=dev-python/graph-tool-2.27
 
 # Robin H. Johnson <robbat2@gentoo.org> (25 Mar 2019)
 # Requires >=dev-lang/lua-5.3 which is masked