net-wireless/blueman: fix DHCP server dir & kernel config check

Closes: https://bugs.gentoo.org/596634
Closes: https://bugs.gentoo.org/628924
Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Tiziano Müller <dev-zero@gentoo.org>

diff --git a/net-wireless/blueman/blueman-2.1_alpha3-r1.ebuild b/net-wireless/blueman/blueman-2.1_alpha3-r1.ebuild
new file mode 100644 (file)
index 0000000..80488b8
--- /dev/null
+++ b/net-wireless/blueman/blueman-2.1_alpha3-r1.ebuild
@@ -0,0 +1,123 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+PYTHON_COMPAT=( python3_{5,6,7} )
+inherit gnome2-utils linux-info python-single-r1 systemd
+
+DESCRIPTION="Simple and intuitive GTK+ Bluetooth Manager"
+HOMEPAGE="https://github.com/blueman-project/blueman"
+
+if [[ ${PV} == "9999" ]] ; then
+       inherit autotools git-r3
+       EGIT_REPO_URI="https://github.com/blueman-project/blueman.git"
+       KEYWORDS=""
+else
+       SRC_URI="https://github.com/blueman-project/${PN}/releases/download/${PV/_/.}/${P/_/.}.tar.xz"
+       KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="appindicator network nls policykit pulseaudio"
+
+DEPEND="
+       dev-python/pygobject:3[${PYTHON_USEDEP}]
+       >=net-wireless/bluez-5:=
+       ${PYTHON_DEPS}"
+BDEPEND="
+       dev-python/cython[${PYTHON_USEDEP}]
+       virtual/pkgconfig
+       nls? ( dev-util/intltool sys-devel/gettext )"
+RDEPEND="${DEPEND}
+       dev-python/dbus-python[${PYTHON_USEDEP}]
+       dev-python/pycairo[${PYTHON_USEDEP}]
+       sys-apps/dbus
+       x11-libs/gtk+:3[introspection]
+       x11-libs/libnotify[introspection]
+       || (
+               x11-themes/adwaita-icon-theme
+               x11-themes/faenza-icon-theme
+               x11-themes/mate-icon-theme
+       )
+       appindicator? ( dev-libs/libappindicator:3[introspection] )
+       network? (
+               net-firewall/iptables
+               || (
+                       sys-apps/net-tools
+                       sys-apps/iproute2
+               )
+               || (
+                       net-dns/dnsmasq
+                       net-misc/dhcp
+                       >=net-misc/networkmanager-0.8
+               )
+       )
+       policykit? ( sys-auth/polkit )
+       pulseaudio? ( media-sound/pulseaudio[bluetooth] )
+       !net-wireless/gnome-bluetooth
+"
+
+S=${WORKDIR}/${P/_/.}
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+pkg_pretend() {
+       if use network; then
+               local CONFIG_CHECK="~BRIDGE ~IP_NF_IPTABLES
+                       ~IP_NF_NAT ~IP_NF_TARGET_MASQUERADE"
+               check_extra_config
+       fi
+}
+
+pkg_setup() {
+       python-single-r1_pkg_setup
+}
+
+src_prepare() {
+       default
+       [[ ${PV} == 9999 ]] && eautoreconf
+}
+
+src_configure() {
+       local myconf=(
+               --docdir=/usr/share/doc/${PF}
+               --disable-runtime-deps-check
+               --disable-static
+               --with-systemdsystemunitdir="$(systemd_get_systemunitdir)"
+               --with-systemduserunitdir="$(systemd_get_userunitdir)"
+               --with-dhcp-config="/etc/dhcp/dhcpd.conf"
+               $(use_enable appindicator)
+               $(use_enable policykit polkit)
+               $(use_enable nls)
+               $(use_enable pulseaudio)
+               # thunar integration is a single data file with no extra deps
+               # so install it unconditionally
+               --enable-thunar-sendto
+       )
+       econf "${myconf[@]}"
+}
+
+src_install() {
+       default
+
+       if use policykit; then
+               # Allow users in plugdev group to modify connections
+               insinto /usr/share/polkit-1/rules.d
+               doins "${FILESDIR}/01-org.blueman.rules"
+       fi
+
+       python_fix_shebang "${D}"
+       rm "${D}"/$(python_get_sitedir)/*.la || die
+}
+
+pkg_postinst() {
+       gnome2_icon_cache_update
+       gnome2_schemas_update
+}
+
+pkg_postrm() {
+       gnome2_icon_cache_update
+       gnome2_schemas_update
+}

diff --git a/net-wireless/blueman/blueman-9999.ebuild b/net-wireless/blueman/blueman-9999.ebuild
index c05adb445a66f983af7542e984bad83db90c0a43..d7fc408394e5d34ed63c9dc7cd18fbb50e307aac 100644 (file)
--- a/net-wireless/blueman/blueman-9999.ebuild
+++ b/net-wireless/blueman/blueman-9999.ebuild
@@ -1,9 +1,9 @@
-# Copyright 1999-2018 Gentoo Authors
+# Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI="6"
+EAPI="7"
 
-PYTHON_COMPAT=( python{3_4,3_5,3_6,3_7} )
+PYTHON_COMPAT=( python3_{5,6,7} )
 inherit gnome2-utils linux-info python-single-r1 systemd
 
 DESCRIPTION="Simple and intuitive GTK+ Bluetooth Manager"
@@ -14,7 +14,7 @@ if [[ ${PV} == "9999" ]] ; then
        EGIT_REPO_URI="https://github.com/blueman-project/blueman.git"
        KEYWORDS=""
 else
-       SRC_URI="https://github.com/blueman-project/${PN}/releases/download/${PV}/${P}.tar.xz"
+       SRC_URI="https://github.com/blueman-project/${PN}/releases/download/${PV/_/.}/${P/_/.}.tar.xz"
        KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
 fi
 
@@ -22,15 +22,15 @@ LICENSE="GPL-3"
 SLOT="0"
 IUSE="appindicator network nls policykit pulseaudio"
 
-COMMON_DEPEND="
+DEPEND="
        dev-python/pygobject:3[${PYTHON_USEDEP}]
        >=net-wireless/bluez-5:=
        ${PYTHON_DEPS}"
-DEPEND="${COMMON_DEPEND}
+BDEPEND="
        dev-python/cython[${PYTHON_USEDEP}]
        virtual/pkgconfig
        nls? ( dev-util/intltool sys-devel/gettext )"
-RDEPEND="${COMMON_DEPEND}
+RDEPEND="${DEPEND}
        dev-python/dbus-python[${PYTHON_USEDEP}]
        dev-python/pycairo[${PYTHON_USEDEP}]
        sys-apps/dbus
@@ -65,12 +65,11 @@ pkg_pretend() {
        if use network; then
                local CONFIG_CHECK="~BRIDGE ~IP_NF_IPTABLES
                        ~IP_NF_NAT ~IP_NF_TARGET_MASQUERADE"
-               linux-info_pkg_setup
+               check_extra_config
        fi
 }
 
 pkg_setup() {
-       pkg_pretend
        python-single-r1_pkg_setup
 }
 
@@ -86,6 +85,7 @@ src_configure() {
                --disable-static
                --with-systemdsystemunitdir="$(systemd_get_systemunitdir)"
                --with-systemduserunitdir="$(systemd_get_userunitdir)"
+               --with-dhcp-config="/etc/dhcp/dhcpd.conf"
                $(use_enable appindicator)
                $(use_enable policykit polkit)
                $(use_enable nls)