dev-python/gwcs: initial import

Package-Manager: portage-2.3.3

diff --git a/dev-python/gwcs/Manifest b/dev-python/gwcs/Manifest
new file mode 100644 (file)
index 0000000..c70d553
--- /dev/null
+++ b/dev-python/gwcs/Manifest
@@ -0,0 +1 @@
+DIST gwcs-0.7_rc2.tar.gz 87079 SHA256 13cab5214b61e6b9e5f0212f7e076b8247929f8f54779ecd92738a67102f154e SHA512 8df99ec22a8ffbf9f7e4ca000f69aa89301fd62c16a8b4f004f84cccf333abb71c856e854cd08e61a811ad769e99ef61e1f0e6c0a61f7c1895ac6159aa99c897 WHIRLPOOL c12ed58a74a7a626ae7aa276b1ede36bd1e0fe89281ab388d97f294667df6e538e1c089e55ea311f6aadbd1bc1804abc767e14c9426de625ee40217dda90bbef

diff --git a/dev-python/gwcs/gwcs-0.7_rc2.ebuild b/dev-python/gwcs/gwcs-0.7_rc2.ebuild
new file mode 100644 (file)
index 0000000..ac871b8
--- /dev/null
+++ b/dev-python/gwcs/gwcs-0.7_rc2.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python  for managing the World Coordinate System"
+HOMEPAGE="http://gwcs.readthedocs.org"
+
+# take 0.7_rc2 instead 0f 0.5.1, incompatible with asdf-1.2.1
+#SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+SRC_URI="https://github.com/spacetelescope/${PN}/archive/${PV/_}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="doc test"
+
+RDEPEND="
+       dev-python/astropy[${PYTHON_USEDEP}]
+       dev-python/asdf[${PYTHON_USEDEP}]
+       $(python_gen_cond_dep 'dev-python/configparser[${PYTHON_USEDEP}]' python2_7 )"
+DEPEND="${RDEPEND}
+       dev-python/astropy-helpers[${PYTHON_USEDEP}]
+       dev-python/cython[${PYTHON_USEDEP}]
+       dev-python/setuptools[${PYTHON_USEDEP}]
+       doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+       test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
+
+S="${WORKDIR}/${PN}-${PV/_}"
+python_prepare_all() {
+       # use system astropy-helpers instead of bundled one
+       sed -i -e '/auto_use/s/True/False/' setup.cfg || die
+       distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+       if use doc; then
+               python_setup
+               PYTHONPATH="${BUILD_DIR}"/lib \
+                                 esetup.py build_sphinx --no-intersphinx
+       fi
+}
+
+python_test() {
+       esetup.py test
+}
+
+python_install_all() {
+       use doc && local HTML_DOCS=( docs/_build/html/. )
+       distutils-r1_python_install_all
+}

diff --git a/dev-python/gwcs/metadata.xml b/dev-python/gwcs/metadata.xml
new file mode 100644 (file)
index 0000000..033a8d0
--- /dev/null
+++ b/dev-python/gwcs/metadata.xml
@@ -0,0 +1,20 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>sci-astronomy@gentoo.org</email>
+    <name>Gentoo Astronomy Project</name>
+  </maintainer>
+  <longdescription lang="en">
+    GWCS takes a general approach to the astronomy World Coodinate
+    System. It supports a data model which includes the entire
+    transformation pipeline from input coordinates (detector by
+    default) to world coordinates. The goal is to provide a flexible
+    toolkit which is easily extendible by adding new transforms and
+    frames.
+  </longdescription>
+  <upstream>
+    <remote-id type="pypi">gwcs</remote-id>
+    <remote-id type="github">spacetelescope/gwcs</remote-id>    
+  </upstream>
+</pkgmetadata>