dev-python/qscintilla-python: add 2.11.1, drop python3_4 support

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Davide Pesavento <pesa@gentoo.org>

diff --git a/dev-python/qscintilla-python/Manifest b/dev-python/qscintilla-python/Manifest
index a3b924ad27c7e32b6638957c5b31934090bae4cb..3b4a37e043fbc7e54bc839dd3a37125a945fae7a 100644 (file)
--- a/dev-python/qscintilla-python/Manifest
+++ b/dev-python/qscintilla-python/Manifest
@@ -1 +1,2 @@
 DIST QScintilla_gpl-2.10.8.tar.gz 2736054 BLAKE2B 4bc7a2bc1974f8e10a96b7716a8e35d4854e9eeb8040734f99b796bddd9679ee2539f6517743689f9d7deff9ce523cdbb2f77ccd65eaadfc947dcc7a1337d918 SHA512 c0a216737dbda6bc390225196b37a43e4884c9cd67e6e81fc1b1b952683fe88dbfe7caf3c66d94a378f37502e1f08cbdf788426248e73f5f66ec65982b7652b5
+DIST QScintilla_gpl-2.11.1.tar.gz 2932060 BLAKE2B 9f2f9fd89667cc04c95d0a36e4a615dcf3c1c11a5446e19a43104513894b76bc7478f2aed7e8c94ce413f940327deb09e51507bee1fa35c79c176e01e6b74767 SHA512 40b600aa8eec17bc99491a08aeaee72bf498a66f0257d310a8df2667de82805715b9c859885c092acfb03ba8f69433a6517d0d4bb324bf99bd9db461172c08d5

diff --git a/dev-python/qscintilla-python/qscintilla-python-2.10.8.ebuild b/dev-python/qscintilla-python/qscintilla-python-2.10.8.ebuild
index a03ddc26eb022336f428e042c6f56a3b6531621c..1b2bcb06dd656dc4cea7da86e1e879658e339db0 100644 (file)
--- a/dev-python/qscintilla-python/qscintilla-python-2.10.8.ebuild
+++ b/dev-python/qscintilla-python/qscintilla-python-2.10.8.ebuild
@@ -1,9 +1,9 @@
-# Copyright 1999-2018 Gentoo Authors
+# Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
 
-PYTHON_COMPAT=( python2_7 python3_{4,5,6,7} )
+PYTHON_COMPAT=( python2_7 python3_{5,6,7} )
 inherit python-r1 qmake-utils
 
 MY_P=QScintilla_gpl-${PV/_pre/.dev}

diff --git a/dev-python/qscintilla-python/qscintilla-python-2.11.1.ebuild b/dev-python/qscintilla-python/qscintilla-python-2.11.1.ebuild
new file mode 100644 (file)
index 0000000..dfe6ef7
--- /dev/null
+++ b/dev-python/qscintilla-python/qscintilla-python-2.11.1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{5,6,7} )
+inherit python-r1 qmake-utils
+
+MY_P=QScintilla_gpl-${PV/_pre/.dev}
+
+DESCRIPTION="Python bindings for QScintilla"
+HOMEPAGE="https://www.riverbankcomputing.com/software/qscintilla/intro"
+SRC_URI="https://www.riverbankcomputing.com/static/Downloads/QScintilla/${MY_P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+IUSE="debug"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="
+       ${PYTHON_DEPS}
+       >=dev-python/sip-4.19:=[${PYTHON_USEDEP}]
+       dev-python/PyQt5[gui,printsupport,widgets,${PYTHON_USEDEP}]
+       dev-qt/qtcore:5
+       dev-qt/qtgui:5
+       dev-qt/qtprintsupport:5
+       dev-qt/qtwidgets:5
+       ~x11-libs/qscintilla-${PV}:=
+"
+RDEPEND="${DEPEND}"
+
+S=${WORKDIR}/${MY_P}/Python
+
+src_prepare() {
+       default
+       python_copy_sources
+}
+
+src_configure() {
+       configuration() {
+               local myconf=(
+                       "${PYTHON}"
+                       configure.py
+                       --pyqt=PyQt5
+                       --qmake="$(qt5_get_bindir)"/qmake
+                       --sip-incdir="$(python_get_includedir)"
+                       $(usex debug '--debug --trace' '')
+                       --verbose
+               )
+               echo "${myconf[@]}"
+               "${myconf[@]}" || die
+
+               # Run eqmake to respect toolchain, build flags, and prevent stripping
+               eqmake5 -recursive
+       }
+       python_foreach_impl run_in_build_dir configuration
+}
+
+src_compile() {
+       python_foreach_impl run_in_build_dir default
+}
+
+src_install() {
+       installation() {
+               # parallel install fails because mk_distinfo.py runs too early
+               emake -j1 INSTALL_ROOT="${D}" install
+               python_optimize
+       }
+       python_foreach_impl run_in_build_dir installation
+}