sys-libs/libieee1284: Rev bump to fix multilib usage

The fix from bug 619810 (commit 8c950f9ec6) was wrong and caused the
breakage seen in bug 634218.

Thanks to Mike Gilbert for finding the root cause for bug 619810.

Fixes: https://bugs.gentoo.org/634218
Bug: https://bugs.gentoo.org/619810
Package-Manager: Portage-2.3.13, Repoman-2.3.4
RepoMan-Options: --force

diff --git a/sys-libs/libieee1284/libieee1284-0.2.11-r6.ebuild b/sys-libs/libieee1284/libieee1284-0.2.11-r6.ebuild
new file mode 100644 (file)
index 0000000..eddd151
--- /dev/null
+++ b/sys-libs/libieee1284/libieee1284-0.2.11-r6.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit python-single-r1 multilib-minimal
+
+DESCRIPTION="Library to query devices using IEEE1284"
+HOMEPAGE="http://cyberelk.net/tim/software/libieee1284/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 ppc x86 ~x86-fbsd"
+IUSE="doc python static-libs"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+       python? ( ${PYTHON_DEPS} )"
+DEPEND="${RDEPEND}
+       doc? (
+               app-text/docbook-sgml-utils
+               >=app-text/docbook-sgml-dtd-4.1
+               app-text/docbook-dsssl-stylesheets
+               dev-perl/XML-RegExp
+       )"
+
+pkg_setup() {
+       use python && python-single-r1_pkg_setup
+}
+
+multilib_src_configure() {
+       ECONF_SOURCE="${S}" econf \
+               --enable-shared \
+               $(use_enable static-libs static) \
+               $(multilib_native_use_with python)
+}
+
+multilib_src_install_all() {
+       einstalldocs
+       dodoc doc/interface*
+
+       if ! use static-libs; then
+               find "${D}" -name '*.la' -delete || die
+       fi
+}