sys-power/acpid: add 2.0.29-r1 for further improvements

Package-Manager: Portage-2.3.31, Repoman-2.3.9

diff --git a/sys-power/acpid/acpid-2.0.29-r1.ebuild b/sys-power/acpid/acpid-2.0.29-r1.ebuild
new file mode 100644 (file)
index 0000000..f969980
--- /dev/null
+++ b/sys-power/acpid/acpid-2.0.29-r1.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit linux-info systemd
+
+DESCRIPTION="Daemon for Advanced Configuration and Power Interface"
+HOMEPAGE="https://sourceforge.net/projects/acpid2"
+SRC_URI="mirror://sourceforge/${PN}2/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ia64 ~x86"
+IUSE="selinux"
+
+RDEPEND="selinux? ( sec-policy/selinux-apm )"
+DEPEND=">=sys-kernel/linux-headers-3"
+
+pkg_pretend() {
+       local CONFIG_CHECK="~INPUT_EVDEV"
+       local WARNING_INPUT_EVDEV="CONFIG_INPUT_EVDEV is required for ACPI button event support."
+       [[ ${MERGE_TYPE} != buildonly ]] && check_extra_config
+}
+
+pkg_setup() { :; }
+
+PATCHES=(
+       "${FILESDIR}"/${PN}-2.0.25-kde4.patch #515088
+       "${FILESDIR}"/${PN}-2.0.25-add_mate-power-manager.patch #538590
+)
+
+src_install() {
+       emake DESTDIR="${D}" install
+
+       newdoc kacpimon/README README.kacpimon
+       dodoc -r samples
+       rm -f "${D}"/usr/share/doc/${PF}/COPYING || die
+
+       exeinto /etc/acpi
+       newexe "${FILESDIR}"/${PN}-1.0.6-default.sh default.sh
+       exeinto /etc/acpi/actions
+       newexe samples/powerbtn/powerbtn.sh powerbtn.sh
+       insinto /etc/acpi/events
+       newins "${FILESDIR}"/${PN}-1.0.4-default default
+
+       newinitd "${FILESDIR}"/${PN}-2.0.26-init.d ${PN}
+       newconfd "${FILESDIR}"/${PN}-2.0.16-conf.d ${PN}
+
+       systemd_dounit "${FILESDIR}"/systemd/${PN}.{service,socket}
+}
+
+pkg_postinst() {
+       if [[ -z ${REPLACING_VERSIONS} ]]; then
+               elog
+               elog "You may wish to read the Gentoo Linux Power Management Guide,"
+               elog "which can be found online at:"
+               elog "https://wiki.gentoo.org/wiki/Power_management/Guide"
+               elog
+       fi
+
+       # files/systemd/acpid.socket -> ListenStream=/run/acpid.socket
+       mkdir -p "${ROOT%/}"/run
+
+       if ! grep -qs "^tmpfs.*/run " "${ROOT%/}"/proc/mounts ; then
+               echo
+               ewarn "You should reboot the system now to get /run mounted with tmpfs!"
+       fi
+}