dev-python/nbconvert: Version bump

Package-Manager: portage-2.2.28

diff --git a/dev-python/nbconvert/Manifest b/dev-python/nbconvert/Manifest
index 18314c5481ef0878334e9a6c09292c30409d1db3..e252c3701f3c6453e4541dc075815dda2fd7020d 100644 (file)
--- a/dev-python/nbconvert/Manifest
+++ b/dev-python/nbconvert/Manifest
@@ -1 +1,2 @@
 DIST nbconvert-4.1.0.tar.gz 263948 SHA256 e0296e45293dd127d028f678e3b6aba3f1db3283a134178bdb49eea402d4cf1c SHA512 9761cf8cdf206bd8f27c666d7b520cbd7d805353cf46b212b46ee6053b47ec6728a5926dfe59acef109c8770580c41d51aa5b943a27e72bccecc68a7d7b68bfb WHIRLPOOL 9cc27a45b00ee9914674cd14a279be1691eb8a8538803bdda127513f56dd0ce53b10745f305f8fb82abd2d19efe7c1b0284bf05f8088360d2def6c97db0c1c6e
+DIST nbconvert-4.2.0.tar.gz 428726 SHA256 55946d7522741294fcdd50799bd1777d16673ce721fecca0610cdb86749863c6 SHA512 441d32e5bd63cb7d0b9a70b814ec6ea647a04542601461cb8b008f4f9ab894f5729687093400703b222435100384378653fbbb38427431d9da62992ef778906a WHIRLPOOL 024ef6b9a70a9248431c71092de7ae993fad1144110669c0d538d13646cd991b5389f4550c269c55c541d96526541b884d5dec8632048a9365eb1986fe34d85a

diff --git a/dev-python/nbconvert/nbconvert-4.2.0.ebuild b/dev-python/nbconvert/nbconvert-4.2.0.ebuild
new file mode 100644 (file)
index 0000000..1ae46dc
--- /dev/null
+++ b/dev-python/nbconvert/nbconvert-4.2.0.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5} )
+
+inherit distutils-r1
+
+DESCRIPTION="Converting Jupyter Notebooks"
+HOMEPAGE="http://jupyter.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+       dev-python/jupyter_core[${PYTHON_USEDEP}]
+       dev-python/nbformat[${PYTHON_USEDEP}]
+       dev-python/mistune[${PYTHON_USEDEP}]
+       dev-python/jinja[${PYTHON_USEDEP}]
+       dev-python/pygments[${PYTHON_USEDEP}]
+       dev-python/traitlets[${PYTHON_USEDEP}]
+       dev-python/entrypoints[${PYTHON_USEDEP}]
+       "
+DEPEND="${RDEPEND}
+       doc? (
+               dev-python/ipython[${PYTHON_USEDEP}]
+               dev-python/jupyter_client[${PYTHON_USEDEP}]
+               dev-python/sphinx[${PYTHON_USEDEP}]
+               app-text/pandoc
+       )
+       test? (
+               dev-python/nose[${PYTHON_USEDEP}]
+               dev-python/coverage[${PYTHON_USEDEP}]
+               dev-python/ipykernel[${PYTHON_USEDEP}]
+       )
+       "
+
+python_prepare_all() {
+       # Prevent un-needed download during build
+       if use doc; then
+               sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die
+       fi
+
+       distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+       use doc && emake -C docs html
+}
+
+python_test() {
+       distutils_install_for_testing
+       cd "${TEST_DIR}"/lib || die
+       nosetests --with-coverage --cover-package=nbconvert nbconvert || die
+}
+
+python_install_all() {
+       use doc && HTML_DOCS=( docs/build/html/. )
+       distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+       if ! has_version app-text/pandoc ; then
+               einfo "Pandoc is required for converting to formats other than Python,"
+               einfo "HTML, and Markdown. If you need this functionality, install"
+               einfo "app-text/pandoc."
+       fi
+}