dev-python/atomicwrites: add PyPy{,3}, doc

Package-Manager: Portage-2.3.41, Repoman-2.3.9
Closes: https://github.com/gentoo/gentoo/pull/9189

diff --git a/dev-python/atomicwrites/atomicwrites-1.1.5-r3.ebuild b/dev-python/atomicwrites/atomicwrites-1.1.5-r3.ebuild
new file mode 100644 (file)
index 0000000..75fd01f
--- /dev/null
+++ b/dev-python/atomicwrites/atomicwrites-1.1.5-r3.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( pypy{,3} python{2_7,3_{4,5,6}} )
+
+inherit distutils-r1
+
+DESCRIPTION="Atomic file writes"
+HOMEPAGE="https://github.com/untitaker/python-atomicwrites"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="doc test"
+
+DEPEND="
+       dev-python/setuptools[${PYTHON_USEDEP}]
+       doc? (
+               dev-python/sphinx[${PYTHON_USEDEP}]
+               dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
+       )
+       test? ( dev-python/pytest[${PYTHON_USEDEP}] )
+"
+
+python_prepare_all() {
+       sed -i "/'sphinx.ext.intersphinx'/d" docs/conf.py || die
+       distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+       if use doc; then
+               sphinx-build docs docs/_build/html || die
+               HTML_DOCS=( docs/_build/html/. )
+       fi
+}
+
+python_test() {
+       py.test -v || die "Tests fail with ${EPYTHON}"
+}