net-im/licq: Fixced RDEPEND (bug #608008). EAPI-6 bump.

Ebuild overhaul and cleanup.

Package-Manager: Portage-2.3.3, Repoman-2.3.1

diff --git a/net-im/licq/licq-1.8.2.ebuild b/net-im/licq/licq-1.8.2.ebuild
index 88a4311bb230f55894be6d8875e8c1fe83b8b38e..b1aeafd0e55bba238008ee9292d7c67587add224 100644 (file)
--- a/net-im/licq/licq-1.8.2.ebuild
+++ b/net-im/licq/licq-1.8.2.ebuild
@@ -1,8 +1,8 @@
-# Copyright 1999-2016 Gentoo Foundation
+# Copyright 1999-2017 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 # $Id$
 
-EAPI=5
+EAPI=6
 
 inherit cmake-utils eutils flag-o-matic
 
@@ -13,34 +13,49 @@ SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
 LICENSE="GPL-2"
 SLOT="2"
 KEYWORDS="alpha amd64 ia64 ppc sparc x86"
-IUSE="debug doc linguas_he nls socks5 ssl xosd aosd xmpp qt4 msn"
+IUSE="debug doc l10n_he nls socks5 ssl xosd aosd xmpp qt4 msn"
 
-RDEPEND=">=app-crypt/gpgme-1
+RDEPEND="
+       >=app-crypt/gpgme-1
+       app-text/hunspell
        dev-libs/boost:=
+       x11-libs/libXScrnSaver
        xmpp? ( net-libs/gloox )
        qt4? ( dev-qt/qtgui:4 )
        socks5? ( net-proxy/dante )
        ssl? ( >=dev-libs/openssl-0.9.5a:0= )
        xosd? ( x11-libs/xosd )
-       aosd? ( x11-libs/libaosd )"
-DEPEND="${RDEPEND}
+       aosd? ( x11-libs/libaosd )
+"
+DEPEND="
+       ${RDEPEND}
        doc? ( app-doc/doxygen[dot] )
-       nls? ( sys-devel/gettext )"
+       nls? ( sys-devel/gettext )
+"
 
 src_prepare() {
-       local licq_plugins="auto-reply icq rms"
-       use msn && licq_plugins+=" msn"
-       use xosd && licq_plugins+=" osd"
-       use aosd && licq_plugins+=" aosd"
-       use xmpp && licq_plugins+=" jabber"
-       use qt4 && licq_plugins+=" qt4-gui"
-
-       local plugins="" x
-       for x in ${licq_plugins}; do
-               plugins+=" ${x}\/CMakeLists.txt"
+       default
+
+       local licq_plugins=(
+               auto-reply
+               icq
+               rms
+               $(usex aosd aosd '')
+               $(usex msn msn '')
+               $(usex qt4 qt4-gui '')
+               $(usex xmpp jabber '')
+               $(usex xosd osd '')
+       )
+
+       local plugins=() x
+       for x in ${licq_plugins[@]} ; do
+               plugins+=( ${x}/CMakeLists.txt )
        done
 
-       sed -i -e "s/file(GLOB cmake_plugins.*$/set(cmake_plugins ${plugins})/" plugins/CMakeLists.txt
+       # somehow sed doesn't like an array variable
+       x="${plugins[@]}"
+       sed -e "s|file(GLOB cmake_plugins.*$|set(cmake_plugins ${x})|" \
+               -i plugins/CMakeLists.txt || die
 }
 
 pkg_setup() {
@@ -49,23 +64,24 @@ pkg_setup() {
 }
 
 src_configure() {
-       local myopts="-DCMAKE_BUILD_TYPE=$(use debug && echo 'Debug' || echo 'Release')"
-       mycmakeargs="$myopts
-               $(cmake-utils_use doc USE_DOXYGEN)
-               $(cmake-utils_use linguas_he USE_HEBREW)
-               $(cmake-utils_use nls ENABLE_NLS)
-               $(cmake-utils_use socks5 USE_SOCKS5)
-               $(cmake-utils_use ssl USE_OPENSSL)
-               -DUSE_FIFO=ON
+       mycmakeargs=(
                -DBUILD_PLUGINS=ON
-               -DBUILD_TESTS=OFF"
+               -DBUILD_TESTS=OFF
+               -DCMAKE_BUILD_TYPE="$(usex debug 'Debug' 'Release')"
+               -DENABLE_NLS="$(usex nls)"
+               -DUSE_DOXYGEN="$(usex doc)"
+               -DUSE_FIFO=ON
+               -DUSE_HEBREW="$(usex l10n_he)"
+               -DUSE_OPENSSL="$(usex ssl)"
+               -DUSE_SOCKS5="$(usex socks5)"
+       )
 
        cmake-utils_src_configure
 }
 
 src_install() {
+       local DOCS=( README )
        cmake-utils_src_install
-       dodoc README
 
        docinto doc
        dodoc doc/*