sci-libs/indilib: Fix RDEPENDs, add USE websocket

Reported-by: Toralf Förster <toralf@gentoo.org>
Closes: https://bugs.gentoo.org/700876
Package-Manager: Portage-2.3.80, Repoman-2.3.19
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

diff --git a/sci-libs/indilib/indilib-1.8.2-r1.ebuild b/sci-libs/indilib/indilib-1.8.2-r1.ebuild
new file mode 100644 (file)
index 0000000..7e6d637
--- /dev/null
+++ b/sci-libs/indilib/indilib-1.8.2-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils udev
+
+DESCRIPTION="INDI Astronomical Control Protocol library"
+HOMEPAGE="https://www.indilib.org/"
+SRC_URI="https://github.com/${PN}/${PN/lib/}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD GPL-2+ LGPL-2+ LGPL-2.1+"
+SLOT="0/1"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="ogg test websocket"
+
+RDEPEND="
+       net-misc/curl
+       sci-libs/cfitsio:=
+       sci-libs/fftw:3.0=
+       sci-libs/gsl:=
+       sci-libs/libnova:=
+       sys-libs/zlib
+       virtual/jpeg:0
+       virtual/libusb:0
+       ogg? (
+               media-libs/libogg
+               media-libs/libtheora
+       )
+       websocket? ( dev-libs/boost:= )
+"
+DEPEND="${RDEPEND}
+       kernel_linux? ( sys-kernel/linux-headers )
+       test? ( >=dev-cpp/gtest-1.8.0 )
+       websocket? ( dev-cpp/websocketpp )
+"
+
+RESTRICT="!test? ( test )"
+
+S="${WORKDIR}/${P/lib/}"
+
+src_configure() {
+       local mycmakeargs=(
+               -DINDI_BUILD_QT5_CLIENT=OFF
+               -DINDI_BUILD_UNITTESTS=$(usex test)
+               -DUDEVRULES_INSTALL_DIR="$(get_udevdir)"
+               $(cmake-utils_use_find_package ogg OggTheora)
+               -DINDI_BUILD_WEBSOCKET=$(usex websocket)
+       )
+
+       cmake-utils_src_configure
+}
+
+src_test() {
+       BUILD_DIR="${BUILD_DIR}"/test cmake-utils_src_test
+}

diff --git a/sci-libs/indilib/metadata.xml b/sci-libs/indilib/metadata.xml
index f0a7e60d23ed94a36edd63933a5f0d2eb7684e67..5d5d0f3c56e49ae0f96e64fd4a9def90c88692a9 100644 (file)
--- a/sci-libs/indilib/metadata.xml
+++ b/sci-libs/indilib/metadata.xml
@@ -9,4 +9,7 @@
                <remote-id type="github">indilib/indi</remote-id>
                <remote-id type="sourceforge">indi</remote-id>
        </upstream>
+       <use>
+               <flag name="websocket">Enable support for WebSocket protocol</flag>
+       </use>
 </pkgmetadata>