app-emulation/containers-storage: Bump to version 1.15.1

Package-Manager: Portage-2.3.80, Repoman-2.3.19
Signed-off-by: Zac Medico <zmedico@gentoo.org>

diff --git a/app-emulation/containers-storage/Manifest b/app-emulation/containers-storage/Manifest
index a63ff9869c125b04e048314f83a1f4d82892d21e..3d89411a36f9746b43d5e028a1438578ec1fd306 100644 (file)
--- a/app-emulation/containers-storage/Manifest
+++ b/app-emulation/containers-storage/Manifest
@@ -1 +1,2 @@
 DIST containers-storage-1.15.0.tar.gz 5971848 BLAKE2B 79e39d0587319df2e73d1f2b0d34dd5d72b32151edd94a87af9e0ce109ee4a276bba80db8c04e496618c16ff427b6396414cfa1b99b2eaeacc66fbceb7456965 SHA512 5d758a863b0c845d912ee97afb4e8304e3899071d489c41b3116c8acaf2aa55648e6c0a14d0edb0d2694a8eb74b61ea05373b6bb5d3d577aeda9b8693092fced
+DIST containers-storage-1.15.1.tar.gz 6037975 BLAKE2B e6d0d9adae829fd3d8cb40aa124b7149ee56ed13650b0dc57ba316ab2f03e754bdbb3e566c199b7768c612b159fa3051db39cd90127f4676255e452863aa7e24 SHA512 ea017e7dec840e5794f0ae61ebfc0cbf55b8de2c237286371eef3fd1808809e2bb149f08ba62126c741e0811839bf0af8f97bbda32e715132e42905f2ebd3a6c

diff --git a/app-emulation/containers-storage/containers-storage-1.15.1.ebuild b/app-emulation/containers-storage/containers-storage-1.15.1.ebuild
new file mode 100644 (file)
index 0000000..d094e8e
--- /dev/null
+++ b/app-emulation/containers-storage/containers-storage-1.15.1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit go-module
+
+KEYWORDS="~amd64"
+DESCRIPTION="containers/storage library"
+HOMEPAGE="https://github.com/containers/storage"
+LICENSE="Apache-2.0 BSD BSD-2 CC-BY-SA-4.0 ISC MIT"
+SLOT="0"
+IUSE="btrfs +device-mapper test"
+EGO_PN="${HOMEPAGE#*//}"
+EGIT_COMMIT="v${PV}"
+SRC_URI="https://${EGO_PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+RDEPEND="
+       btrfs? ( sys-fs/btrfs-progs )
+       device-mapper? ( sys-fs/lvm2:= )"
+DEPEND="${RDEPEND}
+       dev-go/go-md2man
+       test? (
+               sys-fs/btrfs-progs
+               sys-fs/lvm2
+               sys-apps/util-linux
+       )"
+RESTRICT="test"
+
+S=${WORKDIR}/${P#containers-}
+
+src_prepare() {
+       default
+
+       sed -e 's:GO111MODULE=off:GO111MODULE=on:' -i Makefile || die
+
+       [[ -f hack/btrfs_tag.sh ]] || die
+       use btrfs || { echo -e "#!/bin/sh\necho exclude_graphdriver_btrfs" > \
+               "hack/btrfs_tag.sh" || die; }
+
+       [[ -f hack/libdm_tag.sh ]] || die
+       use device-mapper || { echo -e "#!/bin/sh\necho btrfs_noversion exclude_graphdriver_devicemapper" > \
+               "hack/libdm_tag.sh" || die; }
+}
+
+src_compile() {
+       export -n GOCACHE XDG_CACHE_HOME #678856
+       emake containers-storage docs
+}
+
+src_install() {
+       dobin "${PN}"
+       while read -r -d ''; do
+               mv "${REPLY}" "${REPLY%.1}" || die
+       done < <(find "${S}/docs" -name '*.[[:digit:]].1' -print0)
+       find "${S}/docs" -name '*.[[:digit:]]' -exec doman '{}' + || die
+}
+
+src_test() {
+       GOPATH="${S}" unshare -m emake local-test-unit || die
+}