app-emulation/ski: fix built failure against glibc-2.28

<ustat.h> was removed in glibc-2.28.
While at it added missing dependency on binutils-libs.

Package-Manager: Portage-2.3.49, Repoman-2.3.10

diff --git a/app-emulation/ski/files/ski-1.3.2-glibc-2.28.patch b/app-emulation/ski/files/ski-1.3.2-glibc-2.28.patch
new file mode 100644 (file)
index 0000000..f09c5b4
--- /dev/null
+++ b/app-emulation/ski/files/ski-1.3.2-glibc-2.28.patch
@@ -0,0 +1,8 @@
+--- a/src/dos.c
++++ b/src/dos.c
+@@ -51,5 +51,2 @@ extern int localtime_r(const __time_t *, __struct_tm *);
+ #include <unistd.h>   /* Also #includes <utime.h> */
+-#if !defined(__FreeBSD__)
+-#include <ustat.h>
+-#endif
+ #include <sys/utsname.h>

diff --git a/app-emulation/ski/ski-1.3.2-r3.ebuild b/app-emulation/ski/ski-1.3.2-r3.ebuild
new file mode 100644 (file)
index 0000000..a6551f5
--- /dev/null
+++ b/app-emulation/ski/ski-1.3.2-r3.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools
+
+DESCRIPTION="ia64 instruction set simulator"
+HOMEPAGE="http://ski.sourceforge.net/ http://www.gelato.unsw.edu.au/IA64wiki/SkiSimulator"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="motif"
+
+RDEPEND="dev-libs/libltdl:0=
+       sys-libs/binutils-libs:0=
+       sys-libs/ncurses:0=
+       virtual/libelf
+       motif? ( x11-libs/motif:0= )"
+DEPEND="${RDEPEND}
+       sys-devel/bison
+       sys-devel/flex
+       dev-util/gperf"
+
+PATCHES=(
+       "${FILESDIR}"/${P}-syscall-linux-includes.patch
+       "${FILESDIR}"/${P}-remove-hayes.patch
+       "${FILESDIR}"/${P}-no-local-ltdl.patch
+       "${FILESDIR}"/${P}-AC_C_BIGENDIAN.patch
+       "${FILESDIR}"/${P}-configure-withval.patch
+       "${FILESDIR}"/${P}-binutils.patch
+       "${FILESDIR}"/${P}-uselib.patch #592226
+       "${FILESDIR}"/${P}-ncurses-config.patch
+       "${FILESDIR}"/${P}-prototypes.patch
+       "${FILESDIR}"/${P}-glibc-2.28.patch
+)
+
+src_prepare() {
+       default
+
+       rm -rf libltdl src/ltdl.[ch] macros/ltdl.m4
+
+       AT_M4DIR="macros" eautoreconf
+}
+
+src_configure() {
+       econf \
+               --without-included-ltdl \
+               --without-gtk \
+               $(use_with motif x11)
+}