dev-python/backports-functools-lru-cache: Fix namespace support

diff --git a/dev-python/backports-functools-lru-cache/backports-functools-lru-cache-1.3-r1.ebuild b/dev-python/backports-functools-lru-cache/backports-functools-lru-cache-1.3-r1.ebuild
new file mode 100644 (file)
index 0000000..b94cdf9
--- /dev/null
+++ b/dev-python/backports-functools-lru-cache/backports-functools-lru-cache-1.3-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1
+
+MY_PN="${PN/-/.}"
+MY_PN="${MY_PN//-/_}"
+DESCRIPTION="Backport of functools.lru_cache from Python 3.3"
+HOMEPAGE="https://github.com/jaraco/backports.functools_lru_cache"
+SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~x86"
+IUSE="doc test"
+
+RDEPEND="dev-python/backports[${PYTHON_USEDEP}]"
+DEPEND="
+       dev-python/setuptools[${PYTHON_USEDEP}]
+       >=dev-python/setuptools_scm-1.9[${PYTHON_USEDEP}]
+       doc? (
+               dev-python/sphinx[${PYTHON_USEDEP}]
+               dev-python/rst-linker[${PYTHON_USEDEP}]
+       )
+       test? (
+               >=dev-python/pytest-2.8[${PYTHON_USEDEP}]
+               dev-python/pytest-runner[${PYTHON_USEDEP}]
+       )
+"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+python_compile_all() {
+       use doc && esetup.py build_sphinx
+}
+
+python_test() {
+       PYTHONPATH=. py.test || die "tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+       use doc && local HTML_DOCS=( "${BUILD_DIR}"/sphinx/html/. )
+       distutils-r1_python_install_all
+
+       find "${D}" -name '*.pth' -delete || die
+}