AUX ffmpeg-0.7.6-fix_ppc64_32ul.patch 1094 RMD160 b765f1f8420701e6d9447391dd498f6807b2e2e7 SHA1 f4fd276e9a88d815657282d67b716dc793f30988 SHA256 b6e60ba7f9d179b8b2ba03cf74694d1e92e6fc6d4626cda258ab1af50e0afea4
DIST ffmpeg-0.7.6.tar.bz2 4529035 RMD160 18641ae249d8b6f14f99013d1fccd85b0baddfa5 SHA1 0ea9ea769e195bf79d1b787acf253582481413b5 SHA256 f23265dc55fa8424872bc6cd026e340a367bc7eb4d5a6a32ca4aacb581b13cc2
DIST ffmpeg-0.7.7.tar.bz2 4531586 RMD160 1123b0e38811dfd4f4f1cb0f7678518f90849034 SHA1 30cc01d359d99bb6304b7fecbd5ff909843d93f4 SHA256 7231846b0d59d3fc3c0ed8370a35c823b59b84de3e92d2d8223b3bef3b92c8e1
+DIST ffmpeg-0.7.8.tar.bz2 4530406 RMD160 8f69a6bc5caaba4e3d440c2d5dc96a946454a52c SHA1 df4983c028a61d4bf3baceab3bae535b91b8928a SHA256 548197968e69b732c12b2cad3173eb6933a9573a7b1f5b29be36d31b9977c9f3
DIST ffmpeg-0.8.5.tar.bz2 4523772 RMD160 16659c26a5158aeee454ce555562ca059af6fa04 SHA1 a69d909958b23f8b2509ddda6cdeba2601edf5ff SHA256 f63df1ee08c2c64a4b3f106a88dd055b9f19e3457f1d7c23d8b8169e0a0ef115
DIST ffmpeg-0.8.6.tar.bz2 4527768 RMD160 9dace19db0f6337956403b3f13da3980361dd777 SHA1 ad7eaefa5072ca3c11778f9186fab35558a04478 SHA256 0ec9084438a26514455d49a72008d0b563d5a3c9d137cd22e46cb86bdc8bf6f0
EBUILD ffmpeg-0.7.6.ebuild 8428 RMD160 605d4178c97232660275ed3e7b516b734f26dd83 SHA1 ad4e689edb43fd0cb9afd1c056b16981219b5b03 SHA256 763a13877018d508fa73c76560d88894ccd260513b585294c4f077d4e3974faa
EBUILD ffmpeg-0.7.7.ebuild 8435 RMD160 838e2cfd74d3eed768a346d5cea73dfe195cc22f SHA1 1660c3caa7bff0fd070fdf864e5eb172d14fde4b SHA256 e68ae64c91924e456a16fb9dee00cecf6516a7fee0c814fa5788fd7473bab1fc
+EBUILD ffmpeg-0.7.8.ebuild 8443 RMD160 b6278d55d1ce6fe1d2b8d06bb5beacd2cc4b4797 SHA1 6181bc9405ed12ac3d514c4d91de5faa38842121 SHA256 da24c6d27450f8185a15570d4b753e60993697aeafdfce51b6ca2ce12a4d1790
EBUILD ffmpeg-0.8.5.ebuild 8043 RMD160 6d0818622d1b63f56ca61ee97c7e2b1bb797d229 SHA1 7590930cb73be2c4333005f88a6680a23e308da1 SHA256 74aaf70cf001c3a3be73dd7ae2e28ade46f568ed6c795b5a032fda93731a18b0
EBUILD ffmpeg-0.8.6.ebuild 8042 RMD160 4709694f4d6b3da1c20b6cd0e7f2783e8bcdd6f5 SHA1 170e0f605117aa622c6b42d1f60e252df9092b16 SHA256 ec9f7859106af231a8d8993dbd3ca2ec66b70eddc9761f7b8976f6007f558423
EBUILD ffmpeg-9999.ebuild 8746 RMD160 e8911f7df8b090b3c60566a77895da2090b22975 SHA1 a506f393a080edd996c140e1e5752b286a6363f5 SHA256 b8a1c288920ddf238efc353d171bae3337dcbcd59aa432ec5516c0f7c290385d
-MISC ChangeLog 70389 RMD160 3900325f9c1b72a3e7e9d811461407c3672d6a30 SHA1 cd61bd94e6de859300dfb831e726b2a6f9af14be SHA256 b3ab3fca23c3edd0d45d86ef9c576c5a284f7e74e7c764955b56f2d5d2da6e24
+MISC ChangeLog 70509 RMD160 be3ca53cae948e14ed79e1ce4b491ad16de9cca5 SHA1 cd4f8fa1054a9d12913872381c7ae83f8893bd14 SHA256 5d1e8d9b47307a57fe8c37007465e20e8486d155a2ba08017370ed85789ba0d0
MISC metadata.xml 3022 RMD160 794769b4ccc4c9348f64b884ec5bdc9e81173994 SHA1 5b0d926db53d9e1314ed0fe2821d7952b5386133 SHA256 7566645dd9bf7db7cf3a7be1cfa3fec5c33f156aa52619a09a4b46f6581086ef
-----BEGIN PGP SIGNATURE-----
-Version: GnuPG v2.0.17 (GNU/Linux)
+Version: GnuPG v2.0.18 (GNU/Linux)
-iEYEARECAAYFAk7H6cMACgkQuQc30/atMkAilQCgo0tQZ6RjNX1lCef/Ra4mdQwO
-k4UAn0ka47qc2fd2zqPvlifPMzi4hkP0
-=mvKA
+iEYEARECAAYFAk7NZZEACgkQvFcC4BYPU0pADwCgpmsmPwtqXqopgPZx8B8CVfVz
+hHoAn3hW5v6vavPs3uTA8e3bBO52n6d7
+=HpN4
-----END PGP SIGNATURE-----
--- /dev/null
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/ffmpeg/ffmpeg-0.7.8.ebuild,v 1.1 2011/11/23 21:28:43 aballier Exp $
+
+EAPI="2"
+
+SCM=""
+if [ "${PV#9999}" != "${PV}" ] ; then
+ SCM="git-2"
+ EGIT_REPO_URI="git://git.videolan.org/ffmpeg.git"
+fi
+
+inherit eutils flag-o-matic multilib toolchain-funcs ${SCM}
+
+DESCRIPTION="Complete solution to record, convert and stream audio and video. Includes libavcodec."
+HOMEPAGE="http://ffmpeg.org/"
+if [ "${PV#9999}" != "${PV}" ] ; then
+ SRC_URI=""
+elif [ "${PV%_p*}" != "${PV}" ] ; then # Snapshot
+ SRC_URI="mirror://gentoo/${P}.tar.bz2"
+else # Release
+ SRC_URI="http://ffmpeg.org/releases/${P/_/-}.tar.bz2"
+fi
+FFMPEG_REVISION="${PV#*_p}"
+
+LICENSE="GPL-2 amr? ( GPL-3 ) encode? ( aac? ( GPL-3 ) )"
+SLOT="0"
+if [ "${PV#9999}" = "${PV}" ] ; then
+ KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+fi
+IUSE="
+ +3dnow +3dnowext aac alsa altivec amr avx bindist +bzip2 celt cpudetection
+ custom-cflags debug dirac doc +encode faac frei0r gsm +hardcoded-tables
+ ieee1394 jack jpeg2k +mmx +mmxext mp3 network oss pic qt-faststart rtmp
+ schroedinger sdl speex +ssse3 static-libs test theora threads truetype
+ v4l vaapi vdpau vorbis vpx X x264 xvid +zlib
+ "
+
+VIDEO_CARDS="nvidia"
+
+for x in ${VIDEO_CARDS}; do
+ IUSE="${IUSE} video_cards_${x}"
+done
+
+RDEPEND="
+ alsa? ( media-libs/alsa-lib )
+ amr? ( media-libs/opencore-amr )
+ bzip2? ( app-arch/bzip2 )
+ celt? ( >=media-libs/celt-0.11.1 )
+ dirac? ( media-video/dirac )
+ encode? (
+ aac? ( media-libs/vo-aacenc )
+ amr? ( media-libs/vo-amrwbenc )
+ faac? ( media-libs/faac )
+ mp3? ( >=media-sound/lame-3.98.3 )
+ theora? ( >=media-libs/libtheora-1.1.1[encode] media-libs/libogg )
+ vorbis? ( media-libs/libvorbis media-libs/libogg )
+ x264? ( >=media-libs/x264-0.0.20110426 )
+ xvid? ( >=media-libs/xvid-1.1.0 )
+ )
+ frei0r? ( media-plugins/frei0r-plugins )
+ gsm? ( >=media-sound/gsm-1.0.12-r1 )
+ ieee1394? ( media-libs/libdc1394 sys-libs/libraw1394 )
+ jack? ( media-sound/jack-audio-connection-kit )
+ jpeg2k? ( >=media-libs/openjpeg-1.3-r2 )
+ rtmp? ( >=media-video/rtmpdump-2.2f )
+ sdl? ( >=media-libs/libsdl-1.2.13-r1[audio,video] )
+ schroedinger? ( media-libs/schroedinger )
+ speex? ( >=media-libs/speex-1.2_beta3 )
+ truetype? ( media-libs/freetype:2 )
+ vaapi? ( >=x11-libs/libva-0.32 )
+ video_cards_nvidia? ( vdpau? ( x11-libs/libvdpau ) )
+ vpx? ( >=media-libs/libvpx-0.9.6 )
+ X? ( x11-libs/libX11 x11-libs/libXext )
+ zlib? ( sys-libs/zlib )
+ !media-video/qt-faststart
+"
+
+DEPEND="${RDEPEND}
+ >=sys-devel/make-3.81
+ dirac? ( dev-util/pkgconfig )
+ doc? ( app-text/texi2html )
+ ieee1394? ( dev-util/pkgconfig )
+ mmx? ( dev-lang/yasm )
+ rtmp? ( dev-util/pkgconfig )
+ schroedinger? ( dev-util/pkgconfig )
+ test? ( net-misc/wget )
+ truetype? ( dev-util/pkgconfig )
+ v4l? ( sys-kernel/linux-headers )
+"
+
+S=${WORKDIR}/${P/_/-}
+
+src_prepare() {
+ if [ "${PV%_p*}" != "${PV}" ] ; then # Snapshot
+ export revision=git-N-${FFMPEG_REVISION}
+ fi
+ epatch "${FILESDIR}"/${PN}-0.7.6-fix_ppc64_32ul.patch #387207
+}
+
+src_configure() {
+ local myconf="${EXTRA_FFMPEG_CONF}"
+ # Set to --enable-version3 if (L)GPL-3 is required
+ local version3=""
+
+ # enabled by default
+ for i in debug doc network vaapi zlib; do
+ use ${i} || myconf="${myconf} --disable-${i}"
+ done
+ use bzip2 || myconf="${myconf} --disable-bzlib"
+ use sdl || myconf="${myconf} --disable-ffplay"
+
+ use custom-cflags && myconf="${myconf} --disable-optimizations"
+ use cpudetection && myconf="${myconf} --enable-runtime-cpudetect"
+
+ #for i in h264_vdpau mpeg1_vdpau mpeg_vdpau vc1_vdpau wmv3_vdpau; do
+ # use video_cards_nvidia || myconf="${myconf} --disable-decoder=${i}"
+ # use vdpau || myconf="${myconf} --disable-decoder=${i}"
+ #done
+ use video_cards_nvidia && use vdpau || myconf="${myconf} --disable-vdpau"
+
+ # Encoders
+ if use encode
+ then
+ use mp3 && myconf="${myconf} --enable-libmp3lame"
+ use aac && { myconf="${myconf} --enable-libvo-aacenc" ; version3=" --enable-version3" ; }
+ use amr && { myconf="${myconf} --enable-libvo-amrwbenc" ; version3=" --enable-version3" ; }
+ for i in theora vorbis x264 xvid; do
+ use ${i} && myconf="${myconf} --enable-lib${i}"
+ done
+ if use bindist
+ then
+ use faac && ewarn "faac is nonfree and cannot be distributed;
+ disabling faac support."
+ else
+ use faac && myconf="${myconf} --enable-libfaac --enable-nonfree"
+ fi
+ else
+ myconf="${myconf} --disable-encoders"
+ fi
+
+ # libavdevice options
+ use ieee1394 && myconf="${myconf} --enable-libdc1394"
+ # Indevs
+ # v4l1 gone since linux-headers-2.6.38
+ myconf="${myconf} --disable-indev=v4l"
+ use v4l || myconf="${myconf} --disable-indev=v4l2"
+ for i in alsa oss jack ; do
+ use ${i} || myconf="${myconf} --disable-indev=${i}"
+ done
+ use X && myconf="${myconf} --enable-x11grab"
+ # Outdevs
+ for i in alsa oss ; do
+ use ${i} || myconf="${myconf} --disable-outdev=${i}"
+ done
+ # libavfilter options
+ use frei0r && myconf="${myconf} --enable-frei0r"
+ use truetype && myconf="${myconf} --enable-libfreetype"
+
+ # Threads; we only support pthread for now but ffmpeg supports more
+ use threads && myconf="${myconf} --enable-pthreads"
+
+ # Decoders
+ use amr && { myconf="${myconf} --enable-libopencore-amrwb --enable-libopencore-amrnb" ; version3=" --enable-version3" ; }
+ for i in celt gsm dirac rtmp schroedinger speex vpx; do
+ use ${i} && myconf="${myconf} --enable-lib${i}"
+ done
+ use jpeg2k && myconf="${myconf} --enable-libopenjpeg"
+
+ # CPU features
+ for i in mmx ssse3 altivec avx ; do
+ use ${i} || myconf="${myconf} --disable-${i}"
+ done
+ use mmxext || myconf="${myconf} --disable-mmx2"
+ use 3dnow || myconf="${myconf} --disable-amd3dnow"
+ use 3dnowext || myconf="${myconf} --disable-amd3dnowext"
+ # disable mmx accelerated code if PIC is required
+ # as the provided asm decidedly is not PIC for x86.
+ if use pic && use x86 ; then
+ myconf="${myconf} --disable-mmx --disable-mmx2"
+ fi
+
+ # Option to force building pic
+ use pic && myconf="${myconf} --enable-pic"
+
+ # Try to get cpu type based on CFLAGS.
+ # Bug #172723
+ # We need to do this so that features of that CPU will be better used
+ # If they contain an unknown CPU it will not hurt since ffmpeg's configure
+ # will just ignore it.
+ for i in $(get-flag march) $(get-flag mcpu) $(get-flag mtune) ; do
+ [ "${i}" = "native" ] && i="host" # bug #273421
+ [[ ${i} = *-sse3 ]] && i="${i%-sse3}" # bug 283968
+ myconf="${myconf} --cpu=${i}"
+ break
+ done
+
+ # Mandatory configuration
+ myconf="
+ --enable-gpl
+ ${version3}
+ --enable-postproc
+ --enable-avfilter
+ --disable-stripping
+ ${myconf}"
+
+ # cross compile support
+ if tc-is-cross-compiler ; then
+ myconf="${myconf} --enable-cross-compile --arch=$(tc-arch-kernel) --cross-prefix=${CHOST}-"
+ case ${CHOST} in
+ *freebsd*)
+ myconf="${myconf} --target-os=freebsd"
+ ;;
+ mingw32*)
+ myconf="${myconf} --target-os=mingw32"
+ ;;
+ *linux*)
+ myconf="${myconf} --target-os=linux"
+ ;;
+ esac
+ fi
+
+ # Misc stuff
+ use hardcoded-tables && myconf="${myconf} --enable-hardcoded-tables"
+
+ # Specific workarounds for too-few-registers arch...
+ if [[ $(tc-arch) == "x86" ]]; then
+ filter-flags -fforce-addr -momit-leaf-frame-pointer
+ append-flags -fomit-frame-pointer
+ is-flag -O? || append-flags -O2
+ if (use debug); then
+ # no need to warn about debug if not using debug flag
+ ewarn ""
+ ewarn "Debug information will be almost useless as the frame pointer is omitted."
+ ewarn "This makes debugging harder, so crashes that has no fixed behavior are"
+ ewarn "difficult to fix. Please have that in mind."
+ ewarn ""
+ fi
+ fi
+
+ cd "${S}"
+ ./configure \
+ --prefix=/usr \
+ --libdir=/usr/$(get_libdir) \
+ --shlibdir=/usr/$(get_libdir) \
+ --mandir=/usr/share/man \
+ --enable-shared \
+ --cc="$(tc-getCC)" \
+ $(use_enable static-libs static) \
+ ${myconf} || die
+}
+
+src_compile() {
+ emake version.h || die #252269
+ emake || die
+
+ if use qt-faststart; then
+ tc-export CC
+ emake -C tools qt-faststart || die
+ fi
+}
+
+src_install() {
+ emake DESTDIR="${D}" install install-man || die
+
+ dodoc README INSTALL
+ dodoc doc/*
+
+ if use qt-faststart; then
+ dobin tools/qt-faststart || die
+ fi
+}
+
+src_test() {
+ if use encode ; then
+ LD_LIBRARY_PATH="${S}/libpostproc:${S}/libswscale:${S}/libavcodec:${S}/libavdevice:${S}/libavfilter:${S}/libavformat:${S}/libavutil" \
+ emake test || die "Some tests failed"
+ else
+ ewarn "Tests fail without USE=encode, skipping"
+ fi
+}
projects / gentoo.git / commitdiff