dev-python/google-reauth-python: new package

Package-Manager: Portage-2.3.40, Repoman-2.3.9

diff --git a/dev-python/google-reauth-python/Manifest b/dev-python/google-reauth-python/Manifest
new file mode 100644 (file)
index 0000000..02bf095
--- /dev/null
+++ b/dev-python/google-reauth-python/Manifest
@@ -0,0 +1 @@
+DIST google-reauth-python-0.1.0.tar.gz 17720 BLAKE2B c78a43f1062988ada715c9e1bb64c2252a3debd5b9b366df9780200717a006c5e4957bf37d81e645989c6fc74c5e5b4354c88244309bb1a22a936ef74f6172c8 SHA512 b92b822b5c59d74f7ac747e66f35eaa906a0e18ccbb791e0904551c6ecd9b904ac7602ea38333a16396ffa49638a1b4991827429c7f52311b9506f55400bf117

diff --git a/dev-python/google-reauth-python/google-reauth-python-0.1.0.ebuild b/dev-python/google-reauth-python/google-reauth-python-0.1.0.ebuild
new file mode 100644 (file)
index 0000000..5bdf90c
--- /dev/null
+++ b/dev-python/google-reauth-python/google-reauth-python-0.1.0.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python based U2F host library"
+HOMEPAGE="https://github.com/google/google-reauth-python"
+SRC_URI="https://github.com/google/google-reauth-python/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="test"
+
+RDEPEND="
+       dev-python/oauth2client[${PYTHON_USEDEP}]
+       dev-python/pyu2f[${PYTHON_USEDEP}]
+       dev-python/six[${PYTHON_USEDEP}]
+"
+DEPEND="
+       ${RDEPEND}
+       dev-python/setuptools[${PYTHON_USEDEP}]
+       test? (
+               dev-python/pytest[${PYTHON_USEDEP}]
+               dev-python/mock[${PYTHON_USEDEP}]
+       )
+"
+
+DOCS=( CHANGELOG.rst CONTRIBUTING.rst README.rst )
+
+python_prepare_all() {
+       sed -e "s:'some_origin'.encode('ascii'):'some_origin':" \
+               -e "s:SignResponse('key_handle', 'resp',:SignResponse('key_handle'.encode(), 'resp'.encode(),:" \
+               -i tests/test_reauth.py || die
+
+       distutils-r1_python_prepare_all
+}
+
+python_test() {
+       py.test -v tests || die "Tests failed under ${EPYTHON}"
+}

diff --git a/dev-python/google-reauth-python/metadata.xml b/dev-python/google-reauth-python/metadata.xml
new file mode 100644 (file)
index 0000000..babc9a1
--- /dev/null
+++ b/dev-python/google-reauth-python/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+       <maintainer type="person">
+               <email>zmedico@gentoo.org</email>
+               <name>Zac Medico</name>
+       </maintainer>
+       <upstream>
+               <remote-id type="pypi">google-reauth</remote-id>
+               <remote-id type="github">google/google-reauth-python</remote-id>
+       </upstream>
+</pkgmetadata>