dev-games/tiled: version bump 1.0.0

Package-Manager: Portage-2.3.5, Repoman-2.3.2

diff --git a/dev-games/tiled/Manifest b/dev-games/tiled/Manifest
index 077fc3755ee032d5d0f4ae9badbd9380abb4ca4f..3f546102b036869df824a62eb169b601d61ad1cc 100644 (file)
--- a/dev-games/tiled/Manifest
+++ b/dev-games/tiled/Manifest
@@ -1 +1,2 @@
 DIST tiled-0.18.2.tar.gz 6409369 SHA256 575e110dd4904f785222d9a298f63eddf5c5b0b8f1450cb684ef3a9ae91292cd SHA512 6cb6844541fc4e52e05e8d12974af395161fbe0c03dddd9be362b6df7a88620ddf13c3a96f8cdb175662d3ae13f162137cf74b6b4c2664ca7dd753e3cb48cd26 WHIRLPOOL 2945156eb99f88d65fa276e1d9a52724e09c996b35fa2bf1d198a41f5785cd52da3d090c268ac4a445dbf94cac12b66ab515b0786ff8bcd9798176220cc937bf
+DIST tiled-1.0.0.tar.gz 6575292 SHA256 a5e5f1f3ec9428f124e1fbe65ac3b7ab3c17dc13a3c0d489ff6d356f7f6ad43c SHA512 a5d8af9a1aeae5c4a9eefc865e28ad22c61dad6d04878867c495bbc0c9491723bc51ed30e428fd4d1eaed5c752f90e595d46cc46cde745588556a8b9fa2db727 WHIRLPOOL 7a8241314a60f6ad2c78b4067772475e151645d6668a0f975d177332334f52e79b5ee7e648395e67214d98889bf9d73da5a82d60c4a52a35c5e7cba05df6932d

diff --git a/dev-games/tiled/tiled-1.0.0.ebuild b/dev-games/tiled/tiled-1.0.0.ebuild
new file mode 100644 (file)
index 0000000..065606a
--- /dev/null
+++ b/dev-games/tiled/tiled-1.0.0.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+inherit gnome2-utils multilib python-single-r1 qmake-utils xdg
+
+DESCRIPTION="A general purpose tile map editor"
+HOMEPAGE="http://www.mapeditor.org/"
+SRC_URI="https://github.com/bjorn/tiled/archive/v${PV}/${P}.tar.gz"
+
+LICENSE="BSD BSD-2 GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="examples python"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+       >=dev-qt/qtcore-5.6:5
+       >=dev-qt/qtgui-5.6:5
+       >=dev-qt/qtnetwork-5.6:5
+       >=dev-qt/qtopengl-5.6:5
+       >=dev-qt/qtwidgets-5.6:5
+       sys-libs/zlib
+       python? ( ${PYTHON_DEPS} )
+"
+DEPEND="${RDEPEND}
+       dev-qt/linguist-tools:5
+"
+
+DOCS=( AUTHORS COPYING NEWS.md README.md )
+
+pkg_setup() {
+       use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+       eqmake5 LIBDIR="/usr/$(get_libdir)" PREFIX="/usr" DISABLE_PYTHON_PLUGIN="$(usex !python)"
+}
+
+src_install() {
+       emake INSTALL_ROOT="${D}" install
+
+       einstalldocs
+
+       if use examples ; then
+               docompress -x /usr/share/doc/${PF}/examples
+               dodoc -r examples
+       fi
+}
+
+pkg_postinst() {
+       gnome2_icon_cache_update
+       xdg_desktop_database_update
+       xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+       gnome2_icon_cache_update
+       xdg_desktop_database_update
+       xdg_mimeinfo_database_update
+}