dev-python/backports-weakref: New package

Bug: https://bugs.gentoo.org/688034
Copyright: Sony Interactive Entertainment Inc.
Package-Manager: Portage-2.3.67, Repoman-2.3.14
Signed-off-by: Zac Medico <zmedico@gentoo.org>

diff --git a/dev-python/backports-weakref/Manifest b/dev-python/backports-weakref/Manifest
new file mode 100644 (file)
index 0000000..6b5303d
--- /dev/null
+++ b/dev-python/backports-weakref/Manifest
@@ -0,0 +1 @@
+DIST backports.weakref-1.0.post1.tar.gz 10574 BLAKE2B a53a64dc22d8d1ac93a157bef4a858156f620593ae3d9e69b99762298e9aed73a04fd0557d98f53eed8816e746869718bc028aeda619330ce7c031f8b6f346b1 SHA512 27fb7ffd3313e62ca5ac220efe5ce0a9ae2ba8a589c80d3c5cf98741e913da7f713e1ecf2af848510383f574fa3bc3b7b3c21e6696f0a252fb517fe836c07cc7

diff --git a/dev-python/backports-weakref/backports-weakref-1.0_p1.ebuild b/dev-python/backports-weakref/backports-weakref-1.0_p1.ebuild
new file mode 100644 (file)
index 0000000..0271680
--- /dev/null
+++ b/dev-python/backports-weakref/backports-weakref-1.0_p1.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python2_7 python3_{5,6,7} )
+
+inherit distutils-r1
+
+MY_PN=${PN/-/.}
+MY_P=${MY_PN}-${PV/_p/.post}
+
+DESCRIPTION="Backport of new features in Python's weakref module"
+HOMEPAGE="https://github.com/PiDelport/backports.weakref https://pypi.org/project/backports.weakref/"
+SRC_URI="mirror://pypi/${P:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="PSF-2.3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE=""
+RDEPEND="dev-python/backports[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+       dev-python/setuptools[${PYTHON_USEDEP}]"
+# Tests require backports.test.support
+RESTRICT="test"
+S="${WORKDIR}/${MY_P}"
+
+python_prepare_all() {
+       sed -e "s|'setuptools_scm'||" \
+               -i setup.py || die
+       distutils-r1_python_prepare_all
+}
+
+python_test() {
+       PYTHONPATH="${BUILD_DIR}/lib" \
+               "${PYTHON:-python}" tests/test_weakref.py || die "tests failed with ${EPYTHON}"
+}
+
+python_install() {
+       # avoid a collision with dev-python/backports
+       rm "${BUILD_DIR}"/lib/backports/__init__.py || die
+       distutils-r1_python_install --skip-build
+}

diff --git a/dev-python/backports-weakref/metadata.xml b/dev-python/backports-weakref/metadata.xml
new file mode 100644 (file)
index 0000000..5cdefd3
--- /dev/null
+++ b/dev-python/backports-weakref/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+       <maintainer type="person">
+               <email>zmedico@gentoo.org</email>
+               <name>Zac Medico</name>
+       </maintainer>
+       <upstream>
+               <remote-id type="github">PiDelport/backports.weakref</remote-id>
+               <remote-id type="pypi">backports.weakref</remote-id>
+               <bugs-to>https://github.com/PiDelport/backports.weakref/issues</bugs-to>
+       </upstream>
+</pkgmetadata>