mate-base/mate-session-manager: Version bump (v1.22.0)

Signed-off-by: Mikle Kolyada <zlogene@gentoo.org>
Package-Manager: Portage-2.3.62, Repoman-2.3.11

diff --git a/mate-base/mate-session-manager/Manifest b/mate-base/mate-session-manager/Manifest
index 133427b70a36f0fe73567384acf926d764400120..583bf9a9957d5b921787f685b5d895b876e43612 100644 (file)
--- a/mate-base/mate-session-manager/Manifest
+++ b/mate-base/mate-session-manager/Manifest
@@ -1 +1,2 @@
 DIST mate-session-manager-1.18.2.tar.xz 570336 BLAKE2B d1fd8f6a037fa38833d4aae05dcc9ed98ff192c712819342a77d19fb00e09febaa90fd0396048a3cee64ea424c6a72e8ae90f067d61929ef524825c97d500f8e SHA512 e3d3e2524cd0d00930b5c6b81134b969555f00550d23a357d426a6f0d475884ce6ab16be365fd5e95801dd53c250069ad091dec6c93f2ab70818460fbef4765e
+DIST mate-session-manager-1.22.0.tar.xz 603016 BLAKE2B 5d7064756b7d7d2ca4fdebf18319dc8a8d8eca6ed31c5e8e37e503c7099a0d541186028d6b4e174bff1ce9ca727a374e9597498b2ca6d5494dc74f21fec0baeb SHA512 7e5e21e37c7ac55ca7d71302edef9aabeccf39233aec9edfe93a2fdcd4150d039e8121adecebb3d0a4a707eccef0c7afa1b54c5b52b57853242964c7506eeb9a

diff --git a/mate-base/mate-session-manager/mate-session-manager-1.22.0.ebuild b/mate-base/mate-session-manager/mate-session-manager-1.22.0.ebuild
new file mode 100644 (file)
index 0000000..ed715c0
--- /dev/null
+++ b/mate-base/mate-session-manager/mate-session-manager-1.22.0.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit mate
+
+if [[ ${PV} != 9999 ]]; then
+       KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
+
+DESCRIPTION="MATE session manager"
+HOMEPAGE="http://mate-desktop.org/"
+
+LICENSE="GPL-2 LGPL-2 FDL-1.1"
+SLOT="0"
+
+IUSE="debug elibc_FreeBSD gnome-keyring ipv6 systemd +xtrans"
+
+# x11-misc/xdg-user-dirs{,-gtk} are needed to create the various XDG_*_DIRs, and
+# create .config/user-dirs.dirs which is read by glib to get G_USER_DIRECTORY_*
+# xdg-user-dirs-update is run during login (see 10-user-dirs-update-gnome below).
+
+COMMON_DEPEND=">=dev-libs/dbus-glib-0.76
+       >=dev-libs/glib-2.50:2
+       dev-libs/libxslt
+       sys-apps/dbus
+       x11-libs/gdk-pixbuf:2
+       >=x11-libs/gtk+-3.22:3
+       x11-libs/libICE
+       x11-libs/libSM
+       x11-libs/libX11
+       x11-libs/libXau
+       x11-libs/libXext
+       x11-libs/libXrender
+       x11-libs/libXtst
+       x11-libs/pango
+       virtual/libintl
+       elibc_FreeBSD? ( || ( dev-libs/libexecinfo >=sys-freebsd/freebsd-lib-10.0 ) )
+       systemd? ( sys-apps/systemd )
+       !systemd? ( >=sys-auth/consolekit-0.9.2 )
+       xtrans? ( x11-libs/xtrans )"
+
+RDEPEND="${COMMON_DEPEND}
+       x11-apps/xdpyinfo
+       x11-misc/xdg-user-dirs
+       x11-misc/xdg-user-dirs-gtk
+       gnome-keyring? ( gnome-base/gnome-keyring )"
+
+DEPEND="${COMMON_DEPEND}
+       >=dev-util/intltool-0.40
+       >=dev-lang/perl-5
+       >=sys-devel/gettext-0.10.40:*
+       virtual/pkgconfig:*
+       !<gnome-base/gdm-2.20.4"
+
+MATE_FORCE_AUTORECONF=true
+
+src_configure() {
+       mate_src_configure \
+               --docdir="${EPREFIX}/usr/share/doc/${PF}" \
+               $(use_with systemd) \
+               $(use_with xtrans)  \
+               $(use_enable debug) \
+               $(use_enable ipv6)
+}
+
+src_install() {
+       mate_src_install
+
+       dodir /etc/X11/Sessions/
+       exeinto /etc/X11/Sessions/
+       doexe "${FILESDIR}"/MATE
+
+       dodir /usr/share/mate/applications/
+       insinto /usr/share/mate/applications/
+       doins "${FILESDIR}"/defaults.list
+
+       dodir /etc/X11/xinit/xinitrc.d/
+       exeinto /etc/X11/xinit/xinitrc.d/
+       doexe "${FILESDIR}"/15-xdg-data-mate
+
+       # This should be done in MATE too, see Gentoo bug #270852
+       doexe "${FILESDIR}"/10-user-dirs-update-mate
+}