sci-libs/libsigrok: Version bump, bug #579878

Package-Manager: portage-2.2.28
Signed-off-by: Sven Wegener <swegener@gentoo.org>

diff --git a/sci-libs/libsigrok/Manifest b/sci-libs/libsigrok/Manifest
index 0289374531a8993c326e2283dc195f75363115c9..7944562eb00869a4c02a7be5c288f7738448aec1 100644 (file)
--- a/sci-libs/libsigrok/Manifest
+++ b/sci-libs/libsigrok/Manifest
@@ -1 +1,2 @@
 DIST libsigrok-0.3.0.tar.gz 924503 SHA256 43926907a06f1d7aa73c68ae379d66412ac2728483eed7d20a8cf061f73f7050 SHA512 b94e8a8da1346f9ab267fd693975411243f2cb016e48ec05f4ad88a8a1dfe5ed6f5ad4ac4bf0e94dc551dc92cd70d2719983e21abaa4811693fb28a27bf74550 WHIRLPOOL 709b1e7fd0b3f864129ade9d91cc072cf72675bc10ec053e71cd0e7ce18442d405dc8ab5d435ac59694360a2be4f5a9a2ceb559dd3e6c7a7736dafa7a04ccae7
+DIST libsigrok-0.4.0.tar.gz 1387329 SHA256 5f291f3fee36e6dab1336f1c78596e50588831bc5ebd7cddc2a95fe8c71d669e SHA512 5963c1a44cf351a38d9434f89a15b20d36c7196a78464c302c65ab262bcdb2f26274c7fabf01174757e1f9a367497b9721578ebf802f75ef97ee71ff3dade1e0 WHIRLPOOL 0364ff1e75212025e06080eacc8e088ee791deb605c1a8c63a25c8bbd45b2812aad1e456969f2c179e62e554f4c33a935e97cf8afe378e2f75715084d82694d4

diff --git a/sci-libs/libsigrok/libsigrok-0.4.0.ebuild b/sci-libs/libsigrok/libsigrok-0.4.0.ebuild
new file mode 100644 (file)
index 0000000..02ab795
--- /dev/null
+++ b/sci-libs/libsigrok/libsigrok-0.4.0.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="6"
+
+PYTHON_COMPAT=( python{2_7,3_{3,4,5}} )
+
+inherit eutils python-single-r1 java-pkg-opt-2
+
+if [[ ${PV} == "9999" ]]; then
+       EGIT_REPO_URI="git://sigrok.org/${PN}"
+       inherit git-r3 autotools
+else
+       SRC_URI="http://sigrok.org/download/source/${PN}/${P}.tar.gz"
+       KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="provide basic hardware drivers for logic analyzers and input/output file format support"
+HOMEPAGE="http://sigrok.org/wiki/Libsigrok"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="cxx ftdi java parport python serial static-libs test usb"
+REQUIRED_USE="java? ( cxx ) python? ( cxx ${PYTHON_REQUIRED_USE} )"
+
+# We also support librevisa, but that isn't in the tree ...
+LIB_DEPEND=">=dev-libs/glib-2.32.0[static-libs(+)]
+       >=dev-libs/libzip-0.8[static-libs(+)]
+       cxx? ( dev-cpp/glibmm:2[static-libs(+)] )
+       python? ( ${PYTHON_DEPS} >=dev-python/pygobject-3.0.0[${PYTHON_USEDEP}] )
+       ftdi? ( >=dev-embedded/libftdi-0.16:=[static-libs(+)] )
+       parport? ( sys-libs/libieee1284[static-libs(+)] )
+       serial? ( >=dev-libs/libserialport-0.1.1[static-libs(+)] )
+       usb? ( virtual/libusb:1[static-libs(+)] )"
+RDEPEND="!static-libs? ( ${LIB_DEPEND//\[static-libs(+)]} )
+       static-libs? ( ${LIB_DEPEND} )
+       java? ( >=virtual/jre-1.4 )"
+DEPEND="${LIB_DEPEND//\[static-libs(+)]}
+       test? ( >=dev-libs/check-0.9.4 )
+       cxx? ( app-doc/doxygen )
+       java? (
+               >=dev-lang/swig-3.0.6
+               >=virtual/jdk-1.4
+       )
+       python? (
+               >=dev-lang/swig-3.0.6
+       )
+       virtual/pkgconfig"
+
+pkg_setup() {
+       use python && python-single-r1_pkg_setup
+       java-pkg-opt-2_pkg_setup
+}
+
+src_prepare() {
+       [[ ${PV} == "9999" ]] && eautoreconf
+       eapply_user
+}
+
+src_configure() {
+       econf \
+               $(use_with ftdi libftdi) \
+               $(use_with parport libieee1284) \
+               $(use_with serial libserialport) \
+               $(use_with usb libusb) \
+               $(use_enable cxx) \
+               $(use_enable java) \
+               $(use_enable python) \
+               --disable-ruby \
+               $(use_enable static-libs static)
+}
+
+src_test() {
+       emake check
+}
+
+src_install() {
+       default
+       prune_libtool_files
+}