app-misc/btail: use HTTPS, EAPI=7 bump

Closes: https://bugs.gentoo.org/686232
Closes: https://github.com/gentoo/gentoo/pull/12043
Signed-off-by: Michael Mair-Keimberger <m.mairkeimberger@gmail.com>
Signed-off-by: Michael Palimaka <kensington@gentoo.org>

diff --git a/app-misc/btail/btail-0.3-r1.ebuild b/app-misc/btail/btail-0.3-r1.ebuild
new file mode 100644 (file)
index 0000000..b434b22
--- /dev/null
+++ b/app-misc/btail/btail-0.3-r1.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DESCRIPTION="Bayesian logfile filter"
+HOMEPAGE="https://www.vanheusden.com/btail/"
+SRC_URI="${HOMEPAGE}/${P}.tgz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+
+DEPEND="sys-libs/gdbm"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+       default
+       sed -i Makefile \
+               -e '/^LDFLAGS/s:=:+=:g' \
+               -e '/$(CC)/s:-Wall:$(CFLAGS) &:g' \
+               || die
+       sed -i conf.cpp \
+               -e '/Configline/s:):, line):g' \
+               || die
+}
+
+src_compile() {
+       emake \
+               CFLAGS="${CFLAGS}" \
+               CXXFLAGS="${CXXFLAGS}" \
+               CC="$(tc-getCC)" \
+               CXX="$(tc-getCXX)"
+}
+
+src_install() {
+       dobin blearn btail
+       dodoc readme.txt btail.conf license.txt
+}