app-emulation/q4wine: version bump 1.3.5

Package-Manager: Portage-2.3.6, Repoman-2.3.2

diff --git a/app-emulation/q4wine/Manifest b/app-emulation/q4wine/Manifest
index 074e1b7772da569b0d79025da25a8d8a515296bf..c51497acbb517c0ad392436a8cbc6ade132dd84c 100644 (file)
--- a/app-emulation/q4wine/Manifest
+++ b/app-emulation/q4wine/Manifest
@@ -1 +1,2 @@
 DIST q4wine-1.3.4.tar.bz2 3013860 SHA256 9862c9353964ed51802342896f6fd0ca3c1d759cc1b7161c8447d447e9b6b4bd SHA512 e5fa50ebf0c098a02d3ee9dfdd5b8ef16eef57f47bef9f43a9849ce7df2f8d66da3404e688b738ff8ccd01be63217d6352aaba803de2383b7e1b0ea1c3c6d565 WHIRLPOOL 5fa4b83da73dcee27e278b849573b1ea16d96cd5b8cb77c247ba70548fe0d78cae72d6adf55fb87c38b31c7d54e574fb6f9c5d00ff82bf759c33134bb4597938
+DIST q4wine-1.3.5.tar.bz2 2862445 SHA256 aa48b0ea8ff504e341b3352194380aa256f6ac8a6a301e1bbf30196eec8d310c SHA512 54fb7bce28750cb71589f6a94658f61369c7777cf7865b71d2feea4ac1221714d861a781fbd1325ee3d21f124162fd2eedc2780ab2bd0af93864eefebcde5f4c WHIRLPOOL b52408ade21dab7203b3d8032e196a2e63f5a806f08fcd8fa6a1d839b4f457475b94d0962e29dbd0ac0a5a9bcaf9bd64786b2268af9b6fc446d1328baee3c1fe

diff --git a/app-emulation/q4wine/q4wine-1.3.5.ebuild b/app-emulation/q4wine/q4wine-1.3.5.ebuild
new file mode 100644 (file)
index 0000000..e9e247c
--- /dev/null
+++ b/app-emulation/q4wine/q4wine-1.3.5.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils gnome2-utils xdg-utils
+
+# Upstream names the package PV-rX. We change that to
+# PV_pX so we can use portage revisions.
+MY_P=${PN}-${PV/_p/-r}
+
+DESCRIPTION="Qt GUI configuration tool for Wine"
+HOMEPAGE="http://q4wine.brezblock.org.ua/"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+dbus debug +ico +iso +wineappdb"
+
+CDEPEND="
+       dev-qt/qtcore:5
+       dev-qt/qtgui:5
+       dev-qt/qtnetwork:5
+       dev-qt/qtsingleapplication[qt5,X]
+       dev-qt/qtsql:5[sqlite]
+       dev-qt/qtwidgets:5
+       dev-qt/qtxml:5
+       dbus? ( dev-qt/qtdbus:5 )
+       ico? ( >=media-gfx/icoutils-0.26.0 )
+"
+DEPEND="${CDEPEND}
+       dev-qt/linguist-tools:5
+"
+RDEPEND="${CDEPEND}
+       app-admin/sudo
+       >=sys-apps/which-2.19
+       iso? ( sys-fs/fuseiso )
+"
+
+S=${WORKDIR}/${MY_P}
+
+DOCS=( AUTHORS ChangeLog README )
+
+src_configure() {
+       local mycmakeargs=(
+               -DQT5=ON
+               -DDEBUG=$(usex debug ON OFF)
+               -DWITH_ICOUTILS=$(usex ico ON OFF)
+               -DWITH_SYSTEM_SINGLEAPP=ON
+               -DWITH_WINEAPPDB=$(usex wineappdb ON OFF)
+               -DUSE_BZIP2=OFF
+               -DUSE_GZIP=OFF
+               -DWITH_DBUS=$(usex dbus ON OFF)
+       )
+       cmake-utils_src_configure
+}
+
+pkg_postinst() {
+       gnome2_icon_cache_update
+       xdg_desktop_database_update
+}
+
+pkg_postrm() {
+       gnome2_icon_cache_update
+       xdg_desktop_database_update
+}