gnome-extra/gnome-builder: Version bump

Package-Manager: portage-2.2.24

diff --git a/gnome-extra/gnome-builder/Manifest b/gnome-extra/gnome-builder/Manifest
index e915c345ca44f8edd600a8fbc147471f0521bde0..b124ce1ca2ba509f46868e1423074f80bd8f655e 100644 (file)
--- a/gnome-extra/gnome-builder/Manifest
+++ b/gnome-extra/gnome-builder/Manifest
@@ -1 +1,2 @@
 DIST gnome-builder-3.16.3.tar.xz 1733356 SHA256 a1d7b287d39ce724114c128e25bb00e273ecd8982ed22c8aba48cad9c4d51e61 SHA512 bd552763e958dd121f20adefab68de7d40d66fb3253c21ac9fe97eef7ffb5e98ea2b4ba21522db2cf1626c989bd6c04b27a16ba5e7ecb0bb66afc6299979652c WHIRLPOOL e690fafd8271fd9fd2908424f684bf2704bb768e51e50a8a983eb32f22e1d6807d66f381ebee849b8d7b73d4658301a57fbe6eeb32958ca9dd84ecb934a01d61
+DIST gnome-builder-3.18.1.tar.xz 1510460 SHA256 501c95220dcf8ca44a5748e863492377fe2c3aee78a95973d6819b1836e5407c SHA512 8e53b0d7a0afe440708bf33357408424cca5302e4516f85af18d04bce787012db681c93b6f48e9d41d8cb1a7c050d5e68770bf2e1ed8814ed43fa91e1d60c0f1 WHIRLPOOL d805338a3b49fe56794ddd9dca1ff047a4a9c87de24d06fed377637dba4e2ce8cf953cc8770e8745666dde1abfaabee9c68827631605a24e76e06148bed03f5b

diff --git a/gnome-extra/gnome-builder/gnome-builder-3.18.1.ebuild b/gnome-extra/gnome-builder/gnome-builder-3.18.1.ebuild
new file mode 100644 (file)
index 0000000..0239743
--- /dev/null
+++ b/gnome-extra/gnome-builder/gnome-builder-3.18.1.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+GCONF_DEBUG="no"
+PYTHON_COMPAT=( python{3_3,3_4,3_5} )
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 python-single-r1 vala virtualx
+
+DESCRIPTION="Builder attempts to be an IDE for writing software for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Builder"
+
+LICENSE="GPL-3+ GPL-2+ LGPL-3+ LGPL-2+ MIT CC-BY-SA-3.0 CC0-1.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+introspection python vala"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# FIXME: some unittests seem to hang forever
+RDEPEND="
+       >=dev-libs/gjs-1.42
+       >=dev-libs/glib-2.45.8:2[dbus]
+       dev-libs/libgit2[ssh,threads]
+       >=dev-libs/libgit2-glib-0.23.4[ssh]
+       >=dev-libs/libpeas-1.14.1
+       >=dev-libs/libxml2-2.9
+       dev-util/uncrustify
+       sys-devel/clang
+       >=x11-libs/gtk+-3.17.8:3[introspection?]
+       >=x11-libs/gtksourceview-3.17.7:3.0[introspection?]
+       introspection? ( >=dev-libs/gobject-introspection-1.42:= )
+       python? (
+               ${PYTHON_DEPS}
+               dev-python/pygobject:3 )
+       vala? ( $(vala_depend) )
+"
+DEPEND="${RDEPEND}
+       dev-libs/appstream-glib
+       >=dev-util/gtk-doc-am-1.11
+       >=dev-util/intltool-0.50.1
+       >=sys-devel/gettext-0.18
+       virtual/pkgconfig
+"
+
+pkg_setup() {
+       use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+       use vala && vala_src_prepare
+       gnome2_src_prepare
+}
+
+src_configure() {
+       use python && export PYTHON3_CONFIG="$(python_get_PYTHON_CONFIG)"
+       gnome2_src_configure \
+               --disable-static \
+               $(use_enable introspection) \
+               $(use_enable python python-pack-plugin) \
+               $(use_enable vala vala-pack-plugin)
+}
+
+src_test() {
+       # FIXME: this should be handled at eclass level
+       "${EROOT}${GLIB_COMPILE_SCHEMAS}" --allow-any-name "${S}/data/gsettings" || die
+
+       GSETTINGS_SCHEMA_DIR="${S}/data/gsettings" Xemake check
+}