media-libs/grilo: Version bump

Package-Manager: portage-2.2.26

diff --git a/media-libs/grilo/Manifest b/media-libs/grilo/Manifest
index 78dbabe00287f6ffdd62323ddde861ec80106c2b..4680ccd21b711f8c0c034b7d4c5e9b560142afb2 100644 (file)
--- a/media-libs/grilo/Manifest
+++ b/media-libs/grilo/Manifest
@@ -1,2 +1,3 @@
 DIST grilo-0.2.12.tar.xz 617284 SHA256 55b4663550bc8185f8db232e96b9ba99fbfa9175e31e7321fa5ccaacf3617b85 SHA512 a8102dc66e30676a3fcf2be1c96b4c461b78095c03d7566216bb6c04f875b3be6a305d81464058a11f92dee00e68b2abdcb8d5c5f2a0d95732ac7dbb473820f4 WHIRLPOOL fece087c8003138e9b6a977cb3c9d60dd41364dd6b7cb2efe98efab863e38ea360daf44b90ec7a970810a8b4a980221ef73e8a4606dca8e26e52f36980ba9ffc
 DIST grilo-0.2.14.tar.xz 622860 SHA256 79c82ea1747ae7430a648aa9660e44d88d48c968bcdaeb3b2c5cb97e1c921ccd SHA512 0c06396b6c0c97bb7602f372077126432a0bc8284c85f3e684d1d050ab7ace6f59764c79870ce26462f8e1facfbbfca5f950fa3e35999483548510c10a42e440 WHIRLPOOL 1aed02f103beaf7f0425969806ee0fb7c802e584ab8c46a335a3af9e7efe75126b1ca8c5841ac11ca99cfe6dea6391616a3373a4165a6d01c06cc3800904cdec
+DIST grilo-0.2.15.tar.xz 627196 SHA256 6f5d2583250a68e76d281edaa08adb880d5a78ed46f9ecd22ae4715f1dd66815 SHA512 ac0a76d9075e5383fe1a56277b23986a8ec8e86f01f3f782ac7dc79539904712c22295c679243604b619f24088a1210622e0699b5601678264bd7651012ded3e WHIRLPOOL 6ea64142e1a4923d0ea3554ec3591f2c3dd6d30fdeaccde9a2a8e48d3e62ff1cd38b23a9eb39aa4c79c3a93c800e7dbfb4ad3a278e92d5ac57cb2e374a18f793

diff --git a/media-libs/grilo/grilo-0.2.15.ebuild b/media-libs/grilo/grilo-0.2.15.ebuild
new file mode 100644 (file)
index 0000000..e87bbcf
--- /dev/null
+++ b/media-libs/grilo/grilo-0.2.15.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+GCONF_DEBUG="no" # --enable-debug only changes CFLAGS
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python2_7 )
+VALA_MIN_API_VERSION="0.28"
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 python-any-r1 vala
+
+DESCRIPTION="A framework for easy media discovery and browsing"
+HOMEPAGE="https://wiki.gnome.org/Projects/Grilo"
+
+LICENSE="LGPL-2.1+"
+SLOT="0.2/1" # subslot is libgrilo-0.2 soname suffix
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+IUSE="gtk examples +introspection +network playlist test vala"
+REQUIRED_USE="test? ( introspection )"
+
+RDEPEND="
+       >=dev-libs/glib-2.44:2
+       dev-libs/libxml2:2
+       net-libs/liboauth
+       gtk? ( >=x11-libs/gtk+-3:3 )
+       introspection? ( >=dev-libs/gobject-introspection-0.9:= )
+       network? ( >=net-libs/libsoup-2.41.3:2.4 )
+       playlist? ( >=dev-libs/totem-pl-parser-3.4.1 )
+"
+DEPEND="${RDEPEND}
+       >=dev-util/gtk-doc-am-1.10
+       >=dev-util/intltool-0.40
+       virtual/pkgconfig
+       vala? ( $(vala_depend) )
+       test? (
+               $(python_gen_any_dep '
+                       dev-python/pygobject:2[${PYTHON_USEDEP}]
+                       dev-python/pygobject:3[${PYTHON_USEDEP}]')
+               media-plugins/grilo-plugins:0.2 )
+"
+# eautoreconf requires gnome-common
+
+python_check_deps() {
+       has_version "dev-python/pygobject:2[${PYTHON_USEDEP}]" && \
+               has_version "dev-python/pygobject:3[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+       use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+       # Don't build examples
+       sed -e '/SUBDIRS/s/examples//' \
+               -i Makefile.am -i Makefile.in || die
+
+       use vala && vala_src_prepare
+       gnome2_src_prepare
+}
+
+src_configure() {
+       # --enable-debug only changes CFLAGS, useless for us
+       gnome2_src_configure \
+               --disable-static \
+               --disable-debug \
+               $(use_enable gtk test-ui) \
+               $(use_enable introspection) \
+               $(use_enable network grl-net) \
+               $(use_enable playlist grl-pls) \
+               $(use_enable test tests) \
+               $(use_enable vala)
+}
+
+src_install() {
+       gnome2_src_install
+       # Upstream made this conditional on gtk-doc build...
+       emake -C doc install DESTDIR="${ED}"
+
+       if use examples; then
+               # Install example code
+               insinto /usr/share/doc/${PF}/examples
+               doins "${S}"/examples/*.c
+       fi
+}