app-backup/backintime: Add 1.2.0_pre20180221 Qt5-based snapshot

Drop unused eclass and fix description - it is not clear why this
should be targeted at specific desktop environments.

Bug: https://bugs.gentoo.org/641962
Package-Manager: Portage-2.3.28, Repoman-2.3.9

diff --git a/app-backup/backintime/Manifest b/app-backup/backintime/Manifest
index c4b266b68b831313768abd5330d9d2cbaf3c2f94..40a96401478643444cd66170c5880ce4692eddd5 100644 (file)
--- a/app-backup/backintime/Manifest
+++ b/app-backup/backintime/Manifest
@@ -1 +1,2 @@
 DIST backintime-1.1.24.tar.gz 658961 BLAKE2B 88255ea138f31c4540f54d2053616d4c8ce35f7c969b15a9c46422bfed4f0fd2cabb01e0cd4d1505fb84eee31daacb9da36c6bf71225f5b9a1d47d6941e571b2 SHA512 d16b6d3a710154ca8bddf80a8f06835efe84dd2f2435102e06a732f7e6e291b1954864298542658bab2b7bc42d5a6bf1d9338a98c66fd3f888c450b9685cc011
+DIST backintime-1.2.0_pre20180221.tar.gz 712330 BLAKE2B 9ba40c5f89b9fbdf0b1c381bf2e3edce13553b2c301792627fc037bd2de181804b2dc6cad6e78a02844f8835dcd6415a35590125e832d55187fa2ed1a5fa864b SHA512 ad1bb11ea411904027952809c577de1a5317f40430af9b91b16a2c157d560c72b65c879bb880b557e9b5e333e76a44977a26486f4ed4f45281a5e8b0d4583c2a

diff --git a/app-backup/backintime/backintime-1.2.0_pre20180221.ebuild b/app-backup/backintime/backintime-1.2.0_pre20180221.ebuild
new file mode 100644 (file)
index 0000000..fbc9194
--- /dev/null
+++ b/app-backup/backintime/backintime-1.2.0_pre20180221.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_{4,5,6} )
+
+COMMIT=45ec81c185789b2dbafd7348d1af039b5183c9ff
+inherit python-single-r1 gnome2-utils vcs-snapshot
+
+DESCRIPTION="Backup system inspired by TimeVault and FlyBack"
+HOMEPAGE="https://backintime.readthedocs.io/ https://github.com/bit-team/backintime/"
+SRC_URI="https://github.com/bit-team/${PN}/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="qt5"
+
+DEPEND="${PYTHON_DEPS}
+       dev-python/dbus-python[${PYTHON_USEDEP}]
+       dev-python/keyring[${PYTHON_USEDEP}]
+       net-misc/openssh
+       net-misc/rsync[xattr,acl]"
+RDEPEND="${DEPEND}
+       qt5? ( dev-python/PyQt5 )"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+src_prepare() {
+       #fix doc install location
+       sed -e "s:/doc/${PN}-common:/doc/${PF}:g" \
+               -i common/configure || die
+       sed -e "s:/doc/${PN}-qt:/doc/${PF}:g" \
+               -i qt/configure || die
+       sed -e "/addInstallFile \"..\/VERSION/d" \
+               -e "/addInstallFile \"..\/LICENSE/d" \
+               -e "/addInstallFile \"..\/debian\/copyright/d" \
+               -i {qt,common}/configure || die
+
+       if [ -n ${LINGUAS+x} ] ; then
+               cd common/po || die
+               for po in *.po ; do
+                       if ! has ${po/.po} ${LINGUAS} ; then
+                               rm ${po} || die
+                       fi
+               done
+       fi
+
+       default
+}
+
+src_configure() {
+       cd "${S}"/common || die
+       ./configure --python3 --no-fuse-group || die
+       if use qt5 ; then
+               cd "${S}"/qt || die
+               ./configure --python3 || die
+       fi
+}
+
+src_compile() {
+       cd "${S}"/common || die
+       emake
+       if use qt5 ; then
+               cd "${S}"/qt || die
+               emake
+       fi
+}
+
+src_install() {
+       cd "${S}"/common || die
+       emake DESTDIR="${D}" install
+       if use qt5 ; then
+               cd "${S}"/qt || die
+               emake DESTDIR="${D}" install
+       fi
+
+       python_optimize "${D}"
+}
+
+pkg_postinst() {
+       gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+       gnome2_icon_cache_update
+}

diff --git a/app-backup/backintime/backintime-9999.ebuild b/app-backup/backintime/backintime-9999.ebuild
index 1bff0ab51bab78e7a03860f2a95e9c618de4b610..9fcb400d83e9e794c54c5734ab4e0154e880618f 100644 (file)
--- a/app-backup/backintime/backintime-9999.ebuild
+++ b/app-backup/backintime/backintime-9999.ebuild
@@ -1,13 +1,13 @@
-# Copyright 1999-2017 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=6
 
 PYTHON_COMPAT=( python3_{4,5,6} )
 
-inherit eutils python-single-r1 gnome2-utils git-r3
+inherit python-single-r1 gnome2-utils git-r3
 
-DESCRIPTION="Backup system inspired by TimeVault and FlyBack, with a GUI for GNOME and KDE4"
+DESCRIPTION="Backup system inspired by TimeVault and FlyBack"
 HOMEPAGE="https://backintime.readthedocs.io/ https://github.com/bit-team/backintime/"
 EGIT_REPO_URI="https://github.com/bit-team/backintime/"