media-sound/playerctl: bump to 0.6.0

Package-Manager: Portage-2.3.19, Repoman-2.3.6

diff --git a/media-sound/playerctl/Manifest b/media-sound/playerctl/Manifest
index aedd19a08d060248d0c70dc09cc2c5cab5f1191c..8abb779fa23725c39b71bce3020de95bbe1f2f09 100644 (file)
--- a/media-sound/playerctl/Manifest
+++ b/media-sound/playerctl/Manifest
@@ -1 +1,2 @@
 DIST playerctl-0.5.0.tar.gz 17015 BLAKE2B 5da1d0fd4e442ac5f124bd693ae14222624c5239c9fad72e57d43977467339522344bc8d8c37b0f2bfda51c61861dc33d7e35e4a730ce59a87b691b5657ec729 SHA512 307cad5eeea7efa0c97c885660f49468f442fe907ef2495b56ac512e0551c7248750897b6d00934cbfcfcb35f486a101a238b276ef71d2ef866132ca3cc0932c
+DIST playerctl-0.6.0.tar.gz 22124 BLAKE2B 6bb90586c56e21a00b5e6e1769248b9782a8211b01dacf590857fe4fe199d6d3fa7aa46a36cba9a8e198a1aad0bf17973fc15140db11c484edfb0275971d3d08 SHA512 8023b5704ca2a428510df6228850b616061289764cc3c4190c0c46f79d6a20e499495f2d773bd821357653ba63bca40eac70f7cc3a11251da3c6a4f7781db739

diff --git a/media-sound/playerctl/playerctl-0.6.0.ebuild b/media-sound/playerctl/playerctl-0.6.0.ebuild
new file mode 100644 (file)
index 0000000..ae41da2
--- /dev/null
+++ b/media-sound/playerctl/playerctl-0.6.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools xdg-utils
+
+DESCRIPTION="A CLI utility to control media players over MPRIS"
+HOMEPAGE="https://github.com/acrisci/playerctl"
+SRC_URI="https://github.com/acrisci/playerctl/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc"
+
+RDEPEND="
+       dev-libs/glib:2
+       dev-libs/gobject-introspection
+"
+DEPEND="${RDEPEND}
+       dev-util/gdbus-codegen
+       dev-util/gtk-doc-am
+       doc? ( dev-util/gtk-doc )
+       virtual/pkgconfig
+"
+
+src_prepare() {
+       if ! use doc; then
+               echo 'EXTRA_DIST = ' > gtk-doc.make || die
+       fi
+
+       default
+       eautoreconf
+}
+
+src_configure() {
+       xdg_environment_reset # 596166
+
+       econf \
+               $(use_enable doc gtk-doc) \
+               $(use_enable doc gtk-doc-html)
+}
+
+src_compile() {
+       emake -j1
+}
+
+src_install() {
+       default
+       find "${ED}" -name '*.la' -delete || die
+}