dev-python/pythonmagick: version bump to 0.9.14

diff --git a/dev-python/pythonmagick/Manifest b/dev-python/pythonmagick/Manifest
index a34831e5daab8a941eb3f969985721eb9848187e..734286ae74f6e616b9700be90897c2bf1b879ee2 100644 (file)
--- a/dev-python/pythonmagick/Manifest
+++ b/dev-python/pythonmagick/Manifest
@@ -1 +1,2 @@
 DIST PythonMagick-0.9.12.tar.xz 256872 SHA256 4b108324460aa497627a0fc2547f946253558cec3457a35f9f0e107adac833d0 SHA512 accdc3e89528d397eb608ab00fe015fe5069130c228631a024c3b4c6ecb38239d6329f66fa1d56b3ac48ff20caed5243c5dd5cfd920b0ea3867dc64bb38e5859 WHIRLPOOL a8051f2661f54eeb031073eda5feab6612e64932f3ba0936e46917d9834f582c5b9dc50b6d52afaa33d81cbe4e3555b9eb350ffe9caf01097d3f69127fc802ef
+DIST PythonMagick-0.9.14.tar.xz 270488 SHA256 42fc1fc0def8a9fa0af282c1ba330831d7ba310b5d7dc7b0f03c0536a26b93ba SHA512 a09696d8ebe3c8d38a9148e6f812c149d34fbe1dbe64ecf07b43e153b3c7fd97738491818dec348072ff96e54ac0eddd17eff75c5cef8df21a8a89f58e918e98 WHIRLPOOL dcdd3b78c9b425cefbc8f05b0e3af9be9fa217c5175788ce75d44c985a86fb7c73d85d0e6b41e344685d78db2b66a9ea820b1f30a7fd8e30290e08b22fd20d71

diff --git a/dev-python/pythonmagick/pythonmagick-0.9.14.ebuild b/dev-python/pythonmagick/pythonmagick-0.9.14.ebuild
new file mode 100644 (file)
index 0000000..48e81a3
--- /dev/null
+++ b/dev-python/pythonmagick/pythonmagick-0.9.14.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+WANT_AUTOMAKE="1.12"
+
+inherit autotools eutils python-r1
+
+MY_PN="PythonMagick"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Python bindings for ImageMagick"
+HOMEPAGE="http://www.imagemagick.org/script/api.php"
+SRC_URI="mirror://imagemagick/python/${MY_P}.tar.xz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE=""
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+       >=dev-libs/boost-1.48[python,${PYTHON_USEDEP}]
+       >=media-gfx/imagemagick-6.9.1
+"
+DEPEND="${RDEPEND}
+       virtual/pkgconfig
+"
+
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=(
+       "${FILESDIR}"/${PN}-0.9.10-Makefile.am.patch
+       "${FILESDIR}"/${PN}-0.9.10-ax_boost_python.patch
+)
+
+src_prepare() {
+       default
+       eautoreconf
+       python_copy_sources
+}
+
+src_configure() {
+       python_configure() {
+               if ! python_is_python3; then
+                       local -x CXXFLAGS="${CXXFLAGS} -fno-strict-aliasing"
+               fi
+               econf \
+                       --disable-static \
+                       --with-boost-python=boost_python-${EPYTHON#python}
+       }
+
+       python_foreach_impl run_in_build_dir python_configure
+}
+
+src_compile() {
+       python_foreach_impl run_in_build_dir default
+}
+
+src_install() {
+       python_foreach_impl run_in_build_dir default
+       prune_libtool_files --modules
+}